Clever-Excel-Forum › Office-Anwendungen › Excel v
Erste Zahlenübereinstimmung über zwei Spalten finden

Thema geschlossen 
Baumstrukturmodus
Erste Zahlenübereinstimmung über zwei Spalten finden
wirsing Offline
pausiert
Registriert seit: 29.11.2016
Version(en): 2010
#1
01.12.2016, 17:10
Hallo,

in einer Tabelle sind zwei Spalten mit einer Menge an unterschiedlichen Zahlen gefüllt.

Wie kann ich die erste gemeinsame Übereinstimmung von zwei Zahlen in jeder Spalte finden und als Ergebnis in einer Zelle ausgeben?
Vermutlich muß die erste Zahl in Spalte A mit den Werten in Spalten B geprüft werden und bei Nichtfinden wird die zweite Zahl in Spalte verwendet.

Ich habe hierzu einmal ein Beispiel angehangen.

Danke!


Angehängte Dateien
.xls   Vergleichssuche.xls (Größe: 22,5 KB / Downloads: 9)
Suchen
Top
BoskoBiati Offline
नौसिखिया [vidyaarthi]

Registriert seit: 13.04.2014
Version(en): 365
#2
01.12.2016, 17:22 (Dieser Beitrag wurde zuletzt bearbeitet: 01.12.2016, 17:28 von BoskoBiati.)
Hallo,

würde ich mit einer Hilfsspalte lösen:

[html]
Arbeitsblatt mit dem Namen 'Tabelle1'
 ABC
134 
279 
31114 
41519 
51924$A$5/ $B$4
62329 
72734 
83139 
93544 
103949$A$10/ $B$8
114354 
124759 

ZelleFormel
C1=WENN(ISTZAHL(VERGLEICH(A1;B:B;0));ADRESSE(ZEILE();1)&"/ "&ADRESSE(VERGLEICH(A1;B:B;0);2);"")
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
[/html]


Ginge aber auch so:

[html]
Arbeitsblatt mit dem Namen 'Tabelle1'
 DE
1ErgebnisA5
2 B4

ZelleFormel
E1{="A"&VERGLEICH(KKLEINSTE(WENN(ZÄHLENWENN(B1:B12;A1:A12)>0;A1:A12);1);A:A;0)}
E2{="B"&VERGLEICH(KKLEINSTE(WENN(ZÄHLENWENN(A1:A12;B1:B12)>0;B1:B12);1);B:B;0)}
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
[/html]
Gruß

Edgar

Meine Antworten sind freiwillig und ohne Gewähr!
Über Rückmeldungen würde ich mich freuen.
Suchen
Top
shift-del Offline
{Irrtum / Versuch * Glaskugel}
Registriert seit: 12.04.2014
Version(en): Office 365
#3
01.12.2016, 17:22
Hallo

Eine Möglichkeit.
Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCDE
134 ErgebnisA5
279  B4
31114   
41519   
51924   
62329   
72734   
83139   
93544   
103949   
114354   
124759   

ZelleFormel
E1{="A"&VERGLEICH(1;ZÄHLENWENNS(B1:B12;A1:A12);0)}
E2="B"&VERGLEICH(INDIREKT(E1);B1:B12;0)
Achtung, Matrixformel enthalten!
Die geschweiften Klammern{} werden nicht eingegeben.
Verlassen Sie den Zelleneditor mit Strg+Shift + Enter, statt Enter alleine.
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.

Homepage Suchen
Top
WillWissen Offline
CEF-Moderator
Registriert seit: 10.04.2014
Version(en): Microsoft 365, mtl. Kanal
#4
01.12.2016, 17:32 (Dieser Beitrag wurde zuletzt bearbeitet: 01.12.2016, 17:33 von WillWissen. Bearbeitungsgrund: Smilies deaktiviert )
Hi,

eine Hilfsspaltenlösung (HS einfach ausblenden):

Tabelle1

ABCDEF
134#NV#NVErgebnisA4
279#NV#NVB5
31114#NV#NV
41519#NV5
519244#NV
62329#NV#NV
72734#NV#NV
83139#NV10
93544#NV#NV
1039498#NV
114354#NV#NV
124759#NV#NV
Formeln der Tabelle
ZelleFormel
C1=VERGLEICH(A1;$B$1:$B$12;0)
D1=VERGLEICH(B1;$A$1:$A$12;0)
F1=ZEICHEN(SPALTE()-5+64)&AGGREGAT(5;6;C:C)
A2=A1+4
B2=B1+5
C2=VERGLEICH(A2;$B$1:$B$12;0)
D2=VERGLEICH(B2;$A$1:$A$12;0)
F2=ZEICHEN(SPALTE()-4+64)&AGGREGAT(5;6;D:D)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Edit:

