Bestimmte Worte in anderer Tabelle wiedergeben

[wernqq]

Hey,

Ich habe schon einiges mit =TEIL() , =SUCHEN() und =FINDEN() probiert aber ich hab leider nichts hinbekommen :(
Mein Problem:
Ich habe eine Tabelle in der Namenskürzeln (RT, RZ, WS, WR, GD, etc...) eingetragen werden. Diese Werte sollen nochmals automatisch in eine danebenstehende Tabelle sortiert wiedergegeben werden.
Dabei sollen die Namen nach ihren Anfangsbuchstaben in Spalten gruppiert werden (Es gibt nur R, W, G als Anfangsbuchstaben.)

also:

Namen    R      W     G
RT          RT    WS   GD
RZ          RZ    WR
WS
WR
GD


PS: R,W,G steht für rot, weiss, grün. Vielleicht wird dadurch der Sinn der Sortier-Tabelle deutlicher



Ich hoffe es ist verständlich was ich meine :)
MFG

[shift-del]

Hallo

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Namen		R	W	G
2	RT		RT	WS	GD
3	RZ		RZ	WR
4	WS
5	WR
6	GD

Zelle	Formel
C2	=WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE($A$2:$A$6)/(LINKS($A$2:$A$6)=C$1);ZEILE(A1)));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[wernqq]

WOW Danke es funktioniert  :18:
vielen vielen Dank :)

Und würdest du mir weiter helfen?

1.) Zu den "R", "W", "G" Spalten soll noch eine "Andere"-Spalte kommen, in der alle anderen Abkürzungen ohne ein großes "R", "W", "G" augelistet werden sollen. also Kürzel mit allen anderen Anfangsbuchstaben und kleingeschriebene "r","w","g" als Anfangsbuchstaben.

2.) Zusätzlich möchte ich den Abkürzungen ihre vollen Namen zuweisen. Ich dachte ich bekomme es einfacher hin, aber daran scheitere ich ebenfalls :s :s
Also die Abkürzungen haben ihre vollen Namen in der Hauptliste zugewiesen. Jetzt sollen die vollen Namen den Abkürzungen in der sortierten Listen zugeordnet werden.
Ich könnte zwar die selbe Funktion anweden, aber die Reihenfolge muss ja gleich bleiben, also der volle Name muss ja abhängig von der Abkürzung in die selbe Zeile zugeordnet werden.

Namen Abkz          R-Name   R-Abkz         S-Name    R-Abkz
aaa       RW             aaa          RW            SW            ccc
abc       RT              abc           RT             SF             ddd
ccc        SW
ddd       SF
etc..      ....

 oder soll ich dafür ein neuen Thread eröffnen? 


Ich würde mich riesig über eine Hilfestellung freuen :))  

[WillWissen]

Hi,

1.) Zu den "R", "W", "G" Spalten soll noch eine "Andere"-Spalte kommen, in der alle anderen Abkürzungen ohne ein großes "R", "W", "G" augelistet werden sollen. also Kürzel mit allen anderen Anfangsbuchstaben und kleingeschriebene "r","w","g" als Anfangsbuchstaben.

zu dieser Frage kann ich dir aktuell aus Zeitgründen keine Lösung bieten. Im Moment wird mit shift-dels Formel Groß- und Kleinschreibung ignoriert.

2.) Zusätzlich möchte ich den Abkürzungen ihre vollen Namen zuweisen.

Hierzu schaue dir mal den SVERWEIS an.

Tabelle3

	A	B	C	D	E	F	G	H	I	J
1	Namen	R	R-Name	W	W-Name	G	G-Name		Kürzel	Namen
2	RT	RT	aaa	WS	ccc	GD	eee		RT	aaa
3	RZ	RZ	bbb	WT	ddd				RZ	bbb
4	WS								WS	ccc
5	WT								WT	ddd
6	GD								GD	eee

Formeln der Tabelle

