Werte aus zwei Zeilen in eine Spalte untereinandner

[autostrada]

Hallo zusammen,

ich versuche momentan, die Werte aus zwei Zeilen in eine Spalte untereinander zu bekommen. 

Beispiel: 

Die Werte aus E5 bis H5 und E6 bis H6 sollen in einer Spalte untereinander stehen, z.B. in Spalte E ab Zeile 7. Allerdings, das ist jetzt mein Problem, sollen die Daten folgendermaßen in der Spalte eingetragen werden:

E5
E6
F5
F6
G5
G6
H5
H6

Ich würde gerne eine Beispieldatei hochladen für' s bessere Verständnis, finde aber nicht die entsprechende Funktion hierfür...Wo finde ich die?

Vielen Dank schon mal für eure Hilfe...


Gruß


Rolf

[lupo1]

E7: =INDEX($5:$6;REST(ZEILE(A1)-1;2)+1;ZEILE(A10)/2) oder

E7: =INDEX($5:$6;ISTGERADE(ZEILE(A1))+1;ZEILE(A10)/2)

[RPP63]

Nur weil ich auch nachgedacht habe,
mal meine (umständlichere) Lösung:
=INDEX(E$5:H$6;REST(ZEILE(A2);2)+1;AUFRUNDEN(ZEILE(A1)/2;0))
Tabelle1

	E	F	G	H
5	E5	F5	G5	H5
6	E6	F6	G6	H6
7	E5
8	E6
9	F5
10	F6
11	G5
12	G6
13	H5
14	H6

Formeln der Tabelle

Zelle Formel E7 =INDEX(E$5:H$6;REST(ZEILE(A2);2)+1;AUFRUNDEN(ZEILE(A1)/2;0))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Ralf

[autostrada]

Wow, das geht ja echt flott mit den Antworten, danke dafür.

Das mit dem Einfügen der Tabelle hab ich eben rausgefunden... 

Tabelle1

	E	F	G	H
5	E5	F5	G5	H5
6	E6	F6	G6	H6
7	E5
8	E6
9	F5
10	F6
11	G5
12	G6
13	H5
14	H6

Formeln der Tabelle

Zelle Formel E7 =INDEX(E$5:H$6;REST(ZEILE(A2);2)+1;AUFRUNDEN(ZEILE(A1)/2;0)) E8 =INDEX(E$5:H$6;REST(ZEILE(A3);2)+1;AUFRUNDEN(ZEILE(A2)/2;0)) E9 =INDEX(E$5:H$6;REST(ZEILE(A4);2)+1;AUFRUNDEN(ZEILE(A3)/2;0)) E10 =INDEX(E$5:H$6;REST(ZEILE(A5);2)+1;AUFRUNDEN(ZEILE(A4)/2;0)) E11 =INDEX(E$5:H$6;REST(ZEILE(A6);2)+1;AUFRUNDEN(ZEILE(A5)/2;0)) E12 =INDEX(E$5:H$6;REST(ZEILE(A7);2)+1;AUFRUNDEN(ZEILE(A6)/2;0)) E13 =INDEX(E$5:H$6;REST(ZEILE(A8);2)+1;AUFRUNDEN(ZEILE(A7)/2;0)) E14 =INDEX(E$5:H$6;REST(ZEILE(A9);2)+1;AUFRUNDEN(ZEILE(A8)/2;0))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[autostrada]

Jetzt habe ich noch Bezüge zu Arbeitsblättern in der gleichen Arbeitsmappe und in einer andere Arbeitsmappe hergestellt. Das war wiederum relativ einfach...

Gruß


Rolf

[RPP63]

Das pfriemelige, Rolf, ist ja, den Algorithmus der Zählvariablen herauszubekommen. ;)

@Lupo:
Woher zum Geier hast Du die Info, dass Dezimalzahlen in der Index-Funktion abgeschnitten (nicht gerundet) werden?
Ich suche mir nen heißen, gefunden habe ich nichts!
Aber: Gut zu wissen!  :19:

[lupo1]

Gilt bei vielen Funktionen:

=WAHL()
=INDEX()
...

Ist doch auch logisch! Erwarten doch ganzzahlige Werte. Also wird es auch beim 3. Argument SVERWEIS so sein. Und überall sonst auch, z.B. KKLEINSTE(). Das Schöne: Es wird nie gerundet. Immer abgeschnitten. Runden ist ne Katastrophe. Allein der Unterschied zw. kfm. u. math. Runden. Schön klar, und spart viele Zeichen, vor allem bei Tricks:

=KKLEINSTE($C$3:$N$3;SPALTE(A1)*4/3) nach rechts kopiert lässt den 3., 7., 11., ... Eintrag weg.

[RPP63]

Korrekt!
Und wo wir gerade beim Thema Zeichen-Sparen sind:
Mein Zeilenargument der Index-Funktion hat zwei Zeichen weniger!  :05:

[lupo1]

Ich antworte schnell und schmutzig ... da bleibt manche Optimierung liegen ;)