Code Optimierung - Mein Projekt

[Steffl]

Hallo,

das liegt an dieser Codezeile

Code:

rngFind.Offset(0, 11).Value = WorksheetFunction.Proper(TextBox11.Text)              'Vermerk

aus dem CommandButton5_Click-Code. Aus der OH zu Proper

Wandelt den ersten Buchstaben aller Wörter einer Zeichenfolge in Großbuchstaben um. Wandelt alle anderen Buchstaben in Kleinbuchstaben um.

[sandormiles]

Danke Stefan, wieder was gelernt... "WorksheetFunction" dürfte gänzlich überflüssig bei meiner UserForm sein.

[sandormiles]

Nächste Frage... zum PDF erstellen... Mit dem nachfolgenden Makro erstelle ich ein PDF-Dokument. Funktioniert auch so grundsätzlich. Eine Sache ist allerdings komisch, klicke ich im Fenster "Speichern unter" auf "Abbrechen" legt er trotzdem ein Dokument an. Der Code sieht so aus...

Code:

Rem Hier beginnt Makro1
Sub Beleg_Widerspruchszwueisung()
Dim pdfName As String, DtTxt As String, UserTxt As String

   DtTxt = Format(Date, "DD-MM-YYYY")
   UserTxt = Application.UserName
   
pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & "Beleg Widerspruchszuweisung" & "_" & DtTxt & "_" & UserTxt & ".pdf", "PDF-Dateien (*.pdf), *.pdf")

Sheets("Beleg").ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
                         Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintareas:=False, _
                         OpenAfterPublish:=True


End Sub

Der Code befindet sich im Modul "Modul1000000".

[Steffl]

Hallo,

mal ungetestet

Code:

Rem Hier beginnt Makro1
Sub Beleg_Widerspruchszwueisung()
Dim pdfName As String, DtTxt As String, UserTxt As String

   DtTxt = Format(Date, "DD-MM-YYYY")
   UserTxt = Application.UserName
  
pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & "Beleg Widerspruchszuweisung" & "_" & DtTxt & "_" & UserTxt & ".pdf", "PDF-Dateien (*.pdf), *.pdf")

If pdfName <> False Then
Sheets("Beleg").ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
                         Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintareas:=False, _
                         OpenAfterPublish:=True
End If

End Sub

[snb]

Ein PDF in Excel erstellt man mit .exportofixedformat

[RPP63]

Moin!

Sub RPP()
strBullshit = "exportofixedformat"
strCorrect = "ExportAsFixedFormat"
strBullshit = strCorrect
Debug.Print strBullshit
End Sub

:21:

Gruß Ralf

[sandormiles]

Die Lösung liegt irgendwo dazwischen...

Bekomme aktuell einen Laufzeitfehler. Der Code "If pdfName <> False Then" wird mit "Laufzeitfehler '13': Typen unverträglich" angezeigt. Ich schau morgen erst nochmal selbst, was mir das sagen soll.

Grüße zum Abend

[Steffl]

Hallo,

dann ändere mal den Variablentyp

Code:

Rem Hier beginnt Makro1
Sub Beleg_Widerspruchszwueisung()
Dim pdfName As Variant, DtTxt As String, UserTxt As String

    DtTxt = Format(Date, "DD-MM-YYYY")
    UserTxt = Application.UserName
    
pdfName = Application.GetSaveAsFilename(Environ("USERPROFILE") & "\Desktop\" & "Beleg Widerspruchszuweisung" & "_" & DtTxt & "_" & UserTxt & ".pdf", "PDF-Dateien (*.pdf), *.pdf")

If pdfName <> False Then
Sheets("Beleg").ExportAsFixedFormat Type:=xlTypePDF, Filename:=pdfName, _
                          Quality:=xlQualityStandard, IncludeDocProperties:=False, IgnorePrintareas:=False, _
                          OpenAfterPublish:=True
End If

End Sub

Gruß Stefan

[snb]

Code:

Sub Beleg_Widerspruchszwueisung()
   Sheets("Beleg").ExportAsFixedFormat 0, createobject("wscript.shell").specialfolders(12) & "Beleg Widerspruchszuweisung_" & format(date,"dd-mm-yyyy_") & application.username & ".pdf"
End Sub

[sandormiles]

Danke euch beiden!

@snd: Dein "schmaler" Code hat was, funktioniert bei mir aber nicht. Aber danke für die Idee!

Grüße und schönen Abend!