Arbeitszeiterfassung Verknüpfung Wochentage mit Arbeitszeit (WENN-Funktion)

[Gardian1982]

Hallo zusammen,

in einem m.E. sehr schönen Arbeitszeiterfassungstools ist bislang die wöchentliche Arbeitszeit gleich verteilt. D.h. 7:42 Std. pro Tag. Die Zeilen sind entsprechend mit einer WENN-Funktion versehen damit bei Urlauben oder Krankheitstagen die Stunden genullt werden. Nun wollte ich die Arbeitszeiten Mo-Do auf 8:00 und Fr. auf 6:30 Std. setzen. Die Formel sieht bislang so aus:

=WENN(ODER($C10="Sa";$C10="So";$B10="F";$B10="U";$B10="K");;$G$2)

In $G$2 stehen nun die 8:00 Std. und in §G$3 sind nun die 6:30 Std. hinterlegt.

In Spalte C stehen die Wochentage aus denen dann in Spalte F die Arbeitszeiten automatisch generieren.

Frage: Wie muss ich die Formel verändern, dass wenn in Spalte C "Fr" steht, Spalte F sich die Stunden aus $G$3 holt?

Ich komme da auf keine kreative Lösung und wäre sehr dankbar für einen Tipp!

Im Anhang habe ich das Tool hinterlegt.

Beste Grüße

[LCohen]

=WENN(ODER($C10="Sa";$C10="So";$B10="F";$B10="U";$B10="K");;$G$2-($C10="Fr")/16)

[WillWissen]

Hi,

mein Vorschlag:

Arbeitsblatt mit dem Namen '01'
	A	B	C	D	E	F
9	01.01.	FT	Di
10	02.01.		Mi			8:00
11	03.01.		Do			8:00
12	04.01.		Fr			6:30
13	05.01.		Sa
14	06.01.		So

Zelle	Formel
F9	=WENN(ODER(WOCHENTAG(A9;2)>5;B9="FT";B9="U");0;WENN(WOCHENTAG(A9;2)=5;0,2708333;0,3333333))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Gardian1982]

Besten Dank!!! Funktioniert!!!
Jedoch kann ich da nun nicht unter $G$3 die Zeiten mal ändern, sondern müsste immer die Formel manuell anpassen...

[WillWissen]

Hi,

ändere die Formel ab:

Code:

=WENN(ODER(WOCHENTAG(A9;2)>5;B9="FT";B9="U");0;WENN(WOCHENTAG(A9;2)=5;$G$3;$G$2))

Ich hatte deine dort eingetragenen Zeiten übersehen, sonst hätte ich die Formel gleich so gepostet.

[Gardian1982]

Hallo Günter,

vielen lieben Dank!!! Nun ist das weitere Problem, dass in Spalte I immer von 480 Min. Arbeitszeit ausgegangen wird

=WENN($B10="FÜ";-480;WENN(H10=0;;WENN(H10>=F10;STUNDE(H10-F10)*60+MINUTE(H10-F10);(STUNDE(F10-H10)*60+MINUTE(F10-H10))*-1)))

Habe es mit WENN (UND(...-Funktion versucht, da sich nun die Minuten nach den Wochentagen richten müssten. Also vonn FÜ (Überstundenfrei) UND Fr Dann 390 Min. bei allen anderen Wochentagen 480 Min. Hättest Du hierfür auch eine Lösung?

[WillWissen]

Hi,

ich habe etwas umgebaut; ist aus meiner Sicht einfacher zu "verformeln".

Arbeitsblatt mit dem Namen '01'

A

B

C

D

E

F

G

H

I

J

K

L

6

Tag

FT

Wochentag

Beginn

Ende

Arbeitszeit

Pause

Arbeitszeit

Mehrarbeitszeit

Minderarb.-Zeit

Gesamt mehr

Gesamt minder

7

Soll [h]

Ist [h]

pro Tag [min]

8

Übertrag:

9

01.01.

FT

Di

12:30

10

02.01.

Mi

6:00

15:30

8:00

0:30

9:00

1:00

11

03.01.

Do

6:00

15:30

8:00

0:30

9:00

1:00

12

04.01.

FÜ

Fr

6:00

10:00

6:30

0:30

6:30

13

05.01.

Sa

14

06.01.

So

15

07.01.

Mo

6:00

15:30

8:00

0:30

9:00

1:00

16

08.01.

Di

6:00

15:30

8:00

0:30

9:00

1:00

17

09.01.

FÜ

Mi

8:00

0:30

8:00

18

10.01.

Do

6:00

15:00

8:00

0:30

8:30

0:30

19

11.01.

Fr

6:00

10:30

6:30

0:30

4:00

2:30

20

12.01.

Sa

21

13.01.

So

Zelle	Formel
H9	=WENN(B9="FÜ";0;WENN(ANZAHL(D9:E9)=2;REST(E9-D9;1)-G9;0))
I9	=WENN(UND(ANZAHL(D9:E9)=2;WOCHENTAG(A9;2)<5;H9>$G$2);H9-$G$2;WENN(UND(ANZAHL(D9:E9)=2;WOCHENTAG(A9;2)=5;H9>$G$3);H9-$G$3;0))
J9	=WENN(UND(B9="FÜ";WOCHENTAG(A9;2)<5);$G$2;WENN(UND(B9="FÜ";WOCHENTAG(A9;2)=5);$G$3;WENN(UND(ANZAHL(D9:E9)=2;WOCHENTAG(A9;2)<5;H9<$G$2);$G$2-H9;WENN(UND(ANZAHL(D9:E9)=2;WOCHENTAG(A9;2)=5;H9<$G$3);$G$3-H9;0))))
K9	=WENN(SUMME($I$9:$I$39)-SUMME($J$9:$J$39)>=0;SUMME($I$9:$I$39)-SUMME($J$9:$J$39);0)
L9	=WENN(SUMME($I$9:$I$39)-SUMME($J$9:$J$39)<0;SUMME($J$9:$J$39)-SUMME($I$9:$I$39);0)

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

K10:L39 wird nicht mehr benötigt; die Mehr- bzw. Minderzeiten werden bereits in K9:L9 summiert

[Gardian1982]

Hallo Günter,

bei mir sieht es dann so aus:




  Vorlage_2019_neu.xls (Größe: 295 KB / Downloads: 9)

Irgendwas scheint da nicht so zu funktionieren Die Mehr- oder Minderarbeit wird irgendwie nicht erfasst

[WillWissen]

Hi,

ich konnte den Fehler nicht feststellen. Eine ganz vage Vermutung, jedoch von mir nicht nachprüfbar, ist, dass du die Datei als .xls (Excel97-2003-Arbeitsmappe) gespeichert hast. Ich habe deshalb einfach nochmals die Formeln in deine Datei kopiert und sie im .xlsx-Format abgespeichert. Sie arbeitet so, wie sie mMn soll.


  Vorlage_2019_neu.xlsx (Größe: 99,12 KB / Downloads: 3)

[Gardian1982]

Hallo Günter,

Deine Vermutung war absolut richtig, sorry!

Nun funktioniert das Tool bereits echt gut... habe noch ein paar kleinere Veränderungen vorgenommen und wollte gerade die Monate (Feb-Dez) entsprechend ergänzen... Wir würdest Du denn das Problem mit dem Übertrag der Stunden aus dem Vorjahr bzw. ab Feb. der Vormonate lösen? Einfache Addition funktioniert bei der Formel nicht.

Vielen Dank und schöne Grüße, Christoph