Array - Zellinhalt ermitteln mit 2 Bedingungen aus anderen Spalten

[Boduaka]

Hallo liebes Forum,

bin langsam am verzweifeln und benötige eure Hilfe.

Ich möchte in einer kleinen Tabelle in Blatt 2 automatisch aus der Tabelle in Blatt 1
die User auslesen, die in der Spalte C die Bedingung "IB 1" erfüllen und gleichzeitig
in Spalte O die Bedingung ungleich Null (<>0) erfüllen.


Die in den anderen Spalten in Blatt 1 stehenden Daten sind dafür nicht relevant.



Egal, womit ich es probiere, ich komme nicht zum gewünschten Ergebnis.

Mit den folgenden Formeln habe ich es probiert:

{=INDEX(Tabelle1!A2:AK15;VERGLEICH("IB 1"&"<>0";Tabelle1!C2:C15&Tabelle1!O2:O15;0))} = #NV

{=WENN(UND(Tabelle1!O2:O15<>0;Tabelle1!C2:C15="IB 1");Tabelle1!A2:A15;0)*ZÄHLENWENNS(Tabelle1!O2:O15;"<>0";Tabelle1!C2:C15;"IB 1")} = 0

{=SVERWEIS("IB 1";WENN(Tabelle1!O2:O15<>0;Tabelle1!C2:C15;““);1)} = #NV


Um das zu verdeutlichen, habe ich euch eine Beispieldatei angehangen.

Ich hoffe, ich habe mich verständlich ausgedrückt und  Ihr könnt helfen.
Vielen Dank vorab.


  TestUser.xlsx (Größe: 14,77 KB / Downloads: 6)

[steve1da]

Hola,

Code:

=WENNFEHLER(INDEX(Tabelle1!$A$3:$A$15;AGGREGAT(15;6;ZEILE($A$3:$A$15)-2/((Tabelle1!$C$3:$C$15="ib 1")*(Tabelle1!$O$3:$O$15<>0));ZEILE(A1)));"")

Gruß,
steve1da

[Boduaka]

Danke steve1da, klappt super. :19:

Ich verstehe nur noch nicht ganz warum.

Kannst du mir noch kurz folgendes für mein Verständnis erklären:

Im Aggregat nimmst du Bezug auf $A$3:$A$15 und ganz hinten nochmal Bezug auf A1.

In beiden Bezügen stehen keine Daten und dennoch geht das voll auf. Wie kommt das?

[steve1da]

Hola,

Code:

ZEILE($A$3:$A$15)-2

ist eine Bezeichnung, wie oft die Formel den Bereich durchsuchen muss. Von A3 bis A15 sind es 13 Zeilen - man schreibt das dann entweder so

Code:

ZEILE($A$3:$A$15)-2

oder könnte auch

Code:

Zeile(A1:A13)

schreiben.
Zeile(A1) am Ende ist ein Zähler, der den Inhalt der ersten Treffers wiedergibt, dann den Inhalt des zweiten Treffers, usw. Schreib mal in eine leere Zelle
=Zeile(A1) und zieh die Formel nach unten.

Gruß,
steve1da

[Boduaka]

Danke für die Erklärung, habe ich verstanden

Jetzt habe ich das ganze mal auf meine Tabelle angewendet und leider zwerden nicht die korrekten Daten gezogen.

Ich habe das nochmal als Beispiel aufgearbeitet und angehangen.

Jetzt fließen Daten ein, die nicht beide Bedingungen erfüllen.


  TestUser.xlsx (Größe: 34,15 KB / Downloads: 3)

Kannst du dir das nochmal ansehen?

EDIT: Habe den ersten Bezug nicht festgesetzt, aber trotz Korrektur gehts nicht.

[steve1da]

Hola,

habe ich verstanden

nicht ganz

Der Bereich geht von A6:A153. Du schreibst:

Code:

ZEILE($A$6:$A$153)-2

Da muss aber -5 hin.
Und warum schließt du das als Matrixformel ab?

Gruß,
steve1da

[Boduaka]

Super, nochmal ganz lieben Dank. Jetzt funktioniert alles.

Ein Kollege hat mich durcheinander gebracht, weshalb ich das immer als Matrixformel abgeschlossen habe.