DATUM: Anzahl 15. des Monats bis heute

[Sulprobil]

Oder die Variante.
=DATEDIF(DATUM(JAHR($P$12);MONAT($P$12);1);1+MONATSENDE(P13;0);"M")-(TAG($P$12)>15)-(TAG(P13)<15)

P12 = start; P13 = Ende

Gruß Elex

Elex' Lösung hat keinen mir bekannten Fehler. :78:
Meine hat leider einen.
Und Newcomer's auch:
31.5.2020 - 9.10.2020 ergibt bei ihm 3, muss aber 4 sein.

[Kuwer]

Hallo,

vielleicht ginge diese auch durch?

=VRUNDEN(ABS((MONATSENDE(B1;-1)-MONATSENDE(A1;0))/30+(TAG(A1)<16)+(TAG(B1)>14));1)

Gruß Uwe

[Fred11]

oder so (auch ohne DATEDIF):

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Startdatum:	15.02.2020		Stichtag	15
2	Enddatum	23.11.2020
3
4	Anzahl:	10

Zelle	Formel
B4	=MONAT($B$2)-MONAT($B$1)-1+(TAG($B$1)<=$E$1)+(TAG($B$2)>=$E$1)+(JAHR($B$2)-JAHR($B$1))*12

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

(Die Formel von Uwe rechnet nicht ganz richtig, wenn zwischen Start- und Enddatum mehrere Jahre liegen)

Gruß
Fred

[Kuwer]

Hallo Fred,

(Die Formel von Uwe rechnet nicht ganz richtig, wenn zwischen Start- und Enddatum mehrere Jahre liegen)

stimmt. Die 30 müsste 30,4375 sein:    =VRUNDEN(ABS((MONATSENDE(B1;-1)-MONATSENDE(A1;0))/30,4375+(TAG(A1)<16)+(TAG(B1)>14));1)
Aber Deine Formel ist besser. :28:

Gruß Uwe

[Sulprobil]

oder so (auch ohne DATEDIF):

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	Startdatum:	15.02.2020		Stichtag	15
2	Enddatum	23.11.2020
3
4	Anzahl:	10

Zelle	Formel
B4	=MONAT($B$2)-MONAT($B$1)-1+(TAG($B$1)<=$E$1)+(TAG($B$2)>=$E$1)+(JAHR($B$2)-JAHR($B$1))*12

Verwendete Systemkomponenten: [Windows (32-bit) NT 6.02] MS Excel 2010

Diese Tabelle wurde mit Tab2Html (v2.6.0) erstellt. ©Gerd alias Bamberg

(Die Formel von Uwe rechnet nicht ganz richtig, wenn zwischen Start- und Enddatum mehrere Jahre liegen)

Gruß
Fred

Fred's Formel hat mit dem 15. auch kein Problem (soweit ich testen konnte), aber mit dem Stichtag 29 haperts in Nicht-Schaltjahren über Ende Februar hinweg

[newcomer]

Hallo Zusammen, 

noch eine Variante mit Indirekt:

=SUMME(N(TAG(ZEILE(INDIREKT(A1&":"&A2)))=15))

oder für 365:

=SUMME(N(TAG(SEQUENZ(A2-A1+1;;A1))=15))


Gruß


Christian

[RPP63]

Sehr schön, Christian!
Du hattest allerdings zu erwähnen vergessen, dass die erste Formel mittels Strg+Umschalt+Enter abgeschlossen werden muss.

Excel365 erkennt diese Funktionalität automatisch und braucht diesen Abschluss (auch im ersten Fall!) nicht.

Gruß Ralf

[snb]

PHP-Code:

=SUMPRODUCT(N(DAY(ROW(OFFSET(A15;;;A16-A15+1)))=15)) 


[schauan]

@snb

?

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B
15	16. Nov
16	14. Dez	1

Zelle	Formel
B16	=SUMMENPRODUKT(N(TAG(ZEILE(BEREICH.VERSCHIEBEN(A15;;;A16-A15+1)))=15))

Verwendete Systemkomponenten: [Windows (32-bit) NT 10.00] MS Excel 2016

Diese Tabelle wurde mit Tab2Html (v2.6.2) erstellt. ©Gerd alias Bamberg

[RPP63]

Fieser Möpp, André!  :19:
Selbst bei leeren Zellen in A15:A16 kommt logischer Weise bei snb eine 1 heraus.
Schließlich ist TAG(ZEILE(A15)) immer 15

	A	B
15
16		1

Zelle	Formel
B16	=SUMMENPRODUKT(N(TAG(ZEILE(BEREICH.VERSCHIEBEN(A15;;;A16-A15+1)))=15))

:21:

Man könnte ja noch ein INDEX(A:A) drumrum schleifen, aber dann finde ich die Formeln von Christian smarter!

Gruß Ralf