Alter berechnen

[redeagle56]

Hallo,
ich bin gerade dabei eine Ahnentafel zu erstellen.
Die Daten vor 1900 werden von Excel grundsätzlich als Text behandelt.
Wie kann ich das Alter berechnen wenn die Daten vor 1900 liegen und auch
über das Jahr 1900 gehen?
Ich bin fast am Verzweifeln. Vieles schon probiert, komme aber nicht zum Ziel.
Kann mir jemand dabei helfen?
Bitte ohne VBA.

MfG Günter

  Alter berechnen.xlsx (Größe: 14,32 KB / Downloads: 6)

[BoskoBiati]

Hi,

z.B. so:

  Alter berechnen.xlsx (Größe: 9,27 KB / Downloads: 5)

Es ist verdammt schlecht, alle Zellen als Text zu formatieren. Für die Datumswerte geht es noch, beim Rest nicht!

[redeagle56]

Hallo,
danke erst mal für die Mühe.
Die Formatierung der Zellen ist Standard.
Wenn ich aber als Sterbedatum ein Datum über 1900 eingebe, dann macht
Excel daraus ein Datum. Dadurch fehlen natürlich die 4 Stellen von LINKS
und ich bekomme einen Fehler.
Wie kann man das Datum (Format TT.MM.JJJJ) eingeben ohne das Excel nervt?
Gibt es da eine Trick?

MfG Günter

  Alter berechnen_2.xlsx (Größe: 17,67 KB / Downloads: 6)

PS: Habe jetzt vor jeder Datumseingabe ein Apostroph gesetzt, funktioniert.

[BoskoBiati]

Hi,

bei Deiner Version dürfte das funktionieren:

Code:

=LET(xa;TEXT(B4;"TT.MM.JJJJ");xb;TEXT(C4;"TT.MM.JJJJ");xc;RECHTS(xa;4)+400;xd;RECHTS(xb;4)+400;DATEDIF(LINKS(xa;6)&xc;LINKS(xb;6)&xd;"Y"))

[redeagle56]

Hallo,
vielen Dank für die Mühe. Da sehe ich aber nicht mehr durch.
Was bedeuten die Kürzel xa bis xd?
Die Formel funktioniert, weiß nur nicht warum.

MfG Günter

[BoskoBiati]

Hi,

xa bis xd sind Namen für Variablen.

[EA1950]

Hallo @redeagle56,

zur LET-Funktion gibt es diese folgende, sehr ausführliche Microsoft-Hilfe:
LET-Funktion - Microsoft-Support

[BoskoBiati]

Hi,

man könnte es auch so übersetzen:


=Legen wir fest:
       xa=TEXT(B4;"TT.MM.JJJJ")
       xb=TEXT(C4;"TT.MM.JJJJ")

dann: 
        xc=RECHTS(xa;4)+400
        xd=RECHTS(xb;4)+400

werten wir aus: DATEDIF(LINKS(xa;6)&xc;LINKS(xb;6)&xd;"Y"))
Let arbeitet die Anweisungen von links nach rechts ab und gibt den letzten Term aus. Könnte man in meiner Formel auch so schreiben:

Code:

=LET(xa;TEXT(B4;"TT.MM.JJJJ");xb;TEXT(C4;"TT.MM.JJJJ");xc;RECHTS(xa;4)+400;xd;RECHTS(xb;4)+400;xe;DATEDIF(LINKS(xa;6)&xc;LINKS(xb;6)&xd;"Y");xe)

Dann ist xe das Ergebnis der letzten Berechnung und wird in der Zelle angezeigt.
LET ist dann interessant, wenn bestimmte Teile öfter innerhalb einer Formel benutzt werden müssten, in deinem Fall würde die herkömmliche Formel so aussehen:

Code:

=DATEDIF(LINKS(TEXT(B4;"TT.MM.JJJJ");6)&RECHTS(TEXT(B4;"TT.MM.JJJJ");4)+400;LINKS(TEXT(C4;"TT.MM.JJJJ");6)&RECHTS(TEXT(C4;"TT.MM.JJJJ");4)+400;"Y")