Datei erzeugen falls diese nicht vorhanden ist

[Eisbär]

Hi,

ich möchte prüfen, ob in einem bestimmten Verzeichnis eine xlsm - Datei vorhanden ist.

Wenn nicht, soll diese erzeugt werden. Wie geht das mit VBA?

If Not "C:\Testordner\Beispiel.xlsm Then Create Beispiel.xlsm

[Steffl]

Hallo,

vielleicht so?

Code:

Sub Vorhanden_Datei()
    'von Hajo
    If Dir("C:\Testordner\Beispiel.xlsm") <> "" Then
        MsgBox "Datei vorhanden"
    Else
        Workbooks.Add
    End If
End Sub

[Eisbär]

Hallo Stefan,

geht (zumindest bei mir) leider nicht.

Was geht ist folgendes:

Code:

Sub Datei_erzeugen()
Dim Wkbk As Workbook
Dim ExcelApp As Excel.Application
Set ExcelApp = CreateObject("Excel.Application")
Set Wkbk = Excel.Application.Workbooks.Add
Wkbk.SaveAs "C:\Test\Beispiel.xls"
End Sub

Den Kokolores ob Datei vorhanden ist oder nicht etc. ersparen wir uns hier mal.
Was ich bisher nicht hinkriege, ist die Erzeugung einer xlsm Datei.
Außerdem ist die erzeugte Datei Beispiel.xls offen. Das muss ja nicht sein.
Gibt also noch einiges zu verschönern.

[Steffl]

Hallo,

Was ich bisher nicht hinkriege, ist die Erzeugung einer xlsm Datei.

gebe den dazu passenden Parameter mit an

Code:

Wkbk.SaveAs ThisWorkbook.Path & "\Beispiel", 52

[Kuwer]

Hallo,

Sub Vorhanden_Datei()
    Dim strDatei As String
    strDatei = "C:\Testordner\Beispiele.xlsm"
    If Dir(strDatei) = "" Then
        With Workbooks.Add
            .SaveAs strDatei, 52
            .Close
            MsgBox strDatei & " wurde erstellt.", vbInformation
        End With
    Else
        MsgBox strDatei & " ist vorhanden.", vbInformation
    End If
End Sub

Gruß Uwe

[Eisbär]

Danke für eure Hilfe.
An Uwe ein Extra-Dankeschön. Schöner, besser und effizienter als meine eigene Erstlösung.