Uhrzeiten aufaddieren // ohne Hilfstabelle

[Driver]

Hallo Folks,

Tabelle
[
Bild bitte so als Datei hochladen: Klick mich!
]

Formatierung
Zelle | Formel
E2 | =WENN((D2-C2)>=(9,75/24);(D2-C2)-"00:45";WENN((D2-C2)>(9,5/24);(D2-C2)-((D2-C2)-"09:00");WENN((D2-C2)>=(6,5/24);(D2-C2)-"00:30";WENN((D2-C2)>(6/24);(D2-C2)-((D2-C2)-"06:00");(D2-C2)))))
F2 | =WENN((D2-C2)>=(9,75/24);"00:45";WENN((D2-C2)>=(9,5/24);(D2-C2)-"09:00";WENN((D2-C2)>=(6,5/24);"00:30";WENN((D2-C2)>(6/24);(D2-C2)-"06:00";"00:00"))))
G2 | =WENN(F2="00:00";E2-H2;WENN((E2-H2)<=0;TEXT(ABS(E2-H2);"-"&"hh:mm");E2-H2))

In Spalte G sind Zeiten aufgelistet. Dies sind die Differenzen zu Soll und Arbeitszeit. Die Felder sind formatiert als Benutzerdefiniert hh:mm, ABER als TEXT() [damit das - dargestellt werden kann.]
In Spalte I möchte ich nun die Differenzen aufaddieren. Beispiele:
I2 + G3 in I3 (-00:35 + 01:40 = 01:05 Also soll in Feld I3 01:05 stehen.) Wie lautet die Formel dafür?
I3 + G4 in I4 (01:05 + 01:06 = 02:11 Also soll in Feld I4 02:11 stehen.) Wie lautet die Formel dass ich es mit linksgehaltener Maustaste einfach nach unten ziehen kann?

BITTE Möglichkeiten ohne Hilfstabelle (:

Hier die Tabelle im Original:
[url=
Dateiupload bitte im Forum! So geht es: Klick mich!
von filehorst.de laden[/url]

FREUE MICH AUF EURE ANTWORTEN!

Vielen Dank für eure Hilfe im Voraus

VG Driver

Link http://www.office-loesung.de/p/viewtopic.php?f=166&t=735518

[steve1da]

Hola,

verlinkst du bitte deine Fragen in den verschiedenen Foren gegenseitig?
Danke.

Gruß,
steve1da

[BoskoBiati]

Hallo,

eine Möglichkeit:

Arbeitsblatt mit dem Namen 'Kasse'
	C	D	E	F	G	H	I
2	07:00	13:12	06:00	0:12	-01:25	07:25	-01:25
3	07:00	13:00	06:00	0:00	-01:25	07:25	-02:50
4	07:00	13:15	06:00	0:15	-01:25	07:25	-04:15
5	07:00	16:31	09:00	0:31	01:35	07:25	-02:40
6	07:00	16:45	09:00	0:45	01:35	07:25	-01:05
7	07:00	16:50	09:05	0:45	01:40	07:25	00:35
8	07:00	17:00	09:15	0:45	01:50	07:25	02:25

Zelle	Formel
E2	=WENN(D2-C2>=9,75/24;D2-C2-1/32;WENN(D2-C2>9,5/24;3/8;WENN(D2-C2>=6,5/24;D2-C2-1/48;WENN(D2-C2>1/4;1/4;D2-C2))))
F2	=WENN(D2-C2>=9,5/24;MIN(D2-C2-3/8;1/32);WENN(D2-C2>1/4;MIN(D2-C2-1/4;1/48);0))
G2	=TEXT(ABS(E2-H2);WENN(E2-H2<0;"-";" ")&"hh:mm")
I2	=TEXT(ABS(SUMMENPRODUKT(($E$2:E2-$H$2:H2)*1));WENN(SUMMENPRODUKT(($E$2:E2-$H$2:H2)*1)<0;"-";" ")&"hh:mm")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Driver]

Was soll ich sagen... DAS HAB ICH GEWOLLT!!!

Super Danke!!! Vielen Dank! :)

Schöne Restwoche!