Anzahl aus Spalten mit Prüfung von Dopplung

[riddikilus]

Hallo zusammen,
bin neu hier und brauche eure Hilfe.

In der angehängten Datei ist das Problem wahrscheinlich verständlicher erklärt aber ich versuche es hier mal im Fließtext.

Spalte A = Kunde (Kunde kann mehrfach vorkommen)
Spalte B = Status 

Jetzt brauche ich die Anzahl von Kunde die den Status "fertig" haben. Allerdings sollen die Kunden wenn sie doppelt vorkommen nur einmal gezählt werden und wichtig, sie dürfen nur gezählt werden wenn alle ihre Status auf "fertig" gestellt sind.

Vielen Dank fürs drauf rum denken...ich habe mittlerweile einen Knoten im Kopf.

Beste Grüße
Jörg


  test zähle Kunden.xlsx (Größe: 9,78 KB / Downloads: 7)

[UweD]

Hallo


mit Hilfsspalte...



Tabelle1

	A	B	C
1	Kunde	Status	Hilfsspalte
2	Klaus	offen	0
3	Thomas	fertig	1
4	Mike	fertig	1
5	Mike	offen	0
6	Thomas	fertig	0
7	Andre	fertig	1
8	Michael	fertig	1
9	Michael	offen	0
10	Mike	offen	0
11
12
13			4

verwendete Formeln
Zelle	Formel	Bereich	N/A
C2:C10	=(SUMMENPRODUKT(($A$2:$A2&$B$2:$B2=A2&"fertig")*(1))=1)*(B2="fertig")
C13	=SUMME(C2:C10)

http://excel-inn.de/dateien/vba_beispiel..._addin.zip

http://Hajo-Excel.de/tools.htm

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 25.14 einschl. 64 Bit

LG UweD

[riddikilus]

Hallo Uwe,

danke für die schnelle Antwort. 

Allerdings dürfen die Kunden nur gezählt werden wenn alle ihre Status auf "Fertig" gestellt sind.

Das richtige Ergebnis müsste in dem Fall 2 lauten (Thomas und Andre).

LG Jörg

[Elex]

Hi

Code:

=SUMMENPRODUKT((VERGLEICH(A2:A10;A2:A10;0)=ZEILE(A1:A9))*(0=ZÄHLENWENNS(A2:A10;A2:A10;B2:B10;"offen")))

Gruß Elex

[steve1da]

Hola,

Code:

=ZÄHLENWENNS($A$2:$A$10;A2;$B$2:$B$10;"fertig")=ZÄHLENWENN($A$2:$A$10;A2)

Und jetzt die WAHR zählen.

Gruß,
steve1da

[riddikilus]

Danke Elex...funktioniert.

Allerdings habe ich gedacht, ihr referenziert irgendwie auf den Status "fertig" und deshalb habe ich verschwiegen das es noch mehr Status als "offen" gibt. Bekomme ich die anderen Status (z.B. "in Bearbeitung" "zurückgestellt" "obsolet" etc.) noch in die Formel, so dass sie trotzdem funktioniert???
Sorry.

Beste grüße
Jörg

[Elex]

Dann so.

Code:

=SUMMENPRODUKT((VERGLEICH(A2:A10;A2:A10;0)=ZEILE(A1:A9))*(0=ZÄHLENWENNS(A2:A10;A2:A10;B2:B10;"<>fertig")))

[riddikilus]

Hi Steve,

da komme ich auf 3 (WAHR) und nicht auf 2...?

Gruß Jörg

---

Hi Elex,

DANKE!

Ich verstehe zwar nicht wie sie funktioniert...aber sie funktioniert.

Hut ab...

Beste Grüße
Jörg