Brauche Hilfe bei mehreren Wenn(Und) Verknüpfungen

[dzae]

Hallo zusammen
Versuche verzweifelt eine Lösung zu finden
Es geht um folgende Formeln

=WENN(UND(B5="NT01";E5="X");(D5*15,6)/60;(D5*7,8)/60)
=WENN(UND(B5="NT01-Z";E5="X");(D5*18)/60;(D5*9)/60)
=WENN(UND(B5="NT05";E5="X");(D5*19,8)/60;(D5*9,9)/60)

einzeln funktionieren sie einwandfrei doch wie  verknüpfe ich diese 3 Formeln miteinander

Vielen Vielen Dank für Euere Hilfe
Dieter

[WillWissen]

Hi

Code:

=WENN(UND(B5="NT01";E5="X");(D5*15,6)/60;WENN(UND(B5="NT01-Z";E5="X");(D5*18)/60;WENN(UND(B5="NT05";E5="X");(D5*19,8)/60;(D5*9,9)/60)))

[shift-del]

Oder so:

Code:

=SUMME((B5={"NT01";"NT01-Z";"NT05"})*{15,6;18;19,8})/(2-(E5="X"))*D5/60

[lupo1]

Schöne Lösung der SUMME mit Ausschlussmengen!

=SUMME((B5={"NT01";"NT01-Z";"NT05"})*{15,6;18;19,8})/(2-(E5="X"))*D5/60

vielleicht noch kürzer so (ungetestet):

=SUMME((B5="NT0"&{1;"1-Z";5})*{26;30;33})/(2-(E5="X"))*D5%

1. Es bleibt aber festzuhalten, dass sich die SONST der 3 Bed. in der Fragestellung überlappen. Die Priorität muss also noch geklärt werden.
   
2. Und was ist bei SUMME 0? Auch dafür gelten ja die SONST. Die ergeben jetzt aber 0, was strenggenommen nicht stimmt, zumindest, wenn die Einzel-WENNs oben stimmen.
   

[dzae]

Hallo an Euch
Vielen Dank für Euere schnelle Hilfe
Hat super geklappt, hätte jedoch noch ne Anschluss Frage
Wie erreiche ich das wenn in D5 nichts steht auch die Zelle mit der Rückmeldung leer bleibt

Gruss Dieter

[lupo1]

als Standard;Standard; ben.def. formatieren

[dzae]

als Standard;Standard; ben.def. formatieren

Sorry versteh ich nicht

[dzae]

Habs so gelöst

=WENN(E5="";"";SUMME((C5={"NT01";"NT01-Z";"NT05"})*{15,6;18;19,8})/(2-(F5="X"))*E5/60)

Danke

[lupo1]

Klar, mit der "Unterdrückungsmethode" geht es natürlich auch. ;)

Nur bekommt man leicht Probleme beim Weiterverarbeiten.