Auswertung von Spalten mit bestimmten Werten

[Cybat]

Hallo Zusammen,

ich bin noch ganz neu hier, da ich ein Problem mit Excel habe wo ich alleine auf keine Lösung komme.
Das Blatt findet Ihr im Anhang

  ZF-S4B-Monthly-Report-2017 KW1-KW23.xlsx (Größe: 996,49 KB / Downloads: 3)

Mein Ziel ist es jetzt, in den Zeilen 16/17; 20/21 und 24/25 in 07-Resolving Units, die Spalte BQ in Raw-Data für jede einzelne Kalenderwoche auszuwerten (Die Daten werden später noch hinzugefügt)
Es soll für jede Kalenderwoche (Spalte B), wenn in Spalte D ein bestimmter Wert steht (z.B. Disturbance P3 solving time < NBD) den entsprechenden Durchschnitt und die Maximale Wert von BQ ausgeben werden. Halt jeweils nur für die entsprechende KW.


Mit der WENN Formel stoße ich auf das Problem, dass ich nicht die ganze Spalte auswerten kann und bei dem SVERWEIS ist es, soweit ich weiß, nicht möglich den Mittelwert bei der Ausgabe zu bestimmen.
Falls es eine Lösung ohne Macros gibt würde ich das sehr bevorzugen.

Vielen Dank schon mal im Voraus

[steve1da]

Hola,

benutze bitte den Upload im Forum.

Gruß,
steve1da

[Cybat]

Entschuldige, aber wie mache ich das ?
In den Forenregeln stand nichts dazu  :s

[steve1da]

Hola,

unterhalb des Antwortfensters kannst du Anhänge hinzufügen.

Gruß,
steve1da

[steve1da]

Hola,

Code:

=MITTELWERTWENNS('11-Raw-Data'!$BQ$2:$BQ$1395;'11-Raw-Data'!$B$2:$B$1395;B$13;'11-Raw-Data'!$D$2:$D$1395;$A14)

Für das Maximum als Matrixformel (mit Strg-Shift-Enter abschließen):

Code:

=MAX(WENN(('11-Raw-Data'!$B$2:$B$1395=B$13)*('11-Raw-Data'!D2:D1395=A14);'11-Raw-Data'!$BQ$2:$BQ$1395))

Vorher aber die #WERT Fehler in deiner Tabelle 11-Raw-Data bereinigen:

Code:

=WENNFEHLER(BL2-BK2;"")

Code:

=WENNFEHLER(WENN(UND(R2="Disturbance - Low";C2>0);"Disturbances P3 Solving Time > NBD";
WENN(UND(R2="Disturbance - Low";C2<=0);"Disturbances P3 Solving Time < NBD";
WENN(UND(R2="Disturbance - Medium";C2>0);"Disturbances P2 Solving Time > NBD";
WENN(UND(R2="Disturbance - Medium";C2<=0);"Disturbances P2 Solving Time < NBD";
WENN(UND(R2="Disturbance - High";C2>0);"Disturbances P1 Solving Time > NBD";
WENN(UND(R2="Disturbance - High";C2<=0);"Disturbances P1 Solving Time < NBD";
WENN(UND(R2="Request CR0";C2>1);"Duration CR0 after 1 bd";
WENN(UND(R2="Request CR0";C2<=0,9);"Duration CR0 within 1 bd";
WENN(UND(R2="Request CR1";C2<=4,9);"Requests CR1 within 5 bd";
WENN(UND(R2="Request CR1";C2>5);"Requests CR1 after 5 bd";
WENN(UND(R2="Disturbance - High";C2>0);"SCOM";
WENN(UND(R2="Disturbance - High";C2<=0);"SCOM Alarms Solved";
WENN(R2="Disturbance - Medium";" ";" ")))))))))))));"")

Gruß,
steve1da

[Cybat]

Vielen Dank!

Das mit dem Mittelwert und den bereinigen der Raw-Data Tabelle hat super geklappt!


Lediglich bei der Max Formel bekomme ich als Ergebnis 0 wenn ich es normal mit Enter bestätige und #NV wenn ich Shift+Strg+Enter eingebe

 

=MAX(WENN(('11-Raw-Data'!$B$2:$B$5452=K$13)*('11-Raw-Data'!$D$2:$D$1395=A$19);'11-Raw-Data'!$BQ$2:$BQ$5452))

So sieht die Formel aus. Ich habe sie für das gesamte Datenblatt erweitert und soll mit der Auswertung erst ab KW 10 anfangen (Deswegen die kleinen Änderungen)

[BoskoBiati]

Hi,

unterschiedlich große Bereiche!!!!

[Cybat]

Ahh was ein banaler Fehler xD


Jetzt geht alles vielen lieben Dank euch beiden