Zelle Formel B2 =WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE($A$2:$A$16)/(LINKS($A$2:$A$16)=B$1);ZEILE($A1)));"") C2 =WENNFEHLER(SVERWEIS(B2;$I$2:$J$6;2;0);"") D2 =WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE($A$2:$A$16)/(LINKS($A$2:$A$16)=D$1);ZEILE($A1)));"") E2 =WENNFEHLER(SVERWEIS(D2;$I$2:$J$6;2;0);"") F2 =WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE($A$2:$A$16)/(LINKS($A$2:$A$16)=F$1);ZEILE($A1)));"") G2 =WENNFEHLER(SVERWEIS(F2;$I$2:$J$6;2;0);"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Mal noch eine generelle Anmerkung:

Es ist immer sinnvoller, gleich von Anfang an das komplette Problem zu schildern, als nach der Salamitaktik scheibchenweise Lösungen zu erfragen. Man erspart sich u.U. eine Menge zusätzlicher Arbeit.

[shift-del]

Man erspart sich u.U. eine Menge zusätzlicher Arbeit.

Vor allem erspart man den Helfern eine Menge zusätzlicher Arbeit.
Ich warte jedenfalls erst mal auf ein komplettes Beispiel.

[wernqq]

Ja, es tut mir auch wirklich leid. Normalerweise gehöre ich zu denen die ihre Fragen super lang und ausführlich ausführen, aber ich dachte mir ich versuche es kurz zu halten, und hab da auch noch nicht an die nächsten Schritt gedacht, bzw. dachte ich, dass ich es dann selber hinbekomme...

Erstmal an ganz dickes Dankeschön an WillWissen, deine Lösung mit SVERWEIS funktioniert perfekt. :17:


Falls ihr dennoch meine andere Frage beantwortet wollt:
In der linken Eingabe Tabelle kommen auch Kürzel & Namen vor, die nicht R, W, G zugewiesen werden sollen, sondern under "Andere" geordnet werden sollen. Also im Prinzip alle Anfangsbuchstaben außer R, W, G. Aber es könnten auch Namen mit R, W, G vorkommen, die allerdings nicht in diese Spalten gehören, sondern ebenfalls in die "Andere"-Spalte.  Diese besitzen ein kleines r, w, oder g..
(ich spare mir mal die meisten Beispielwerte von davor) also ich stelle es mir so vor:
 
                           andere 
Abkz   Name      Abkz    Namen       R      R-Namen  etc..
RT       aaa          SV          ddd       RT       aaa
WS      bbb          AZ          eee        
GD       ccc          rZ             fff
SV       ddd
AZ       eee    
rZ         fff

Ich hoffe das ist nicht zu kompliziert. :/ (Falls doch könnte man auch das mit den kleinen r, w, g notfalls weglassen, das muss ich dann anders umgehen)

[shift-del]

Hallo

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G	H	I	J	K
1	Abk	Name		Andere Abk	Andere Namen	R	R Namen	W	W Namen	G	G Namen
2	RT	aaa		SV	ddd	RT	aaa	WS	bbb	GD	ccc
3	WS	bbb		AZ	eee
4	GD	ccc		rZ	fff
5	SV	ddd
6	AZ	eee
7	rZ	fff

Zelle	Formel
D2	=WENNFEHLER(INDEX(A:A;AGGREGAT(15;6;ZEILE($A$2:$A$7)/(1-ZÄHLENWENN($F$2:$J$7;$A$2:$A$7));ZEILE(A1)));"")
E2	=WENNFEHLER(SVERWEIS(D2;$A$2:$B$7;2;FALSCH);"")
F2	=WENNFEHLER(INDEX($A:$A;AGGREGAT(15;6;ZEILE($A$2:$A$7)/(CODE(LINKS($A$2:$A$7))=CODE(F$1));ZEILE($A1)));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[wernqq]

Wow vielen vielen dank. hat alles funktioniert. Ich wünsche noch einen schönen abend :) :17: