Bedingte Formatierung und Text im Kalender

[BazzSor]

Hallo Leute,

leider komme ich nicht mehr weiter.

Ich habe einen Kalender erstellt, der auch Feiertage und Ferien darstellen soll. Diese Tage sind auf einem extra Tabellenblatt erfasst.

Die farbliche Kennzeichnung mittels bedingter Formatierung funktioniert sowiet und auch bei den Feiertagen steht in der entsprechenden Zelle der jeweilige Feiertag. Nun möcht eich aber zusätzlich in den farbig markierten Ferientagen auch "Ferien" (mindestens) stehen haben.

Das habe ich mit  der Zählenwenns-Funktion probiert und die Formel an die bestehende angefügt, Trennung mit einem ";". Laut einem Netzbeitrag soll das ja funktionieren...


: machts aber nicht. Ich bekomme da eine Fehlermeldung.

Jetzt hoffe ich, dass Ihr mir weiterhelfen könnt.

viele Grüße

BazzSor

---

Sorry,

die Datei wollte nicht mit.

Hiermit nachgeholt


BazzSor

[steve1da]

Hola,

und wie sollen wir jetzt helfen wenn du nicht mal den Formelversuch nennst?
Hier ist leider niemand der hellsehen kann.

Gruß,
steve1da

[BazzSor]

Hallo steve1da,

sorry - hatte die Datei zwar ausgewählt aber nicht mit eingefügt.

[steve1da]

Hola,

deine Formel für die bed. Formatierung der Feiertage kannst du auch so schreiben:

Code:

=ZÄHLENWENNS('F&F'!$G$7:$G$12;"<="&Planer!M$6;'F&F'!$H$7:$H$12;">="&M$6)

In die Zelle selber dann:

Code:

=wenn(ZÄHLENWENNS('F&F'!$G$7:$G$12;"<="&Planer!M$6;'F&F'!$H$7:$H$12;">="&M$6);"Ferien";"")

Gruß,
steve1da

[BazzSor]

dankeschön.

kann ich diese Formel dann zu der bestehenden einfach hinzufügen ? Oder muss ich die beiden Formeln dann "verschachteln" ?

Gruss BazzSor

[steve1da]

Hola,

nein, du ersetzt deine durch meine, also die für die Ferien.

Wenn du in der Zelle noch den Name der Ferien stehen haben willst an Stelle von "Ferien":

Code:

=WENNFEHLER(INDEX('F&F'!$I$7:$I$12;AGGREGAT(15;6;ZEILE('F&F'!$I$7:$I$12)-6/(('F&F'!$G$7:$G$12<=M$6)*('F&F'!$H$7:$H$12>=M$6));1));"")

Gruß,
steve1da

[BazzSor]

cool

vielen Dank.



Werde das mal gleich übernehmen und dann versuchen deine letzte Formel zu verstehen . ..


Danke nochmal

Gruss BazzSor

---

Hi steve1da,

Deine Formel für die Ferien funktioniert gut.

Nur habe ich dann keine Feiertage mehr angegeben.

Was mache ich falsch ?

Jetzt dachte ich, ich verknüpfe beide Formeln mit der "Oder"-Funktion - aber das war wohl zu "einfältig" ...

=ODER(WENN(ZÄHLENWENNS('F&F'!$G$7:$G$12;"<="&Planer!M$6;'F&F'!$H$7:$H$12;">="&M$6);"Ferien";"");WENN(ZÄHLENWENNS('F&F'!$C$7:$C$18;"<="&M$6;'F&F'!$C$7:$C$18;">="&M$6);"Feiertag";""))



 

BazzSor

[steve1da]

Hola,

wo hast du die Formel denn eingetragen? Wenn du beides in der Zelle stehen haben willst:

Code:

=WENN(ZÄHLENWENNS('F&F'!$G$7:$G$12;"<="&Planer!M$6;'F&F'!$H$7:$H$12;">="&M$6);"Ferien";"")&" "&WENN(ZÄHLENWENNS('F&F'!$C$7:$C$18;"<="&M$6;'F&F'!$C$7:$C$18;">="&M$6);"Feiertag";"")

Ansonsten weiß ich nicht was du mit "Nur habe ich dann keine Feiertage mehr angegeben." meinst.

Gruß,
steve1da

[BazzSor]

Hallo,

momentan steht in in Zeile 1 folgende Formel (M$1) : =WENNNV(SVERWEIS(M$5;'F&F'!$C$7:$D$18;2;FALSCH);""). 

Damit lese ich ja den Feiertag bzw. dessen Bezeichnung aus.

Wenn ich jetzt Deine Formel für die Ferien eintrage überschreibe ich ja nun die  "alte" Formel.  Oder habe ich da etwas missverstanden ?

Die Formeln für die bedingte Formatierung habe ich angepasst - macht so vieles leichter.



Gruss

BazzSor

[steve1da]

Hola,

dann verbinde deinen Sverweis mit meiner Formel mit &:

=WENNNV(SVERWEIS(M$5;'F&F'!$C$7:$D$18;2;FALSCH);"")&" "&WENN(ZÄHLENWENNS('F&F'!$G$7:$G$12;"<="&Planer!M$6;'F&F'!$H$7:$H$12;">="&M$6);"Ferien";"")

Gruß,
steve1da