Besucherliste im Excel

[Ischake]

Hallo Excel-Freunde,

ich bekomme es leider nicht hin und hoffe ich bekomme hier Hilfe.

Ich möchte eine Art "Besucher-Buch" für einen Besprechungsraum erstellen.

Im Tabellenblatt 1 werden in den Zellen C8 - C10 - C12 - C14 - C16 diese Daten eingegeben: Datum - Firma - Name - Uhrzeit - Bemerkung.

Sobald dann die Besprechung vorbei ist möchte ich, dass durch einen Klick auf ein Button die ganzen Informationen ins Tabellenblatt 2 wandern.

Nach dem ersten Besuch in die Zellen A2-B2-C2-D2-E2
Nach dem zweiten Besuch in die Zellen A3-B3-C3-D3-E3
usw...
und dort dann immer gespeichert werden als Archiv.

Wenn die Liste dann geöffnet wird muss das erste Tabellenblatt natürlich leer sein.

Ich hoffe es ist verständlich erklärt und freu mich auf Lösungen.

Danke vorab......

Grüßle

[Kuwer]

Hallo,

in das schon vorhandene VBA-Modul "DieseArbeitsmappe" kommt folgender Code:

Code:

'Modul DieseArbeitsmappe
Private Sub Workbook_Open()
 Tabelle1.Select
 Tabelle1.Range("C8,C10,C12,C14,C16") = ""
End Sub

In ein neuese allgemeines VBA-Modul kommt dieser Code:

Code:

'allgemeines Modul (Modul1)
Sub Schaltflaeche_Klicken()
 With Tabelle1.Range("C8,C10,C12,C14,C16")
   .Copy
   Tabelle2.Cells(Rows.Count, 1).End(xlUp).Offset(1).PasteSpecial _
               Paste:=xlPasteValuesAndNumberFormats, Transpose:=True
   .ClearContents
 End With
End Sub

Im Excel fügst Du in Tabelle1 eine Schaltfläche(Formularsteuerelement), zu finden unter Entwicklertools/Einfügen, ein und weist dieser das Makro zu.

[Ischake]

Hallo Kuwer,

genau so brauche ich es.

Vielen vielen Dank!!!!!

[Rabe]

Hu Uwe,

Code:

'Modul DieseArbeitsmappe
 Tabelle1.Range("C8,C10,C12,C14,C16") = ""

ist das = "" besser als .ClearContents?

[Kuwer]

Hi Ralf,

ist das = "" besser als .ClearContents?

100 pro!

Code:

Sub aaa()
 With Worksheets.Add
   Range("B2:C2").Merge
   Range("A1:C4").Value = "x"
   On Error Resume Next
   Range("B1:B4").ClearContents
   If Err.Number > 0 Then
     MsgBox "Versuch, Range(""B1:B4"") zu leeren." & String(2, vbNewLine) & Err.Number & ": " & Err.Description, vbExclamation
     Err.Clear
   End If
   Range("B1:B4") = ""
 End With
End Sub

Gruß Uwe

[Rabe]

Hi,

100 pro!

ok!

Aber verbundene Zellen sind doch eh Mist. ;)

[schauan]

Hallo Ralf,

der Befehl heißt aber
Range("B2:C2").Merge
und nicht
Range("B2:C2").Merde

:17: