Arbeitszeitkonto

[Arthur-Luvon]

Hallo erst mal,

ich benötige Euer Fachwissen zum erstellen einer Berechnung für das Arbeitszeitkonto.

Folgende Situation:

Flexibles Arbeitszeitkonto (AZK) bedeutet: Von geleisteter wöchentlicher Mehrarbeit über 38,5 Std. gehen 3,5 Std. in das AZK bis maximal 130 Std., der Rest in die Auszahlung

Minusstd. werden im AZK gegengerechnet, bis mindestens plus/-minus Null erreicht ist und ab der 42. Wochenstunde ( wenn das AZK im Minus ist)werden nur die Zuschläge gezahlt.


Wenn das AZK voll ist mit 130 Std. kommt alles bzw. der Überhang in die Auszahlung.

Als Beispiel hänge ich mal eine Datei an die meinen jetzigen Stand anzeigt.

Ich drehe mich nun wirklich im Kreis und habe immer wieder andere Fehler wenn ich die Formeln anpassen will.


Bitte helft mir :)

Gruß Harry

[shift-del]

Moin Harry

Hier mal mein Versuch.

Arbeitsblatt mit dem Namen 'Berechnung'
	A	B	C	D	E	F	G	H	I	J	K
1	KW	Anfangsstand	Arbeitsstunden	Diff.	in AZK	in Auszahlung >3,5	AZK Zwischenstand	in Auszahlung >130	AZK Endstand	Auszahlung Wochenarbeitszeit	Auszahlung AZK-Konto
2	KW 14	-9,0	50,0	11,5	3,5	8,0	-5,5	0,0	-5,5	30,16 €	0,00 €
3	KW 15	-5,5	38,5	0,0	0,0	0,0	-5,5	0,0	-5,5	0,00 €	0,00 €
4	KW 16	-5,5	38,5	0,0	0,0	0,0	-5,5	0,0	-5,5	0,00 €	0,00 €
5	KW 17	-5,5	40,0	1,5	1,5	0,0	-4,0	0,0	-4,0	0,00 €	0,00 €
6	KW 18	-4,0	50,0	11,5	3,5	8,0	-0,5	0,0	-0,5	30,16 €	0,00 €
7	KW 19	-0,5	35,0	-3,5	-3,5	0,0	-4,0	0,0	-4,0	0,00 €	0,00 €

Name	Bezug
AuszahlungAZKKonto	=Tabelle3!$B$7
AuszahlungWochenarbeitszeit	=Tabelle3!$B$6
MaxAZKStd	=Tabelle3!$B$2
MaxWochenStd	=Tabelle3!$B$3
MaxWochenStdinAZK	=Tabelle3!$B$4
TarifWochenStd	=Tabelle3!$B$1

Zelle	Formel
B3	=I2
D2	=C2-TarifWochenStd
E2	=MIN(D2;MaxWochenStdinAZK)
F2	=D2-E2
G2	=B2+E2
H2	=MAX(0;G2-MaxAZKStd)
I2	=G2-H2
J2	=F2*AuszahlungWochenarbeitszeit
K2	=H2*AuszahlungAZKKonto

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle3'
	A	B
1	Tarifliche Wochenstunden	38,5
2	Maximale Anzahl AZK-Stunden	130,0
3	Maximale Anzahl Wochenstunden	42,0
4	Maximale Anzahl Mehrarbeits-Wochenstunden die in das AZK übernommen werden	3,5
5	Stundenlohn	15,09 €
6	Auszahlung wenn Wochen-Arbeitszeit >42 Stunden	3,77 €
7	Auszahlung wenn AZK-Konto >130 Stunden	18,86 €

Name	Bezug
StdLohn	=Tabelle3!$B$5

Zelle	Formel
B6	=RUNDEN(StdLohn*25%;2)
B7	=RUNDEN(StdLohn*125%;2)

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Arthur-Luvon]

Vielen Dank für die Hilfe,
Werde mich gleich nach dem Frühstück daran machen.

Ich melde mich.
Gruß Harry

[Arthur-Luvon]

Guten Abend shift-del und alle anderen fleißigen Helfer und Leser,

also erst einmal herzlichen Dank für deine Mühe.

Habe deinen Versuch in die Mappe eingebaut und muss schon sagen: 
"Nicht schlecht Herr Specht."

Das hat mir sogleich gezeigt wie wenig Ahnung ich doch von Excel habe.



Im Arbeitsblatt Berechnung habe ich noch ein paar Fragen bzw. Wünsche darunter geschrieben bzw. als Kommentare eingefügt.



In den unteren gelb markierten Zellen habe ich Formeln rausgenommen und Zielergebnisse eingetragen.


Hoffentlich schaut jemand dadurch was ich haben möchte, aber das alles schriftlich zu machen ist schon echt schwer. :)

Aber zurück zum Thema:
Im Arbeitsblatt Berechnung Zelle E2;E3;E4 usw. sollen solange alle Mehrarbeitsstunden einfließen bis dass das AZK in Zelle I2;I3;I4 usw. auf Null ist und zusätzlich wenn die Arbeitsstunden in C2;C3;C4 usw. über 42 sind......

Alle weiteren Hinweise im Arbeitsblatt Berechnung

Schöne Grüße und einen schönen Abend

Harry

[shift-del]

Etwas anders strukturiert.

Arbeitsblatt mit dem Namen 'Berechnung'
	A	B	C	D	E	F	G	H	I	J	K	L
1	KW	AZK Anfangsstand	Arbeitsstunden	Diff.	in AZK  (temp)	AZK Zwischenstand	in AZK  (real)	in Auszahlung >130	in Auszahlung >3,5	AZK Endstand	Auszahlung Wochenarbeitszeit	Auszahlung AZK-Konto
2	14.	-9,0	50,0	11,5	9,0	0,0	9,0	0,0	2,5	0,0	9,43 €	0,00 €
3	15.	0,0	38,5	0,0	0,0	0,0	0,0	0,0	0,0	0,0	0,00 €	0,00 €
4	16.	0,0	38,5	0,0	0,0	0,0	0,0	0,0	0,0	0,0	0,00 €	0,00 €
5	17.	0,0	40,0	1,5	1,5	1,5	1,5	0,0	0,0	1,5	0,00 €	0,00 €
6	18.	1,5	50,0	11,5	3,5	5,0	3,5	0,0	8,0	5,0	30,16 €	0,00 €
7	19.	5,0	35,0	-3,5	-3,5	1,5	-3,5	0,0	0,0	1,5	0,00 €	0,00 €

Name	Bezug
AuszahlungAZKKonto	=Tabelle3!$B$7
AuszahlungWochenarbeitszeit	=Tabelle3!$B$6
MaxAZKStd	=Tabelle3!$B$2
MaxWochenStd	=Tabelle3!$B$3
MaxWochenStdinAZK	=Tabelle3!$B$4
TarifWochenStd	=Tabelle3!$B$1

Zelle	Formel
D2	=C2-TarifWochenStd
E2	=MEDIAN(D2;MaxWochenStdinAZK;-B2)
F2	=B2+E2
G2	=WENN(B2+E2>MaxAZKStd;MaxAZKStd-B2;E2)
H2	=MAX(0;F2-MaxAZKStd)
I2	=D2-G2-H2
J2	=B2+G2
K2	=I2*AuszahlungWochenarbeitszeit
L2	=H2*AuszahlungAZKKonto
B3	=J2

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.01] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

[Arthur-Luvon]

Hallo shift-del und alle anderen,

nochmals vielen Dank.

Du hast mir wirklich toll geholfen.

Habe die Tabelle noch etwas angepasst und sollte jetzt klar kommen.

Wenn nicht melde ich mich nochmal.

Liebe Grüße aus dem Norden

Harry