Bankumsätzen sortieren

[Reismann]

Hallo liebe Experten,

ich versuche seit geraumer Zeit mit Excel meine Umsätze, die ich über das Online Banking als *.csv File abrufen kann, Grafisch auszuwerten. Um das ganze zu schaffen, versuche ich das ganze per Excel automatisch nach Monaten Sortieren zu lassen.

Leider reichen meine Excel Kenntnisse nicht aus, um das ganze sauber zu lösen, dass es auch immer funktioniert.

Ich habe euch mal meinen Versuch angehängt. 
  Finanzen_test.xlsx (Größe: 40,71 KB / Downloads: 16)  
  Umsaetze_Beispiel.csv (Größe: 21,95 KB / Downloads: 10)

Ich hatte es geschaft, in der Übersicht die jeweiligen Top Umsätze der Monate anzuzeigen. Leider funktioniert das nicht sehr zuverlässig. Bei gleichen Umsätzen bzw. Beträgen werden hier und da immer wieder falsche Umsätze angezeigt. Das Problem liegt vermutlich irgendwo in meinen mittlerweile nicht mehr überschaubaren Formeln. Die sind mittlerweile so sehr zusammengebastelt, dass ich da selbst nicht mehr durchblicke.

Eventuell kann sich das ja mal jemand ansehen und mir ggf. sogar bei der Lösung behilflich sein.

Ich habe auch mal ein Beispiel der Rohdaten angehängt. Problem hier ist auch für meine Formeln, dass am Ende der Umsatzliste noch ein "* noch nicht ausgeführte Umsätze" steht, was für meine Formeln problematisch ist.

Bin für jede Hilfe dankbar.

Viele Grüße,
Reismann

[Elex]

Hi

Leider funktioniert das nicht sehr zuverlässig. Bei gleichen Umsätzen bzw. Beträgen werden hier und da immer wieder falsche Umsätze angezeigt.

 
Die Formeln sollte das Problem lösen. Beispielhaft für Januar.
in D6 die Formel und mit shift+strg+Enter abschliessen. Dann bis D15 runter ziehen.

Code:

=WENNFEHLER(INDEX(Daten!$C$12:$C$999;KKLEINSTE(WENN((MONAT(Daten!$A$12:$A$999)=1)*(Daten!$D$12:$D$999=C6);ZEILE($A$1:$A$812));1+ZÄHLENWENN($C5:C$5;C6)));"")

in C11 die Formel und mit shift+strg+Enter abschliessen. Dann bis C15 runter ziehen.

Code:

=WENNFEHLER(KKLEINSTE(WENN(((MONAT(Daten!$A$12:$A$999)=1)*Daten!$D$12:$D$999)<0;Daten!$D$12:$D$999);ZEILE(A1));"")

Grafisch auszuwerten

Ist aber sehr allgemein.
Was soll den dargestellt, verglichen oder gegenüber gestellt werden.

Gruß Elex

[Der Steuerfuzzi]

Hallo,

auch von mir ein Vorschlag:

Code:

C6 =AGGREGAT(14+GANZZAHL(ZEILE(A1)/6);6;Daten!$D$12:$D$369/(MONAT(Daten!$A$12:$A$369)=1);REST(ZEILE(A1)-1;5)+1)
D6 =INDEX(Daten!C:C;REST(AGGREGAT(14+GANZZAHL(ZEILE(A1)/6);6;(Daten!$D$12:$D$369+ZEILE(Daten!$A$12:$A$369)%%)/(MONAT(Daten!$A$12:$A$369)=1);REST(ZEILE(A1)-1;5)+1);1)*10000)

Formeln nach unten ziehen.

Das Wennfehler wirst Du nicht benötigen, wenn genug Umsätze im jeweiligen Monat vorhanden sind. Es kann zu komischen Ergebnissen kommen, wenn weniger als 5 größte und/oder kleinste Umsätze vorhanden sind. Um das zu verhindern könnte man hier nochmal eine Abfrage einbauen, die prüft, ob der Wert positiv bzw. negativ ist.

[Reismann]

Ist aber sehr allgemein.

Was soll den dargestellt, verglichen oder gegenüber gestellt werden. 

Tut mir Leid für die Verwirrung. Ich meinte damit, dass ich gerne nachdem das hier funktioniert, ein paar grafische Auswertungen der Monate vornehmen will. Dabei benötige ich erst mal keine Hilfe. 

Ich bin auf jeden Fall begeisert von euren Lösungen. Beide funktionieren super! Ich werde jetzt weiter dran arbeiten und meine anderen Ideen noch versuchen umzusetzen. Falls ich noch mal wo hänge, komme ich noch mal auf euch zurück.

Immer wieder schön zu merken, dass es hier eine so hilfsbereite Community gibt :)

EDIT: @Der Steuerfuzzi: Wie würde denn eine Abfrage aussehen, die prüft ob der Wert Positiv oder negativ ist? Bei deiner Variante entstehen ja Fehler, wenn weniger wie 5 Umsätze da sind. Das würde ich gerne noch beheben.

[Der Steuerfuzzi]

Mit WENNFEHLER und Prüfung auf Vorzeichen:

Code:

C6 =WENNFEHLER(AGGREGAT(14+GANZZAHL(ZEILE(A1)/6);6;Daten!$D$12:$D$369/((MONAT(Daten!$A$12:$A$369)=1)*(VORZEICHEN(Daten!$D$12:$D$369)=1-2*GANZZAHL(ZEILE(A1)/6)));REST(ZEILE(A1)-1;5)+1);"")
D6 =WENNFEHLER(INDEX(Daten!C:C;REST(AGGREGAT(14+GANZZAHL(ZEILE(A1)/6);6;(Daten!$D$12:$D$369+ZEILE(Daten!$A$12:$A$369)%%)/((MONAT(Daten!$A$12:$A$369)=1)*(VORZEICHEN(Daten!$D$12:$D$369)=1-2*GANZZAHL(ZEILE(A1)/6)));REST(ZEILE(A1)-1;5)+1);1)