Abfrage nach mehreren Bedingungen

[Woody96]

Guten Morgen,

ich sitze momentan an einer Excel-Tabelle und komme absolut nicht weiter.

Ich habe verschiedene Nummern mit darin enthaltenen verschiedenen Beschreibungen.

[
Bild bitte so als Datei hochladen: Klick mich!
]

Ich möchte mir die Nummer anzeigen lassen, wenn sie die Beschreibung 2093-700 hat. Dabei soll aber noch geprüft warden, dass diese nur angezeigt wird, wenn in der Zeile davor die selbe Nr. steht und im Status der Text CNF enthalten ist. Der restliche Text ist variable, es geht nur um das CNF.
Die Vorgaben sollen für alle Zeilen überprüft werden und dann angezeigt werden.

Ein wenig habe ich hinbekomemn, aber nur soweit, dass die Nr. angezeigt, die die Beschreibung 2093-700 enthält. Das Ganze dann als Array-Formel.

Code:

{=WENNFEHLER(INDEX(Sheet1!$A$2:$A$178;KGRÖSSTE((Sheet1!$B$2:$B$178="2093-700")*(ZEILE(Sheet1!$B$2:$B$178)-1);ZÄHLENWENN(Sheet1!$B$2:$B$178;"2093-700")+1-ZEILE(Sheet1!B1)));"")}

Ich hoffe, dass jemand eine Idee hat.

Grüße

[chris-ka]

Hi,

bei deinem Bsp. gibt es keine Nummer  dazu ;)

Anbei eine Lösung mit Hilfsspalte
Wenn 1 dann Treffer
das wäre auch leicht auszuwerten


  Test_20_11.xlsx (Größe: 14,1 KB / Downloads: 2)

[WillWissen]

Hi Chris,

sofern ich das Problem richtig verstanden habe, gibt es zwei Treffer:

Sheet1

	A	B	C
7	11003100215	2093-700	PRT  REL
8	11003100216	2093-400	CNF  MILE PRT  REL
9	11003100216	2093-410	CNF  MILE PRT  REL
10	11003100216	2093-700	PRT  REL
11	11003101527	2093-400	CNF  MILE PRT  REL
12	11003101527	2093-410	CNF  MILE PRT  REL
13	11003101527	2093-700	PRT  REL

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

1. Beschreibung 2093-700 (ergibt Nr. 11003100216)
2. Nummer muss in Zeile davor ebenfalls vorkommen
3. Bedingung der Anzeige, dass im Status CNF* vorkommt

Dieses Bsp. bezieht sich auf Zeile 9 und 10

[Woody96]

Hallo,

danke schonmal für die Antworten und die nicht klar genug gemachte Intention meinerseits.
Sheet 1 wird automatisch generiert. Sheet 2 ist identisch vom Aufbau, dort soll allerdings nur Folgendes angezeigt werden mit folgenden Bedingungen:
1. Nr. in Spalte A wieder anzeigen, wenn Beschreibung 2093-700 in selber Zeile in der Spalte B vorhanden ist.
2. Die Nr. soll dann aber nur angezeigt werden, wenn die Zeile davor in Zeile C den Text CNF enthält. Was sonst noch da mit drin steht, ist egal, es geht nur um CNF.

Beispiel:
Zeile 4 hat zwar 2093-700 in B4, aber in C3, also der Zeile davor, steht kein CNF. Daher soll diese Nummer nicht angezeigt werden.
Zeile 10 hat 2093-700 in B4 und CNF in C10 stehen. Daher soll die Nummer angezeigt werden.

[BoskoBiati]

Hi,

so in Sheet2!A2, nach rechts und unten ziehen, Bereiche anpassen:

Code:

=WENNFEHLER(INDEX(Sheet1!A:A;AGGREGAT(15;6;ZEILE(Sheet1!$B$2:$B$200)/(Sheet1!$B$2:$B$200="2093-700")/(ISTZAHL(SUCHEN("CNF";Sheet1!$C$1:$C$199)));ZEILE(A1)));"")

[Woody96]

Super, vielen Dank! Das war genau das, was ich mir vorgestellt hatte!
Nochmals vielen Dank!