Ausgabe einer Zeit bei zwei übereinstimmenden Zellen

[FrlSüßlich]

Hallo an alle,

ich habe folgende Excel-Daten (als Beispiel):

Von-Lager                    Nach-Lager              Dauer
TL-01-01                      PA-02-01                   8 min
HA-03-04                     NB-02-03                   2 min
MI-01-01                      TL-02-01                  10 min

Ich möchte gern, dass die Daten aus beiden Spalten abgeglichen werden um die richtige Zeit in der Haupttabelle zu ergänzen. Ich steh leider kompetent auf dem Schlauch oder geht das nicht umzusetzen?

Danke euch schon mal

[steve1da]

Hola,
und was soll jetzt genau abgeglichen werden und dann in der Haupttabelle, die du nicht zeigst, ergänzt werden?
Gruß,
steve1da

[HKindler]

Hi,

ich rate mal:

in C2 der Haupttabelle
=XVERWEIS(A2&B2;Hilfstabelle!$A$2:$A$4&Hilfstabelle!$B$2:$B$4;Hilfstabelle!$C$2:$C$4)
oder
=FILTER(Hilfstabelle!$C$S:$C$4;(Hilfstabelle!$A$2:$A$4=A2)*(Hilfstabelle!$B$2:$B$4=B2))
Wie immer, wenn keine Beispieldatei vorliegt, natürlich ungetestet.

Wobei die FILTER()-Variante einfacher ist, wenn die Bedingungen komplizierter werden.

[FrlSüßlich]

Danke erstmal für eure schnelle Antwort. Ich habe die Tabelle mal etwas bearbeitet um sie online stellen zu können.

  Daten (gekürzt).xlsx (Größe: 22,67 KB / Downloads: 6)

Auf dem Tabellenblatt "Daten aus System" sind die Daten in gekürzter Art zu sehen, die um die Zeitangabe ergänz werden sollen.

Auf dem Tabellenblatt "Grunddaten" sind alle bisher entstandenen verschiedenen Konstellationen aus "Von-Lagerplatz" und "Nach-Lagerplatz" aufgeführt mit den daraus entstehenden Zeiten.

Ich möchte, dass in der Tabelle mit den Daten aus dem System, die richtige Dauer automatisch ermittelt wird, wenn eine bestimmte Konstellation aus Vor- und Nach-Lagerplatz aufgelistet ist:
z.B.:
Vor-Lagerplatz KO-05-01       nach       Nach-Lagerplatz  NG-03-03       Dauer 5 min

Ich hoffe es ist jetzt etwas nachvollziehbarer was ich meine.

Danke schon mal im voraus für eure Hilfe. ::angel:

[steve1da]

Code:

=VERWEIS(2;1/(Grunddaten!$D$2:$D$297&Grunddaten!$G$2:$G$297=C3&F3);Grunddaten!$H$2:$H$297)

[FrlSüßlich]

Super, das funktioniert erstmal.

Ist es auch möglich, nur auf die Buchstaben-Kombination abzustellen?

Also statt der vollständigen Vor-Lagerplatz-Bezeichnung
TL-01-01 nur auf TL zu prüfen?

[steve1da]

Ja, aber was machst du, wenn es die Kombination mehrfach gibt? Was soll dann genommen werden?

[FrlSüßlich]

Die Buchstabenkombination ist relevanter als die Zahlen. Die Zahlen geben nur einen genaun Stellplatz an, die Buchstaben aber die Halle bzw. Etage.

[steve1da]

Code:

=INDEX(Grunddaten!$H$2:$H$297;AGGREGAT(15;6;ZEILE(Grunddaten!$H$2:$H$297)-1/((LINKS(Grunddaten!$D$2:$D$297;2)=LINKS(C3;2))*(Grunddaten!$G$2:$G$297=F3));1))

[HKindler]

Hi,

=FILTER(Grunddaten!$H$2:$H$297;(Grunddaten!$D$2:$D$297=C3)*(Grunddaten!$G$2:$G$297=F3);"nicht vorhanden")

Falls eine Kombination mehrfach vorkommen kann, übernimmt man so nur das erste Ergebnis::
=ÜBERNEHMEN(FILTER(Grunddaten!$H$2:$H$297;(Grunddaten!$D$2:$D$297=C3)*(Grunddaten!$G$2:$G$297=F3);"nicht vorhanden");1)

Und wenn man nur die ersten beiden Buchstaben vergleichen will:
=ÜBERNEHMEN(FILTER(Grunddaten!$H$2:$H$297;(LINKS(Grunddaten!$D$2:$D$297;2)=LINKS(C3;2))*(LINKS(Grunddaten!$G$2:$G$297;2)=LINKS(F3;2));"nicht vorhanden");1)

Funktioniert allerdings nicht bei Antik-Excel...