Daten aus Liste in Kalender eintragen

[Thomas78]

Hallo zusammen,

ich hab da mal wieder ne Frage:

Ich habe beiliegende Exeltabelle erstellt. Die Übersicht auf der linken Seite soll mir die entsprechenden Daten aus der rechten Seite anzeigen. 
Im Beispiel sollte er mir am 01.07.2017 in Zelle B4 die Werte "8025 tacho" anzeigen. Dies funktioniert mit meiner Formel auch.
Allerdings soll er in Zelle B5 den nächsten Wert für das Datum, sprich "8027 tüv" anzeigen.
Daran scheitert mein bisheriges Excelwissen...

Ich vermute das ich mit Index und Kkleinste evtl. weiterkomme (?), allerdings habe ich keine Ahnung wie.

Ich wäre für Hilfe sehr dankbar.

Vielen Dank und schöne Grüße

Thomas

[neopa]

Hallo Thomas,

in B4: =WENNFEHLER(INDEX($L$1:$L$99&" "&$M$1:$M$99;AGGREGAT(15;6;ZEILE($K$1:$K$99)/($K$1:$K$99=B$3);ZEILE(B1)));"")

und Formel nach unten und rechts kopieren.

[Thomas78]

Hallo Werner,

vielen Dank für die schnelle Hilfe!
Deine Formel funktioniert perfekt. Ich werde sie mir mal in Ruhe anschauen und versuchen zu verstehen.

Schöne Grüße Thomas

[neopa]

Hallo Thomas,

bei Deiner momentanen Datenstruktur (Datumsangaben in Zeile 3 und danach diese jede 6 Zeile) kannst Du folgende etwas erweiterte Formel in B4:

=WENNFEHLER(INDEX($L$1:$L$99&" "&$M$1:$M$99;AGGREGAT(15;6;ZEILE($K$1:$K$99)/($K$1:$K$99=INDEX(B:B;ZEILE()-REST(ZEILE(J7);6)));REST(ZEILE(J7);6)));"")

einkopieren und nach rechts und unten kopieren und dann kannst Du anschließend den gesamten Datenblock B4:B8 nach B10:H14 usw. kopieren ohne dort nochmal entsprechende Anpassungen an der Formel vornehmen zu müssen, wie das bei meinem ersten Vorschlag noch der Fall gewesen wäre.

Solltest Du mehr als 5 Datenzeilen je Tag vorsehen wollen, so muss lediglich der Formelteil REST(ZEILE(J7);6) entsprechend angepasst werden.

[kadrleyn]

I recommend that you review kalender (calendar) template about thread : https://youtu.be/5mb9pse4694
[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

[Thomas78]

Hello kadrleyn,

thanks for your tip. I will try it out!

Hallo Werner,

danke für deinen Nachtrag, ich werds mir mal anschauen.

Eine Frage habe ich allerdings noch:
Wenn ich die Daten in einem anderen Tabellenblatt habe und die Formel abändere holt er mir die Daten nicht.
Funktioniert das mit Index nicht?

Ich habs mit 
=WENNFEHLER(INDEX(Terminliste!$C$6:$C$35&" "&Terminliste!$D$6:$D$35;AGGREGAT(15;6;ZEILE(Terminliste!$B$6:$B$35)/(Terminliste!$B$6:$B$35=B$3);ZEILE(B1)));"")
und auch mit
=WENNFEHLER(INDEX(MitarbeiterFahrzeug&" "&Thema;AGGREGAT(15;6;ZEILE(Datum)/(Datum=B$3);ZEILE(B1)));"")
also Tabelle mit Namensbereich probiert.

Kannst du mir hier nochmal helfen?

Schöne Grüße Thomas

[steve1da]

Hola,

so?

Code:

=WENNFEHLER(INDEX(Terminliste!$C$6:$C$35&" "&Terminliste!$D$6:$D$35;AGGREGAT(15;6;ZEILE(Terminliste!$B$6:$B$35)-5/(Terminliste!$B$6:$B$35=B$3);ZEILE(B1)));"")

Gruß,
steve1da

[Thomas78]

Hallo steve1da,


aaaaaah ich muss Excel also noch sagen das er die ersten 5 Zeilen nicht berücksichtigt?

Deine Formel funktioniert einwandfrei!

Vielen Dank!

[steve1da]

Hola,

nein, du musst Excel sagen, wie groß der Bereich ist, den die Formel abdecken soll. 

Code:

Terminliste!$C$6:$C$35

 
umfasst 30 Zeilen. An Stelle von 

Code:

ZEILE(Terminliste!$B$6:$B$35)-5

hätte ich auch

Code:

ZEILE(Terminliste!$B$1:$B$30)

schreiben können.
Gruß,
steve1da

[Thomas78]

Hallo steve1da,

ok, das heisst der Bereich bezieht sich nicht darauf wo die Tabelle wirklich steht sondern ich gebe ihm nur den Suchbereich von z.B. 30 Zeilen vor, oder?

Habs probiert beide Formeln funktionieren.
vielen Dank für deine Hilfe!

Thomas