Bestimmte Werte ausgeben mit Bedingung

[infostud]

Hallo zusammen,

ich habe folgende Tabelle im Anhang.
Je nach Auswahl in der Dropdownliste (Monate) sollen bestimmte Werte berechnet werden.
Für WoTa und WoEnd bin ich gerade sehr ratlos, wie ich dies bewerkstelligen kann.

Beispiel: Wenn in A2 der März gewählt wird, soll auch in der Liste A5 bis A25 auch nur die Anzahl der Wochenenden im März berechnet werden.

=SUMME(--(WOCHENTAG(A5:A25;16)>5))
Hier müsste der Bereich gewählt werden!?! Je nach Auswahl

viellecht habt ihr Tipps für mich.

VG infostud

---

ich habe es gelöst, da ich eine intelligente Tabelle nutze, konnte ich die Spalte so auswählen.

VG

[infostud]

Hallo zusammen,

leider ist mir das Problem nochmals auf den Weg getreten.

Im Anhang habe ich zur Übersicht eine Tabelle eingefügt:

Ich möchte die Wochentage zählen, ohne Feiertage abhängig auf den in A2 gewählten Monat.
Nur Wochentage eines Monats kann ich zählen.
Alle Feiertage in der Tabelle kann ich auch zählen.

Und diese zwei muss ich zusammenbringen, so dass mir bei Auswahl des Monats in A2 die Anzahl vorhandene Wochentage (ohne Feiertage) angezeigt wird.

Würde mich freuen auf Hinweise, wo mein Denkfehler steckt.

LG
infostud

[HKindler]

Hi,

bei aktuellem Excel:
=SUMMENPRODUKT((TEXT(Tabelle1[Datum];"MMMM")=A2)*(WOCHENTAG(Tabelle1[Datum];2)<6)*ISTFEHLER(XVERGLEICH(Tabelle1[Datum];Tabelle2!$D$2:$D$12;0;2)))

Bei deiner Version musst du statt XVergleich() den herkömmlichen Vergleich() nehmen und auf die Binärsuche (alphabetische Reihenfolge) verzichten, damit wird die Formel bei vielen Feiertagen aber langsam.

[infostud]

Hallo Helmut,

vielen Dank für deinen Code.

Das hat mir schon weitergeholfen.
Nun habe ich die Gegenseite noch zu lösen, da komm ich leider nicht weiter.

Diesmal möchte ich die Wochenende+Feiertage zählen.

=SUMMENPRODUKT((Tabelle1[Datum]<>"")*(TEXT(Tabelle1[Datum];"MMMM")=A2)*(WOCHENTAG(Tabelle1[Datum];16)<3)*AnzahlFeiertage)

AnzahlFeiertage:
=SUMMENPRODUKT((ZÄHLENWENN(Tabelle1[Datum];Tabelle2!$A$2:$A$12)))

Aber so:
=SUMMENPRODUKT((Tabelle1[Datum]<>"")*(TEXT(Tabelle1[Datum];"MMMM")=A2)*(WOCHENTAG(Tabelle1[Datum];16)<3)*(ZÄHLENWENN(Tabelle59[Datum];Feiertage!$A$2:$A$12)))

bekomme ich #NV   

Hast du dazu eine Idee?

Vielen Dank und schöne Grüße
infostud

[HKindler]

Hi,

1. Tabelle1[Datum]<>"" sollte eigentlich überflüssige sein. Zumindest in deiner Beispieldatei ist immer ein Datum und ohne Datum hast du so oder so eine leere Zeile (was anderes macht schließlich keinen Sinn). Und leere Zeilen sind in Listen "verboten".

2. wenn du nur WE zählen willst, dann brauchst du WOCHENTAG(Tabelle1[Datum];2)>=6

3. wenn du nur Feiertage zählen willst: NICHT(ISTFEHLER(XVERGLEICH(Tabelle1[Datum];Tabelle2!$D$2:$D$12;0;2)))

4. Wenn du Feiertage + WE zählen willst (aber einen Feiertag an einem WE nur einfach und nicht doppelt): ((WOCHENTAG(Tabelle1[Datum];2)>=6)+(NICHT(ISTFEHLER(XVERGLEICH(Tabelle1[Datum];Tabelle2!$D$2:$D$12;0;2))))>0

Somit ergibt sich als Formel für die Anzahl Tage, die an einem WE oder an einem Feiertag gearbeitet wurde:
=SUMMENPRODUKT((TEXT(Tabelle1[Datum];"MMMM")=A2)*((WOCHENTAG(Tabelle1[Datum];2)>=6)+(NICHT(ISTFEHLER(XVERGLEICH(Tabelle1[Datum];Tabelle2!$D$2:$D$12;0;2))))>0))


Alternativ funktioniert bei aktuellem Excel auch die FILTER-Variate:
=ZEILEN(FILTER(Tabelle1[Datum];(TEXT(Tabelle1[Datum];"MMMM")=A2)*((WOCHENTAG(Tabelle1[Datum])>=6)+NICHT(ISTFEHLER(XVERGLEICH(Tabelle1[Datum];Tabelle2!$D$2:$D$12;0;2))))))

[infostud]

Hallo Helmut,

vielen Dank für deine Hilfe!
Hat mir sehr geholfen. Manchmal sieht man den Wald vor lauter Bäumen einfach nicht.

Viele Grüße
infostud