Aus "Sehr geehrter Herr" "Herrn machen"

[Sefrie]

Hallo,

für die Excel-Experten wahrscheinlich eine einfach Aufgabe: Wie lautet die Formel wenn ich aus A1 = Herrn Jansen werden soll, aus A2 =  B2 leer bleiben soll  und aus A3 = Frau Adam werden soll?

[url=
Dateiupload bitte im Forum! So geht es: Klick mich!
]
[url=http://www.fotos-hochladen.net][/url]
Vielen lieben Dank für die Hilfe!

[Jockel]

Hallo, dann fang ich mal an..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	Sehr geehrter Herr Jansen,	Herrn Jansen,
2	Sehr geehrte Damen und Herren,
3	Sehr geehrte Frau Adam,	Frau Adam,

Zelle	Formel
B1	=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

P.S.: Änderung bei Sonderfällen..:

=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau ";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)))

[Sefrie]

Hallo, dann fang ich mal an..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	Sehr geehrter Herr Jansen,	Herrn Jansen,
2	Sehr geehrte Damen und Herren,
3	Sehr geehrte Frau Adam,	Frau Adam,

Zelle	Formel
B1	=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

P.S.: Änderung bei Sonderfällen..:


Hallo,

unglaublich, hat funktioniert. Vielen Dank! Habe die Formel ausgeführt und nun ist mir noch aufgefallen, das ein Komma hinter dem Namen steht, also zB Herrn Müller,

Könntest du vielleicht die Formel noch einmal abändern? Vielen Dank im Voraus!

[Peter]

Hallo,

quick and dirty:

=WECHSELN(WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)));",";)

[Jockel]

Hallo, Peters Idee, ist schon cool...

[Hydronaut]

Hallo

Warum nicht einfach wechseln bis der Arzt kommt?

Code:

=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1;"Sehr geehrter ";"");"Sehr geehrte ";"");"Damen und Herren";"");",";"")

[Peter]

Hallo Jockel,

wobei ich jetzt gerade festgestellt habe, dass deine erste Formel beim Herrn Frauenstein ein Problem hat. Die zweite Formel funktioniert bei diesem Beispiel.

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C
1	Sehr geehrter Herr Jansen,	Herrn Jansen	Herrn Jansen
2	Sehr geehrte Damen und Herren
3	Sehr geeehrte Frau Adam,	Frau Adam	Frau Adam
4	Sehr geehrte Frau Hermann,	Frau Hermann	Frau Hermann
5	Sehr geehrter Herr Frauenstein,	Herrn Frauenstein	Frau Frauenstein

Zelle	Formel
B1	=WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau ";A1));"Frau"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));VERWEIS(9^9;FINDEN(",";A1;SPALTE(1:1)))-SUCHEN("#";WECHSELN(A1;" ";"#";3)));"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));VERWEIS(9^9;FINDEN(",";A1;SPALTE(1:1)))-SUCHEN("#";WECHSELN(A1;" ";"#";3)))))
C1	=WECHSELN(WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)));",";)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

@Detlef: Die Ergebnisse deiner Formel passen nicht zu dem gewünschten Ergebnis mit Herrn und Frau:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
1	Sehr geehrter Herr Jansen,	Herr Jansen
2	Sehr geehrte Damen und Herren
3	Sehr geeehrte Frau Adam,	Sehr geeehrte Frau Adam
4	Sehr geehrte Frau Hermann,	Frau Hermann
5	Sehr geehrter Herr Frauenstein,	Herr Frauenstein
6	Sehr geehrter Frau Herrenstein,	Frau Herrenstein

Zelle	Formel
B1	=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1;"Sehr geehrter ";"");"Sehr geehrte ";"");"Damen und Herren";"");",";"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Jockel]

Hallo

Warum nicht einfach wechseln bis der Arzt kommt?

Weil ich einfach nicht grauf gekommen bin...?

Wobei nach der richtigen Anmerkung von Peter so heißen müßte..:

Code:

=WECHSELN(WECHSELN(WECHSELN(WECHSELN(A1;"Sehr geehrter Herr ";"Herrn ");"Sehr geehrte ";"");"Damen und Herren";"");",";"")

[Jockel]

Hallo Jockel,

wobei ich jetzt gerade festgestellt habe, dass deine erste Formel beim Herrn Frauenstein ein Problem hat. Die zweite Formel funktioniert bei diesem Beispiel.

Hi Peter, jupp, ist mir auch aufgefallen...

Dann müsste es so..:

Code:

=WECHSELN(WENN(ISTZAHL(SUCHEN("Damen und";A1));"";WENN(ISTZAHL(SUCHEN("frau ";A1));"Frau "&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50);"Herrn"&TEIL(A1;SUCHEN("#";WECHSELN(A1;" ";"#";3));50)));",";"")

[Hydronaut]

@Detlef: Die Ergebnisse deiner Formel passen nicht zu dem gewünschten Ergebnis mit Herrn und Frau:

Ach, das 'n' ist mir gar nicht aufgefallen.