Registriert seit: 12.03.2018
Version(en): 14.0.7194.5000
Hallo Zusammen
Seit Wochen grüble ich an der Formel aber werde nicht schlau.
Ich habe eine Excel Tabelle wo so aussieht wie im Anhang.
Nun möchte ich für jeden Mitarbeiter einen Auszug haben, wann er an welchem Job arbeitet. Also es müsste einen Bereich nach einem Namen absuchen und mir unten einen Zusammenzug herausgeben von diesem Namen mit Datum und Projektname.
z.B.
Dirk Binggeli
20.02.18, Eröffnung ABC
22.04.04.18, Ferienmesse Bern
Und dies hätte ich dann gerne für jeden Mitarbeiter. Könnt ihr Profis mir helfen?
Vielen Dank!
Excel Zusammenzug Personal.xlsx (Größe: 11,39 KB / Downloads: 6)
Registriert seit: 16.04.2014
Version(en): xl2016/365
Hola,
Code:
=WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A1)));"")
Code:
=WENNFEHLER(INDEX($B$2:$E$2;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A1)));"")
Beide Formel nach unten ziehen. Nicht vergessen hinter den Namen ab A12 den Doppelpunkt zu entfernen.
Gruß,
steve1da
Registriert seit: 12.03.2018
Version(en): 14.0.7194.5000
Hallo Steve1da
Cool danke!
Jedoch funktionierts noch nicht. Wenn ich die Formel so übernehme kommt nix... wenn ich "Wennfehler" lösche und nur "Wenn" eingebe kommt #ZAHL!
Was mach ich noch falsch?
Liebe Grüsse
Registriert seit: 10.04.2014
Version(en): Microsoft 365, mtl. Kanal
Hi Corali,
lies dir hier die Erklärung zu dieser Meldung durch:
https://support.office.com/de-de/article...1dcca0428b
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Registriert seit: 16.04.2014
Version(en): xl2016/365
Hola,
Was mach ich noch falsch?
kenie Ahnung. Den Doppelpunkt hinter dem Namen nicht gelöscht?
Gruß,
steve1da
Registriert seit: 10.04.2014
Version(en): 2016 + 365
12.03.2018, 14:46
(Dieser Beitrag wurde zuletzt bearbeitet: 12.03.2018, 14:46 von Rabe.)
Hi,
geht doch:
| Arbeitsblatt mit dem Namen 'Tabelle1' |
| A | B | C | D | E |
| 1 | Datum: | 20.02.2018 | 15.03.2018 | 22.04.2018 | 28.04.2018 |
| 2 | Projekt: | Eröffnung ABC | Thunfest | Ferienmesse Bern | Phenomen Konzert |
| 3 | | | | | |
| 4 | Licht: | Dirk Binggeli | Beat Bunz | Dirk Binggeli | Beat Bunz |
| 5 | Ton: | Claude Hink | Michi Gerber | Stefan Müller | Michi Gerber |
| 6 | Projektleitung: | Corinne Morier | Peter Würz | Peter Würz | Corinne Morier |
| 7 | | | | | |
| 8 | | | | | |
| 9 | | | | | |
| 10 | Lösung sieht so aus: | | | | |
| 11 | | | | | |
| 12 | Dirk Binggeli | | | | |
| 13 | 20.02.2018 | Eröffnung ABC | | | |
| 14 | 22.04.2018 | Ferienmesse Bern | | | |
| 15 | | | | | |
| 16 | | | | | |
| 17 | Corinne Morier | | | | |
| 18 | 20.02.2018 | Eröffnung ABC | | | |
| 19 | 28.04.2018 | Phenomen Konzert | | | |
| Zelle | Format | Wert |
| B1 | TT.MM.JJJJ | 20.02.2018 |
| C1 | TT.MM.JJJJ | 15.03.2018 |
| D1 | TT.MM.JJJJ | 22.04.2018 |
| E1 | TT.MM.JJJJ | 28.04.2018 |
| A13 | TT.MM.JJJJ | 20.02.2018 |
| A14 | TT.MM.JJJJ | 22.04.2018 |
| A15 | TT.MM.JJJJ | |
| A16 | TT.MM.JJJJ | |
| A18 | TT.MM.JJJJ | 20.02.2018 |
| A19 | TT.MM.JJJJ | 28.04.2018 |
| Zelle | Formel |
| A13 | =WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A1)));"") |
| B13 | =WENNFEHLER(INDEX($B$2:$E$2;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A1)));"") |
| A14 | =WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A2)));"") |
| B14 | =WENNFEHLER(INDEX($B$2:$E$2;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A2)));"") |
| A15 | =WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A3)));"") |
| B15 | =WENNFEHLER(INDEX($B$2:$E$2;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A3)));"") |
| A16 | =WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A4)));"") |
| B16 | =WENNFEHLER(INDEX($B$2:$E$2;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$12);ZEILE(A4)));"") |
| A18 | =WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$17);ZEILE(A1)));"") |
| B18 | =WENNFEHLER(INDEX($B$2:$E$2;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$17);ZEILE(A1)));"") |
| A19 | =WENNFEHLER(INDEX($B$1:$E$1;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$17);ZEILE(A2)));"") |
| B19 | =WENNFEHLER(INDEX($B$2:$E$2;AGGREGAT(15;6;SPALTE($B$1:$E$1)-1/($B$2:$E$6=$A$17);ZEILE(A2)));"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2013 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Registriert seit: 12.03.2018
Version(en): 14.0.7194.5000
Hell YEAAAHH, wooow ihr seit spitze! DANKE TUUUUSIG
Wochenlanges googeln... und hier so schnell . DANKE
Registriert seit: 10.04.2014
Version(en): Office 2019
Hallo,
hier sollte es auch so reichen..:
| Arbeitsblatt mit dem Namen 'Tabelle1 (3)' |
| A | B |
| 12 | Dirk Binggeli | |
| 13 | 20.02.2018 | Eröffnung ABC |
| 14 | 22.04.2018 | Ferienmesse Bern |
| 15 | | |
| 16 | | |
| 17 | Corinne Morier | |
| 18 | 20.02.2018 | Eröffnung ABC |
| 19 | 28.04.2018 | Phenomen Konzert |
| 20 | | |
| Zelle | Formel |
| A13 | =WENNFEHLER(AGGREGAT(15;6;$B$1:$E$1/($B$2:$E$6=$A$12);ZEILE(A1));"") |
| B13 | =WENNFEHLER(INDEX($B$2:$E$2;VERGLEICH($A13;$B$1:$E$1;0));"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Freund einer excellenten Power Query-Abfrage
Registriert seit: 12.03.2018
Version(en): 14.0.7194.5000
Eine Frage habe ich nun noch:
Ich möchte nun in Tabelle 2 diese Auflistungen machen. Jetzt ist natürlich die Formel falsch weil da irgendwo stehen muss, dass es Bezug auf Tabelle 2 nehmen muss. Lediglich der Name würde in Tabelle 2 Stehen und das
Tabelle2:
Dirk Binggeli Datum Projekt
Registriert seit: 12.03.2018
Version(en): 14.0.7194.5000
12.03.2018, 17:58
(Dieser Beitrag wurde zuletzt bearbeitet: 13.03.2018, 10:03 von Rabe.
Bearbeitungsgrund: Text aus Zitat rausgeholt
)
(12.03.2018, 17:47)Jockel schrieb: Hallo, hier sollte es auch so reichen..:
| Arbeitsblatt mit dem Namen 'Tabelle1 (3)' |
| A | B |
| 12 | Dirk Binggeli | |
| 13 | 20.02.2018 | Eröffnung ABC |
| 14 | 22.04.2018 | Ferienmesse Bern |
| 15 | | |
| 16 | | |
| 17 | Corinne Morier | |
| 18 | 20.02.2018 | Eröffnung ABC |
| 19 | 28.04.2018 | Phenomen Konzert |
| 20 | | |
| Zelle | Formel |
| A13 | =WENNFEHLER(AGGREGAT(15;6;$B$1:$E$1/($B$2:$E$6=$A$12);ZEILE(A1));"") |
| B13 | =WENNFEHLER(INDEX($B$2:$E$2;VERGLEICH($A13;$B$1:$E$1;0));"") |
| Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2010 |
| Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg |
Hallo Jockel
Meine Antwort steht doch direkt über deiner Antwort... oder was erwartest du noch an Rückmeldung?
Liebe Grüsse
