Bedingte Formatierung

[cult]

Hey Ihr,

erstmal Hallo von mir da dies mein erster Post ist =)

folgendes Problem:

Ich habe eine Anwesenheitstabelle erstellt in die sich jeder eintragen soll sobald er NICHT Vorort ist.

Nun soll man auf den ersten Blick sehen ob der jenige in diesem Fall Person 1 / Person 2 da sind oder nicht.
Wenn die Person da ist wie in dem Fall Person 2 soll das Feld grün werden indem der Name der Person steht (Dashboard ähnlich
habe mir sowas überlegt bedingte Formatierung M4= Grün =UND($B5:$B300=Heute();ISTLEER($M5)
Leider Funktioniert es nichts wie ich will.

Erst muss die Funktion schauen Das es "heute" ist un dann in der gleichen Zeile schauen dass M Leer ist,
wenn M leer ist in der aktuellen Datums spalte (Die schon Gelb hervorgehoben ist) ist die Person ja vorort

Person 1 soll einfach weiß bleiben da die Person sich ja "heute" in München befindet

Hoffe ihr versteht mein Problem

Mit freunldichen Grüßen

cult

[atilla]

Hallo,

Den Bereich L4:AG4 markieren und Hintergrundfarbe grün nehmen für Anwesend
Im gleichen Bereich folgende Formel für die Bedingte Formatierung eingeben:


=INDEX(L5:L1466;VERGLEICH(HEUTE();$B$5:$B$1466;0))<>""

und das Format zuweisen

Nach der Eingabe, wenn nichts passiert, dann nachschauen, ob Excel die Formel in Anführungszeichen gesetzt hat.
Wenn ja, dann  die Anführungszeichen ,außer wie oben, löschen.

[BoskoBiati]

Hallo,

da sollte eigentlich das reichen:

Arbeitsblatt mit dem Namen '2017'
	L	M
57	München
58	München
59	München

Zelle	bedingte Formatierung...	Format
M58	1: =$B58=HEUTE()	abc
M58	2: =($B58=HEUTE())*(M58="")	abc
M58	3: =$B58=HEUTE()	abc
M58	4: =$H58="f"	abc
M58	5: =REST(#BEZUG!;7)<2	abc

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Außerdem würde ich eine Liste mit Feiertagen anlegen, dann könnte man sich die WENN-Formel in H sparen.

Es gibt in Excel noch mehr Möglichkeiten:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H
1	01.01.2017	Neujahr			Datum	Wochentag	Type
2	06.01.2017	Dreikönig			01.01.2017	So	f	Neujahr
3	27.02.2017	Rosenmontag			02.01.2017	Mo	w
4					03.01.2017	Di	w
5					04.01.2017	Mi	w
6					05.01.2017	Do	w
7					06.01.2017	Fr	f	Dreikönig
8					07.01.2017	Sa	sa
9					08.01.2017	So	so
10					09.01.2017	Mo	w

Name	Bezug
FT	=Tabelle1!$A$1:$B$3

Zelle	Formel
F2	=E2
G2	=WENN(ZÄHLENWENN(FT;E2);"f";VERWEIS(REST(E2;7);{0;1;2};{"sa";"so";"w"}))
H2	=WENNFEHLER(SVERWEIS(E2;A:B;2;0);"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[atilla]

Hallo Edgar,

der TE spricht mehrmals von "die Person", und die Person steht in Zeile 4.
Deshalb bin ich davon ausgegangen, dass die Zellen in Zeile 4 hervorgehoben werden sollen.

Dann warten wir mal ab, was er dazu zu sagen hat.

[cult]

Danke Atilla

Klappt wunderbar genau wie ich es wollte, ja die Zelle in 4 sollte angesprochen werden.

Auch einen Dank an BaskoBiati ich werde mir deine Verbesserungsvoirschläge heute abend genauer anschauen.

Bin sehr begeistert wie schnell das hier ging :D

Mit freundlichen Grüßen

cult

[BoskoBiati]

Hi,

dann reicht immer noch das:

Code:

=(INDEX(L$5:L$1466;HEUTE()-$B$5+1)="")*(L$4<>"")

Arbeitsblatt mit dem Namen '2017'
	L	M	N	O
4	Person 1	Person 2

Zelle	bedingte Formatierung...	Format
L4	1: =(INDEX(L$5:L$1466;HEUTE()-$B$5+1)="")*(L$4<>"")	abc
M4	1: =(INDEX(M$5:M$1466;HEUTE()-$B$5+1)="")*(M$4<>"")	abc
N4	1: =(INDEX(N$5:N$1466;HEUTE()-$B$5+1)="")*(N$4<>"")	abc
O4	1: =(INDEX(O$5:O$1466;HEUTE()-$B$5+1)="")*(O$4<>"")	abc

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg