Bedingte Summierung

[Olivenbaum2013]

Hallo,

ich habe die Frage zu einer Formel bzw. gleich zu mehreren Formeln.

Ich möchte schlicht Ausgaben, die in den jeweiligen Monaten für ein Produkt entstanden sind, addieren. Allerdings sollen nur diejenigen Monaten addiert werden, die bereits gelaufen sind. Welche Monate gelaufen sind, wird durch einen Wert wiedergegeben (s. u. in C9). Dieser Wert ist dann maßgebend für die Addition (=SUMME(D2:??)).
Die Fragezeichen sind eben meine Fragen.

Ich hoffe, das Bild unten gibt zusätzlich Info zu meinem Problem 

[Bild: C:\Users\user\Desktop\Unbenannt.png]
Irgendwie ist es mir gerade ein wenig zuviel.
Doch prinzipiell denke ich, dass die Formel in D9 in Worten wie folgt lauten sollte:
=Summe(D2:Gib Zelle wieder, die sich in der rechten Spalte der gleiche Zeile von (Suche(C9 in C2:C5)) befindet).

Hat jemand von euch eine Idee?

[Jockel]

Hallo, so..:

PHP-Code:

=SUMME(D$2:INDEX(D$2:D$7;VERGLEICH($C$9;$C$2:$C$7;0))) 


oder..:

PHP-Code:

=SUMME(INDEX(D$2:D$7;VERGLEICH($B$9;$C$2:$C$7;0)):INDEX(D$2:D$7;VERGLEICH($C$9;$C$2:$C$7;0))) 


oder..:

PHP-Code:

=SUMME(BEREICH.VERSCHIEBEN(D$2;;;VERGLEICH($C$9;$C$2:$C$7;0))) 


Arbeitsblatt mit dem Namen 'Blatt1'
	B	C	D	E	F
1			Wurst	Käse	Brot
2		Sep.2017	120,00 €	100,00 €	60,00 €
3		Okt.2017	60,00 €	40,00 €	10,00 €
4		Nov.2017	80,00 €	100,00 €	60,00 €
5		Dez.2017	140,00 €	30,00 €	30,00 €
6			10,00 €	40,00 €	10,00 €
7			20,00 €	30,00 €	10,00 €
8
9	Sep.2017	Nov.2017	260,00 €	240,00 €	130,00 €
10			260,00 €	240,00 €	130,00 €
11			260,00 €	240,00 €	130,00 €

Zelle	Formel
D9	=SUMME(D$2:INDEX(D$2:D$7;VERGLEICH($C$9;$C$2:$C$7;0)))
D10	=SUMME(BEREICH.VERSCHIEBEN(D$2;;;VERGLEICH($C$9;$C$2:$C$7;0)))
D11	=SUMME(INDEX(D$2:D$7;VERGLEICH($B$9;$C$2:$C$7;0)):INDEX(D$2:D$7;VERGLEICH($C$9;$C$2:$C$7;0)))

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

[shift-del]

Jörg,

ich hätte hier auf SUMMEWENNS() getippt.

[Jockel]

... ich hätte hier auf SUMMEWENNS() getippt.

Hallo Detlef, so..? Ist für den TS bestimmt (auch) interessant... Zeich mal...

[RPP63]

Kommt drauf an, was in B9:C9 und C2:C5 steht … 
MMM.JJJJ iVm EDATUM()
Dann ist Summewenns() kein Problem!

Ich glaube, ich teste lieber erst … 

Gruß Ralf

[Olivenbaum2013]

Hallo, so..:

PHP-Code:

=SUMME(D$2:INDEX(D$2:D$7;VERGLEICH($C$9;$C$2:$C$7;0))) 


Perfekt,
danke dir.
Diese Formel passt.

[shift-del]

Hallo Detlef, so..? Ist für den TS bestimmt (auch) interessant... Zeich mal...

Gezeicht.

Tabelle1

	B	C	D	E	F
1			Wurst	Käse	Brot
2		Sep 17	120,00 €	100,00 €	60,00 €
3		Okt 17	60,00 €	40,00 €	10,00 €
4		Nov 17	80,00 €	100,00 €	60,00 €
5		Dez 17	140,00 €	30,00 €	30,00 €
6			10,00 €	40,00 €	10,00 €
7			20,00 €	30,00 €	10,00 €
8
9	Sep 17	Nov 17	260,00 €	240,00 €	130,00 €

Formeln der Tabelle

Zelle Formel D9 =SUMMEWENNS(D2:D7;$C2:$C7;"<="&$C9)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8