Berechnung von Mittelwerten unter Bedingungen für mehrere Tabellenblätter

[excelnoob1]

Hallo!

Ich würde gerne über ca. 70 identische Tabellenblätter bestimmte Mittelwerte berechnen. Die Blätter repräsentieren jeweils die Reaktionszeiten von Personen in bestimmten Bedingungen. Ich habe also in Spalte A alle Reaktionszeiten (RZ) und in den folgenden Spalten die jeweiligen Bedingungen in 0en und 1en (0= Bedingung 1, 1=Bedingung 2 etc.)

Was ich nun will ist jetzt das der Mittelwert für RZ für die die Bedingung 0 zutrifft errechnet wird und für solche für die Bed. 1 zutrifft etc. Das hab ich mit "MITTELWERTWENN" für ein einzelnes Tabellenblatt auch geschafft aber da ich nicht unbedingt 70 mal dasselbe klicken will wäre es effizienter wenn es eine Möglichkeit gäbe alle Mittelwerte für die jeweiligen Bedingungen in einem extra Tabellenblatt zusammenzufassen.

Gibts da irgendeine tolle Lösung dafür? Ich weiß das "MITTELWERTWENN" nicht für 3D referencing geeignet ist, hab aber auch wenig hilfreiches im Netz gefunden was auf meinen Fall zutrifft.

Wäre für Hilfe sehr dankbar! :D

[Peter]

Hallo,

Das hab ich mit "MITTELWERTWENN" für ein einzelnes Tabellenblatt auch geschafft

als Idee und ungetestet unter der Voraussetzung, dass die Tabellenblätter identisch aufgebaut sind.

Ich würde die Tabellenblätter gruppieren und dann die Formel für Mittelwertwenn() eingeben. Bei gruppierten Tabellenblätter sollte die Formel auf allen Tabellenblättern in der gleichen Zelle stehen.

In einem separaten Tabellenblatt würde ich in der Spalte A die Tabellenblätter automatisch formelmäßig aufführen und in der Spalte B mit Indirekt() die Werte abfragen:

=INDIREKT(A1&"!Z1")

wobei Z1 die Zelle darstellt in der die Mittelwertwenn-Formel steht.

[excelnoob1]

Das mit dem gruppieren krieg ich hin das mit den Blättern aufführen versteh ich aber nicht ganz wie man das macht.

[Peter]

Hallo,

um in Spalte A die Tabellenblätter aufzulisten könntest du wie folgt vorgehen:

Zunächst einen Name definieren über Formeln - Gruppe Definierte Namen - Namen definieren.

Im Feld 'Namen in der Arbeitsmappe:' gibst du ein x (Buchstabe x) ein

Und in das Feld 'Bezieht sich auf' kopierst du folgende Formel:

=ARBEITSMAPPE.ZUORDNEN(1+0*JETZT())

Dann in der Übersichtsseite in irgendeine Zelle diese Formel eingeben:

=WENN(ZEILE(A1)>ANZAHL2(x);"";HYPERLINK("#'"&INDEX(x;ZEILE(A1))&"'!A1";TEIL(INDEX(x;ZEILE(A1));FINDEN("]";INDEX(x;ZEILE(A1)))+1;31)))

und nach unten kopieren (weiter als die Anzahl der Blätter - falls noch irgendwann neue hinzukommen). Somit listet man alle Blätter auf und verlinkt sie auch gleichzeitig.

Wenn du die Blätter nicht verlinken willst ändere die Formel so ab:

=WENN(ZEILE(A1)>ANZAHL2(x);"";TEIL(INDEX(x;ZEILE(A1));FINDEN("]";INDEX(x;ZEILE(A1)))+1;31))

Und jetzt kannst du mit Indirekt den Tabellenblattnamen in Spalte A verwenden.