AGGREGAT SUCHEN in Zahlenrange

[cult]

Hallo,

ich bräuchte nochmals eure Hilfe =)

ich habe ein Beispiel erstellt

Bei meinem Input Page werden die Auswahlkreterien ausgewählt und daraufhin werden die Maschinen (andere Seite) angezeigt die am besten passen.

das ist wie im Beispiel mit Bool (hellblau) und anderen sachen ziemlich leicht.

aber nun komme ich zu meinem Probelm es sollen nun alle Maschienen angezeigt werden bei dennen der Innendurchmesser ID in der Zahlenrange liegen genauso wie für OD und Höhe also wenn der eingegene wert zwischen MAX und MIN liegt ( MIN < X < MAX ) dieses bekomme ich mit suchen aber irgendwie nicht hin : / Ich hoffe ich drücke mich nicht zu umständlich aus.
Der "-" in der Datenbank sagt das es egal ist welcher Wert dort steht.

Danke für eure Hilfe!!!

[Hydronaut]

Hi

Wird etwas länger.

Code:

=INDEX(Tabelle1[Kriterien];AGGREGAT(15;6;ZEILE(Tabelle1[Kriterien])/(Tabelle1[Min. Outer Diameter]<=$B$6)/(Tabelle1[Max. Outer Diameter]>=$B$6)/(Tabelle1[Min. Inner Diameter]<=$B$7)/(Tabelle1[Max. Inner Diameter]>=$B$7)/(Tabelle1[Min. Height]<=$B$8)/(Tabelle1[Max. Height]>=$B$8)/(Tabelle1[_bool (Yes/No)]=$B$10)-ZEILE(Tabelle1[[#Kopfzeilen];[Kriterien]]);ZEILEN(D$8:D8)))

[neopa]

Hallo,

Detlef hat zwar schon eine Formel eingestellt, doch zu Deiner Feststellung sei zunächst anrgemerkt, dass Du gar nicht SUCHEN() musst.

In D8 hätte gereicht: =WENNFEHLER(INDEX(Table!B:B;AGGREGAT(15;6;ZEILE(s_Bool)/(s_Bool=B$10);ZEILE()-7);1);"")

Zu Deiner eigentlichen Fragestellung gebe es aus meiner Sicht jedoch zunächst Fragen.

Die Formel müsste doch doch zumindest mit vorstehender kombiniert werden. Oder?

Also nur den Innendurchmesser betrachtet dann so:

=WENNFEHLER(INDEX(Table!B:B;AGGREGAT(15;6;ZEILE(s_Bool)/(s_Bool=B$10)/(Tabelle1[Min. Inner Diameter]<=B7)/(Tabelle1[Max. Inner Diameter]>=B7);ZEILE()-7);1);"")

Die anderen Bedingungen kannst Du dann selbst noch entsprechend ergänzen.

Doch da  wäre noch die Frage, wie Deine Daten mit dem Wert "-" zu werten sind. Sollen diese grundsätzlich ausgeschlossen werden oder im Gegenteil als immer zutreffend bewertet werden?

[cult]

Danke für die schnelle Antwort,

Leider nicht genau das was ich wollte bzw es fuhnktioniert leider bei mir nicht.

Und es reicht vollkommen aus wenn in einer Zeile dann nur die Maschienen stehen zu dennen der Innerndurchmesser passt
also 3 Zeilen für OD ID Hight.

" - " in der Datenbank sollen eine Beliebige Zhal auf diese maschinen passt alles

Suchen bruache ich in diesem Fall garnichtmehr ?

[cult]

Ah deine Antwort kam als ich meine verfasst habe =)

also "-" soll als beliebig gelten hier passt alles (joker)

Zu der Frage ob die Fomel dann kombiniert wird
Ich zähle im nachhinein wie oft zb Maschine 1 vorkommt und vergebe dann ein ranking welche Maschiene am geeignetsten ist also welche am Öftesten vorkommt.

[Hydronaut]

Leider nicht genau das was ich wollte bzw es fuhnktioniert leider bei mir nicht.

Ich hatte noch vergessen zu erwähnen dass in Table alle Zellen mit - durch 0 bzw. 9999 ersetzt werden müssen damit der Abgleich funktioniert.

[neopa]

Hallo cult,

Deine Aussage 

Zu der Frage ob die Fomel dann kombiniert wird
Ich zähle im nachhinein wie oft zb Maschine 1 vorkommt und vergebe dann ein ranking welche Maschiene am geeignetsten ist also welche am Öftesten vorkommt.

ist zumindest für mich nicht eindeutig.

Ich interpretiere das nachfolgend mal so, dass Du die Auflistung der Maschinen für jede Bedingung einzeln vornehmen willst.

Dies hab ich nachfolgend mal so umgesetzt, dass bei entsprechenden Angaben in B6:B8 diese Bedingungen jeweils für sich genommen ausgewertet werden, wobei diese natürlich auch alle nur in einer Formel untergebracht werden können (welche ich bevorzugen würde)

Berücksichtigt sind die "-" und das bei keinen Angaben in B6:B8 (könnte man natürlich auch noch für B10 tun) jeweils die komplette Maschinenliste durch die jeweilige Formel erstellt wird. Deine von Dir benannte Formel s_Bool hab ich einfach beibehalten

	A	B	C	D	E	F	G	H	I	J
6	OD [mm]	55		_bool		OD		ID		Hight
7	ID [mm]	45
8	Hight [mm]	9		Maschine 2		Maschine 1		Maschine 1		Maschine 3
9				Maschine 3		Maschine 2		Maschine 2		Maschine 5
10	_Bool	Yes		Maschine 5		Maschine 3		Maschine 3		Maschine 6
11				Maschine 7		Maschine 5		Maschine 5		Maschine 7
12				Maschine 8		Maschine 6		Maschine 6		Maschine 8
13				Maschine 9		Maschine 7		Maschine 7		Maschine 9
14						Maschine 8		Maschine 8
15						Maschine 9		Maschine 9
16

Formeln der Tabelle

Zelle Formel D8 =WENNFEHLER(INDEX(Table!B:B;AGGREGAT(15;6;ZEILE(s_Bool)/(s_Bool=B$10);ZEILE()-7);1);"") F8 =WENNFEHLER(INDEX(Table!B:B;AGGREGAT(15;6;ZEILE(s_Bool)/(WECHSELN(Tabelle1[Min. Outer Diameter];"-";0)*1<=WENN(B$6="";MAX(Tabelle1[Min. Outer Diameter]);B$6))/(WECHSELN(Tabelle1[Max. Outer Diameter];"-";999)*1>=WENN(B$6="";MIN(Tabelle1[Max. Inner Diameter]);B$6));ZEILE()-7);1);"") H8 =WENNFEHLER(INDEX(Table!B:B;AGGREGAT(15;6;ZEILE(s_Bool)/(WECHSELN(Tabelle1[Min. Inner Diameter];"-";0)*1<=WENN(B$7="";MAX(Tabelle1[Min. Inner Diameter]);B$7))/(WECHSELN(Tabelle1[Max. Inner Diameter];"-";999)*1>=WENN(B$7="";MIN(Tabelle1[Max. Inner Diameter]);B$7));ZEILE()-7));"") J8 =WENNFEHLER(INDEX(Table!B:B;AGGREGAT(15;6;ZEILE(s_Bool)/(WECHSELN(Tabelle1[Min. Height];"-";0)*1<=WENN(B$8="";MAX(Tabelle1[Min. Height];B$8))/(WECHSELN(Tabelle1[Max. Height];"-";999)*1>=WENN(B$8="";MIN(Tabelle1[Max. Height]);B$8)));ZEILE()-7);1);"")

[radagast]

heje excelfreunde,

um den kleinsten und grössten aufnahmebereich einer maschine nutzen zu können, sollte ggf. die Bedingung "Min < X < Max" des vorgegeben Zahlenbereiches auf "Min<= X <= Max" abgestellt werden, da sonst ein teil der maschinenkapazität nicht in anwendung kommt.

[cult]

Danke für eure Hilfe klappt alles super!

Also ID OD und Hight werde ich wohl auch zusammennehmen aber mir ging es hauptsächlich um das Verständnis, da dies nicht die eizigen Auswahlkreterien sind und das Probelm ist das es sehr oft sein kann das es nicht nur auf einer Maschine machbar ist sondern diese auch ab und zu gewechselt werden kann nach einem abgeschlossenen Prozessschritt. Deswegen war mein Gedanke die Maschienen zu  zählen je nachdem wie oft sie Vorkommen und am ende ein Ranking zu erstellen und nur dieses auszugeben, dies ist auch der Grund weshalb ich nicht mit einem Spezialfilter arbeiten kann.

Ich hoffe dies hilft zu verstehen wieso ich es so mache =)

Nochmals danke für die schnelle Hilfe