Aggregat

[mikeledv]

Guten Tag liebe Excel-Profis,
bei einer funktionierenden Tabelle muss ich was abändern, komm aber nicht auf eine sinnvolle Lösung.

ZIEL:
Wenn in den letzten 6 eingegebenen Zellen ein Wert steht - dann "reg".
Wenn in den letzten 6 eingegebenen Zellen eine oder mehrere leer sind(besser wäre ein Minus Zeichen oder null - als Hinweis für Eingabe aber kein Wert) - dann "unreg".
Wenn in keiner der letzten 6 eingegebenen Zellen ein Wert steht - dann "kein".

Mit Zahlen klappt die Aggregat-Formel aber die Zellen sollen gemischt sein. Zahlen und Buchstaben. Sofern da überhaupt mit Aggregat so geht?!?
Tabelle anbei.

Hat da jemand eine Idee?
Vielen Dank.
Micha

[shift-del]

Moin

Eine richtige Lösung.

Code:

=VERWEIS(ZÄHLENWENNS(ÜBERNEHMEN(WEGLASSEN(G2:AD2;;-ANZAHLLEEREZELLEN(G2:AD2));;-6);">0,009");{0.1.6};{"kein"."unreg"."reg"})

[mikeledv]

Danke Detlef,
ja so geht es auch, aber nur mit Zahlen.
Ich brauche Zahlen und Buchstaben und irgendein Zeichen um "keine Eingabe" darzustellen.
zBsp. Minus-Zeichen

---

Mit der Formel komme ich auch nicht auf den Wert "KEIN".

[shift-del]

Das Ergebnis entspricht deinen Wunschergebnissen (Zeile 2, 3 und 4).

Mit der Formel komme ich auch nicht auf den Wert "KEIN".

Bei mir kommt "kein" drei mal als Ergebnis.

[HKindler]

Hi,

mein Vorschlag:

Code:

=LET(a;$G2:$AE2;
b;6;
c;FILTER(a;a<>"");
d;ÜBERNEHMEN(c;;-b);
e;ISTZAHL(d)*(d>0);
f;SUMME(e);
g;WENNS(f=b;"reg";f=0;"kein";WAHR;"unreg");
g)

[mikeledv]

Danke Helmut,
das funktioniert aber nur mit Zahlen.
ein "x" in der Zelle - wäre als richtig bzw. so zu bewerten wie eine Zahl. Daher sind 3 Zahlen und 3 mal ein x = 6mal ok. > "reg"
nur ein "-" ist als ungültig oder als "kein Wert in diesem Monat" zu sehen.

Vielleicht ist das was ich möchte in einer Formel nicht abbildbar. ??

---

Hallo Detlef,

ja stimmt. Vielleicht habe ich mein Anliegen schlecht formuliert.
Bis August23 (Spalte R) wurde immer eine Zahl eingegeben für die Berechnung.
Daher ging die Aggregat-Formel eigentlich ganz gut.
Ab Spalte S ist es so, dass entweder eine Zahl drin steht die größer 0 ist oder es ist lediglich ein "x" was ebenfalls ein OK bedeutet aber ohne Zahlenwert.
Nur ein "-" soll anzeigen, dass in diesem Monat nichts war.

Beispiel:
15 heißt 15 genau gemessen
x heißt keine exakte Messung aber es wurde gemessen
- heißt keine Messung in diesem Monat.
Wenn die letzten 6 Monate gemessen wurde egal ob mit x oder einer Zahl = regelmäßig "reg"
Wenn die letzten 6 Monate eine Messung oder mehrere ausgefallen sind, was mit Minuszeichen eingegeben wird "-" ist es unregelmäßig. "unreg"
Wenn die letzten 6 Monate keine Messung war egal ob mit x oder einer Zahl = kein.

[HKindler]

Hi,

wenn man sich nicht klar genug ausdrückt, muss man selber denken...

Code:

e;ISTZAHL(d)*(d>0);

Hiermit wird bestimmt, welche Werte gezählt werden. Das musst du auf deine Anforderungen anpassen. Wenn nur "-" nicht gezählt werden soll, so könnte eventuell

Code:

e;--(d<>"-")

funktionieren. Aufgrund deiner immer noch vagen Beschreibung, musst du das selbst anpassen. Mir ist z.B. nicht klar, ob eine 0 jetzt gezählt werden soll oder nicht. In e muss nur für jeden Wert aus d eine 1 oder 0 ausgespuckt werden, je nach dem ob er gezählt werden soll oder nicht.

[mikeledv]

Danke Helmut,

es sollte keine null mehr geben. Ab September 2023.
lediglich wie beschrieben ganze Zahlen größer als 0 oder eben ein x falls keine Zahl da ist für den Monat.

x soll gezählt werden und alle Zellen die eine Zahl enthalten.
- soll nicht gezählt werden.

[HKindler]

Dann sollte mein Änderungs-Vorschlag doch passen. Hier wird alles gezählt, was nicht "-" ist.

[mikeledv]

Danke Helmut,
ja dein Vorschlag klappt. Ich habe es noch adaptiert, verstehe jetzt auch den Ansatz in deiner Formel.
Super Danke!
Gruß Micha