3 Variable(Anzahl der Zellen) Summen

[o0Julia0o]

hi,

ich möchte 3 in der Anzahl der Zellen variabele Summen bilden. Das sieht so aus:
   
als xls-Datei:
  Test.xlsx (Größe: 11,87 KB / Downloads: 13)

Ich habe Werte von B2:AE30 stehen(Runden). Jetzt möchte ich variabel ein WAHR über eine Anzahl von Runden schreiben. In dem Beispiel auf dem Bild ist das bei (inklusive)Runde 3 der Fall Und ebenso bei Runde 14. Somit bilder Runde 15 bis Runde 30 die letzte Summe.

Manuell habe ich dazu die Summenformel in AF3 bis AH3 geschrieben. Also z.B. für AF3:

Code:

=SUMME(B3:D3)

B3 ist der Wert für die Runde 1(welche im Feld A3 ist). B4 ist der Wert für die Runde 2(welche im Feld A4 ist). usw.

Jetzt soll es so sein, dass ich nur die 2 oder 3 WAHR setze & die Summen automatisch berechnet werden sollen. Geht das? Jede Idee ist willkommen - mir sind die Ansätze ausgegangen... alle im Sande verlaufen.

[Jockel]

Hallo, eine Möglichkeit wäre..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	AF	AG	AH
3	11	68,5	51

Zelle	Formel
AF3	=SUMME(B3:INDEX(B3:AE3;;VERGLEICH(WAHR;B1:AE1;0)))
AG3	=SUMME(INDEX(B3:AE3;;VERGLEICH(WAHR;B1:AE1;0)+1):INDEX(B3:AE3;;AGGREGAT(15;6;SPALTE(B2:AE2)-1/(B1:AE1=WAHR);2)))
AH3	=SUMME(AE3:INDEX(B3:AE3;;AGGREGAT(15;6;SPALTE(B2:AE2)-1/(B1:AE1=WAHR);2)+1))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[shift-del]

Hallo

	AE	AF	AG	AH	AI	AJ	AK	AL	AM	AN	AO	AP
1						1	4	15	31	31	31	31
2	30	∑1	∑2	∑3
3		11	68,5	51			11	68,5	51	0	0	0

Zelle	Formel
AK1	=WENNFEHLER(AGGREGAT(15;6;SPALTE($A$1:$AE$1)/$A$1:$AE$1;SPALTEN($AK1:AK1));31)
AK3	=WENNFEHLER(SUMME(INDEX($A3:$AE3;AJ1+1):INDEX($A3:$AE3;AK1));0)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[lupo1]

AF3: =SUMME(A3:INDEX(3:3;VERGLEICH(WAHR;$1:$1;)))
AG3: =SUMME(A3:AE3)-AF3-AH3
AH3: =SUMME(AE3:INDEX(3:3;VERGLEICH(WAHR;$1:$1)+1))

[o0Julia0o]

wow - was seit ihr denn für "Freaks" - im echt positivem Sinn! Wie schnell ihr so etwas herausgefunden habt. Ich habe da immer mal wieder dran gehockt - über Wochen ;) Als erfolgreichste Variante hatte ich zig Sverweise untereinander und mit zig Wenn-Formeln verknüpft - und hat doch nix geholfen.

Ich kannte auch Index und Vergleich noch nicht. Beim nachvollziehen raucht mir schon der Kopf, weil es zusammen verwendet wird. Die umschließende Summe mal außen vor gelassen - da bin ich eh ´raus ;) Funktioniert aber perfekt! Dankeee! :100:

Wieso überhaupt bei: =SUMME(B3:INDEX(B3:AE3;;VERGLEICH(WAHR;B1:AE1;0))) dieser Anfang =Summe(B3 ? Wieso B3?

[o0Julia0o]

   
Ich habe grundsätzlich immer folgende 3 Eingabemöglichkeiten:
1. Möglicheit: 0 = 0
2. Möglicheit: - = 0
3. Möglicheit: " " = Leer. Da noch kein Ergebnis vorliegt.

Also wenn man 0 in die Tabelle einträgt(1.), soll das auch als 0 gerechnet werden. Wenn man - einträgt(2.), soll das auch als 0 gerechnet werden.
Wenn man aber nichts eingibt(3.), soll das auch nicht berechnet werden. Das Ergebnis soll dann auch nichts sein.



Wenn jetzt die Felder B3:D3 berechnet werden sollten, wäre meine Formel in Feld AF3  dazu: 

Code:

=WENN(ANZAHL(B3:D3)>0;SUMME(B3:D3);WENN(ZÄHLENWENN(B3:D3;"-");0;""))

Jedoch ist der Bereich ja nicht fest, und es muss die obige Formel angewendet werden: =SUMME(B3:INDEX(B3:AE3;;VERGLEICH(WAHR;B1:AE1;0)))


Wie kann ich jetzt die beiden Formeln kombinieren?

  Test.xlsx (Größe: 12,21 KB / Downloads: 12)

[BoskoBiati]

Hi,

kannst Du mal erklären, was es bei einer Summe für einen Unterschied macht, ob mit 0 oder mit "" gerechnet wird?
Im Übrigen ist " " nicht leer! Leer heißt "", dann kannst Du auch mit Anzahl2 alle Zellen abfragen, die nicht leer sind:

Code:

=WENN(ANZAHL2(B3:INDEX(B3:AE3;VERGLEICH(WAHR;B1:AE1;0)))=0;"";SUMME(B3:INDEX(B3:AE3;VERGLEICH(WAHR;B1:AE1;0))))

[o0Julia0o]

kannst Du mal erklären, was es bei einer Summe für einen Unterschied macht, ob mit 0 oder mit "" gerechnet wird?
Im Übrigen ist " " nicht leer! Leer heißt "", dann kannst Du auch mit Anzahl2 alle Zellen abfragen, die nicht leer sind

Ja, ich meinte "" nicht " ". Deine Formel funktioniert. 0 ist o.k., weil dann ein Wert eingetragen ist, nämlich die 0. Bei "-" ist auch ein Wert eingetragen: Das heisst dann, dass dort nichts erreicht wurde. Aber "" bedeutet, dass noch nichts eingetragen wurde. Wenn man jetzt von mehreren solcher Ergebnissen gucken möchte, wieviele den Maximalwert erreicht haben, funkioniert das nicht, wenn dort bei "" eine 0 als Summenergebnis steht. Also wenn nicht nur in Zeile 3 Wert stehen, sondern in Zeile 4 ebenso.

Das gleiche Problem habe ich nun bei einer Zelle weiter: AG3
   
Hier funktioniert meine statische Formel:

Code:

=WENN(ANZAHL(E3:O3)>0;SUMME(E3:O3);WENN(ZÄHLENWENN(E3:O3;"-");0;""))

Ich muss diese ja mit der dynamischen Formel:

Code:

=SUMME(INDEX(B3:AE3;;VERGLEICH(WAHR;B1:AE1;0)+1):INDEX(B3:AE3;;AGGREGAT(15;6;SPALTE(B2:AE2)-1/(B1:AE1=WAHR);2)))

kombinieren. Mein Versuch sieht nun so aus:

Code:

=Anzahl2(INDEX(B3:AE3;;VERGLEICH(WAHR;B1:AE1;0)+1):INDEX(B3:AE3;;AGGREGAT(15;6;SPALTE(B2:AE2)-1/(B1:AE1=WAHR);2)))=0;"";SUMME(INDEX(B3:AE3;;VERGLEICH(WAHR;B1:AE1;0)+1):INDEX(B3:AE3;;AGGREGAT(15;6;SPALTE(B2:AE2)-1/(B1:AE1=WAHR);2))))

Funktionieren tut das aber nicht. Im Grunde möchte ich mit Teil1 der Formel bis

Code:

=0";" "

dynamisch  nachgucken ob das entsprechende zuvor eine 0 ergibt. Dann soll er "" ausgeben. Ansonsten, also bei 0 oder - oder irgendeinem Wert, soll er eben den dynamisch berechneteten Wert ausgeben(wie er ja korrekt mit Jockels Formel berechnet wird).


  Test.xlsx (Größe: 11,92 KB / Downloads: 14)

[Jockel]

Hallo, anstatt du jedes Mal eine Datei hochlädst könntest du eine posten mit mehreren Zeilen und händisch eingetragenen Wunschergebnis...

[o0Julia0o]

oh das war wohl eine alte Version. Genau das hatte ich getan eigentlich. Wunschergebnis steht in AG4, das Ergebnis steht in AG3. Also Wunschergebnis wäre "". Es steht dort aber 0.
Hier mal die aktuelle Datei:
  Test.xlsx (Größe: 12,22 KB / Downloads: 15)