Die Ergebnisformeln müssen natürlich so lauten:

Tabelle1

EF
1ErgebnisA5
2B4
Formeln der Tabelle
ZelleFormel
F1=ZEICHEN(SPALTE()-5+64)&AGGREGAT(5;6;D:D)
F2=ZEICHEN(SPALTE()-4+64)&AGGREGAT(5;6;C:C)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Suchen
Top
Jockel Offline
VUP & {Formelsympathisant}
Registriert seit: 10.04.2014
Version(en): Office 2019
#5
01.12.2016, 17:33
Hallo oder ohne Matrixformelabschluss und ohne INDIREKT()..:

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCDE
134 ErgebnisA5
279  B4
31114   
41519   
51924   
62329   
72734   
83139   
93544   
103949   
114354   
124759   
13     

ZelleFormel
E1="A"&AGGREGAT(15;6;ZEILE(A1:A12)/ZÄHLENWENN(B1:B12;A1:A12);1)
E2="B"&AGGREGAT(15;6;ZEILE(A1:A12)/ZÄHLENWENN(A1:A12;B1:B12);1)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Freund einer excellenten Power Query-Abfrage
Suchen
Top
Gast 123 Offline
Benutzer
Registriert seit: 12.03.2016
Version(en): Excel 2003/ 2016
#6
01.12.2016, 18:03
Hallo

oh wie schön, schon viele Lösungen.  Anbei die Beispieldatei mit Makro zurück.
Ich habe mir erlaubt etwas genauer zu sein und gebe die gefundene Zahl mit an. Bitte anschauen.

öfg  Gast 123


Angehängte Dateien
.xls   Vergleichssuche.xls (Größe: 31,5 KB / Downloads: 0)
Suchen
Top
Jockel Offline
VUP & {Formelsympathisant}
Registriert seit: 10.04.2014
Version(en): Office 2019
#7
01.12.2016, 18:27
(01.12.2016, 18:03)Gast 123 schrieb: Hallo
...
Ich habe mir erlaubt etwas genauer zu sein und gebe die gefundene Zahl mit an. Bitte anschauen.

öfg  Gast 123

Hallöchen, das ist ja nun ein Leichtes. War aber nicht gefragt. Ich wundere mich nur, warum der TE nun zum zweiten Mal Zelladressen haben will. Aber ist eigentlich auch egal...
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Freund einer excellenten Power Query-Abfrage
Suchen
Top
Jockel Offline
VUP & {Formelsympathisant}
Registriert seit: 10.04.2014
Version(en): Office 2019
#8
01.12.2016, 18:57
Hallo, mit nur einer Formel geht's so z.B.:

Arbeitsblatt mit dem Namen 'Tabelle1'
 ABCDEF
134 ErgebnisA3A3
279  B4B4
31114    
41511    
51916    
62321    
72726    
83131    
93536    
103941    
114346    
124751    

ZelleFormel
F1=ZEICHEN(64+ZEILE(A1))&AGGREGAT(15;6;ZEILE($A$1:$A$12)/(ZÄHLENWENN(WAHL(ZEILE(A1);INDEX($B$1:$B$12;;);INDEX($A$1:$A$12;;));WAHL(ZEILE(A1);INDEX($A$1:$A$12;;);INDEX($B$1:$B$12;;))));1)
Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Freund einer excellenten Power Query-Abfrage
Suchen
Top
WillWissen Offline
CEF-Moderator
Registriert seit: 10.04.2014
Version(en): Microsoft 365, mtl. Kanal
#9
01.12.2016, 19:43
Hi Gast,

Zitat:Ich habe mir erlaubt etwas genauer zu sein und gebe die gefundene Zahl mit an.

unabhängig davon, dass das nicht zur Fragestellung gehörte: zum zusätzlichen Auslesen der gefundenen Zahl ist nicht unbedingt VBA nötig - das geht auch mit Formeln. :32:
Gruß Günter
Jeder Fehler erscheint unglaublich dumm, wenn andere ihn begehen.
angebl. von Georg Christoph Lichtenberg (1742-1799)
Suchen
Top
lupo1 Offline
Gesperrt
Registriert seit: 04.03.2015
Version(en): 2000 + meist 2010
#10
01.12.2016, 19:56
Etwas ähnliches hier, wo nämlich gleiche Einträge nebeneinander gestellt werden und bei den anderen Lücken eingebaut werden (rasend schnell auch bei extrem vielen Daten):

http://xxcl.de/0052.htm (Beispiel unten)
[-] Folgende(r) 1 Nutzer sagt Danke an lupo1 für diesen Beitrag:
  • wirsing
Suchen
Top
Thema geschlossen 


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste