ArtikelNr zusammefassen und summieren

[{Boris}]

Hi Bosko,

Formel korrigiert:

Was war denn zu korrigieren?

Edit: Hab`s gesehen - hatte beim 2. SUMMEWENNS die falsche Summenspalte drin.

[BoskoBiati]

Hi Boris,

Deine Formel hat 2x die Spalte E summiert.

Da m.E. die Länderkennung nicht von Bedeutung ist, würde ich das allerdings so machen:

Code:

=LET(a;SORTIEREN(EINDEUTIG(A3:D3375));b;SUMMEWENNS(E3:E3375;A3:A3375;INDEX(a;;1);B3:B3375;INDEX(a;;2);D3:D3375;INDEX(a;;4));c;SUMMEWENNS(G3:G3375;A3:A3375;INDEX(a;;1);B3:B3375;INDEX(a;;2);D3:D3375;INDEX(a;;4));WAHL({1.2.3.4.5};INDEX(a;;1);INDEX(a;;2);INDEX(a;;4);b;c))

o.t.: Gutes Beispiel um die neuen Funktionen kennenzulernen.

[Justin Brausendorf]

Danke an Alle, das ging ja super schnell :)

---

doch nochmal ich, wenn ich jetzt beispielswiese länder herausfilter, zieht er sich das dann in der Tabelle mit der Formel automatisch herraus ? Und mir fällt gerade auf, das zur Referenz das jeweilige NKZ angegeben werden soll...

danke:))

---

okey, das funktioniert mit dem Filtern.... wie ordne ich denn jetzt zur RefNR das NKZ zu ?

[{Boris}]

Hi Bosko,

hatte ich dann auch selbst gesehen - danke für den Hinweis!

Abschließend noch ein paar Variablenauslagerungen mehr sowie eine "geglättete" Ausgabe:

Code:

=LET(a;SORTIEREN(EINDEUTIG(A3:D3375));b;INDEX(a;;1);c;INDEX(a;;2);d;INDEX(a;;4);e;SUMMEWENNS(E3:E3375;A3:A3375;b;B3:B3375;c;D3:D3375;d);f;SUMMEWENNS(G3:G3375;A3:A3375;b;B3:B3375;c;D3:D3375;d);WAHL({1.2.3.4.5};b;GLÄTTEN(c);GLÄTTEN(d);e;f))

bzw. umgebrochen:

Code:

=LET(a;SORTIEREN(EINDEUTIG(A3:D3375));
b;INDEX(a;;1);
c;INDEX(a;;2);
d;INDEX(a;;4);
e;SUMMEWENNS(E3:E3375;A3:A3375;b;B3:B3375;c;D3:D3375;d);
f;SUMMEWENNS(G3:G3375;A3:A3375;b;B3:B3375;c;D3:D3375;d);
WAHL({1.2.3.4.5};b;GLÄTTEN(c);GLÄTTEN(d);e;f))

[Cadmus]

Es sollen Referenznummern zusammengefasst werden mit gleichem Datum und deren Artikelnummern, ...

Klassische Aufgabe für eine Pivottabelle, da brauchts keine Formeln.

[PIVPQ]

Hallo

Sehe ich es richtig so?

[Justin Brausendorf]

Hi, ja das sieht super aus, kann man allerdings zur jeweiligen Relation noch das Länderkennzeichen (NKZ) beifügen ? habe mich schon ausprobiert, aber bekomme es nicht so hin wie es sein soll :)

[BoskoBiati]

Hi,

ist doch in der Formel von Boris enthalten!

[Justin Brausendorf]

hi,

Ja, in der Formel schon, aber wenn ich sie einsetzte wird es nicht angezeigt ? oder was ist mein Fehler ? Denn ich muss wissen wohin welche Referenz ging

hab die Datei nochmal beigefügt...

[{Boris}]

Hi,

das war diese Formel:

=LET(a;SORTIEREN(EINDEUTIG(A3:D3375));b;SUMMEWENNS(E3:E3375;A3:A3375;INDEX(a;;1);B3:B3375;INDEX(a;;2);C3:C3375;INDEX(a;;3);D3:D3375;INDEX(a;;4));c;SUMMEWENNS(G3:G3375;A3:A3375;INDEX(a;;1);B3:B3375;INDEX(a;;2);C3:C3375;INDEX(a;;3);D3:D3375;INDEX(a;;4));WAHL({1.2.3.4.5.6};INDEX(a;;1);INDEX(a;;2);INDEX(a;;3);INDEX(a;;4);b;c))