Login

***Waltbern*** · 28.06.2017, 18:07

Hallo,

Seit ca. einer Woche beschäftige ich mich jetzt mit Excel 2016 und bisher funktioniert es ganz gut, bis jetzt.

Versuche 2 Daten zu sortieren bekomme aber nicht die Leerzeichen weg.

Spalte A ist markiert mit einem X aber nicht durchgehend
Spalte B hat Zahlen

Jetzt versuche das alle Zahlen die neben einem X stehen in Spalte C zu übertragen und alle Zahlen die kein X haben in Spalte D (gelber Markierung)

Es klappt zwar mit "=Wenn" aber in Spalte D bekomme ich die Zellen, die leer sind aber Formeln noch enthalten. (orange Markierung).
Habe zwar versucht die dann in eine andere Spalte (H) zu kopieren und nur Werte einfügen, die oberen leeren Zellen dann zu löschen aber er findet keine leere Zellen obwohl keine Daten oder Formeln vorhanden sind.

[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

Da sich die Anzahl der Daten verändern, von verschiedene Leuten bearbeitet werden, und per Macro die Daten in eine andere Tabelle übertrage werden sollte stören die Leeren Zellen, zumindest die sichtbaren.

Wäre Super wenn mir jemand helfen könnte.
Danke

Jockel · Registriert seit: 10.04.2014 Version(en): Office 2019

Hallo, wie genau willst du denn ordnen..? Hier mal zwei Möglichkeiten (per Formel)..:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E
1	X	11111	11111	11114
2	X	11112	11112	11117
3	X	11113	11113	11118
4		11114	11115	11119
5	X	11115	11116	11120
6	X	11116		11121	11114
7		11117		11122	11117
8		11118			11118
9		11119			11119
10		11120			11120
11		11121			11121
12		11122			11122

Zelle	Formel
C1	=WENNFEHLER(AGGREGAT(15;6;$B$1:$B$12/($A$1:$A$12="x");ZEILE(A1));"")
D1	=WENNFEHLER(AGGREGAT(15;6;$B$1:$B$12/($A$1:$A$12<>"x");ZEILE(A1));"")
E1	=WENNFEHLER(AGGREGAT(15;6;$B$1:$B$12/($A$1:$A$12<>"x");ZEILE(A1)-ZÄHLENWENN($A$1:$A$12;"x"));"")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

**WillWissen** · 28.06.2017, 18:53

Hi,

Jockel war zwar schneller, ich will dir aber meine Lösung mit zwei Hilfsspalten, die du einfach ausblenden kannst, nicht vorenthalten.

Tabelle2

	A	B	C	D	E	F
1	x	1		11111	11111	11113
2	x	2		11112	11112	11115
3			3	11113	11114	11117
4	x	4		11114	11116	11118
5			5	11115	11119
6	x	6		11116	11120
7			7	11117
8			8	11118
9	x	9		11119
10	x	10		11120

Formeln der Tabelle

Zelle	Formel
B1	=WENN(A1="x";ZEILE();"")
C1	=WENN(A1="";ZEILE();"")
E1	=WENNFEHLER(INDEX(D:D;KKLEINSTE(B:B;ZEILE(A1)));"")
F1	=WENNFEHLER(INDEX(D:D;KKLEINSTE(C:C;ZEILE(A1)));"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

***Waltbern*** · 28.06.2017, 20:06

Danke für die Hilfestellung!!!

Leider war ich zu unpräzise. :s

Es gibt Bestellnummer Interne und Externe die unterscheiden sich der Rest ist gleich und die Zuordnung der Spalten darf sich nicht verändern.
Bekomme vom SAP so eine ähnliche Liste

[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

Und so sollten die Daten für die Weitergabe aussehen

[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]
Die Reihenfolge der Daten ist ist nicht so wichtig nur sollte die Interne Nr,, die Ware, die Externe Nr., und die Beschreibung richtig zugeordnet sein.
Ein andere Code vergleicht dann die Spalte weiß und gelb und ordnet die dann zu.

Sorry für die Mühe

**WillWissen** · 28.06.2017, 20:24

Hi,

jetzt bin ich an einem Punkt angelangt, an dem ich (weil recht umfangreich) keine Beispieldatei nach einem ScrShot nachbauen möchte. Bitte lade deine Mustermappe hoch, dann schaue ich gerne, ob ich dir weiterhelfen kann. Zum Hochladen lies dir doch bitte die mit Wichtig gekennzeichneten Beiträge durch:

http://www.clever-excel-forum.de/Forum-N...gshinweise

***Waltbern*** · 29.06.2017, 14:32

Hallo nochmal und Danke für die Hilfe!

Hier mal die Tabelle.

Gruß
Waltbern

Jockel · Registriert seit: 10.04.2014 Version(en): Office 2019

Hallo, ich hatte doch aufgezeigt wie das geht mit dem Auflisten...!!!!

... was soll denn unter Produkt, Lagerart und Lagertyp stehen..?

**Rabe** · 29.06.2017, 15:05

Hi,

mein Vorschlag sieht so aus:
Daten

	H	I	J	K	L	M	N
1	Teilenummer mit Kreuz (PRK)	Lieferart Nr. mit Kreuz (PRK)	Teilenummer ohne Kreuz (PRK)	Lieferart Nr. ohne Kreuz (PRK)	Produkt	Lagerart	Lagertyp
2	S 000 001 12 02	111222			Produkt 1	D43	WA21

verwendete Formeln
Zelle	Formel	Bereich	N/A
H2	=WENN(Daten!$A2="x";Daten!$C2;"")
I2	=WENN(Daten!$A2="x";Daten!$B2;"")
J2	=WENN(Daten!$A2="";Daten!$C2;"")
K2	=WENN(Daten!$A2="";Daten!$B2;"")
L2:N2	=WENN(Daten!$A2="x";SVERWEIS($I2;Daten!$B$2:$F$41;SPALTE(C$1);0);SVERWEIS($K2;Daten!$B$2:$F$41;SPALTE(C$1);0))

Excel-Inn.de

Hajo-Excel.de

XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007

Add-In-Version 19.08 einschl. 64 Bit

Demo - Rabe.xlsx (Größe: 17,92 KB / Downloads: 3)

Jockel · 29.06.2017, 15:17

Hallo, hier nochmal, so wie ich das verstanden habe..:

Arbeitsblatt mit dem Namen 'Daten'
	H	I	J	K	L	M	N
1	Teilenummer mit Kreuz (PRK)	Lieferart Nr. mit Kreuz (PRK)	Teilenummer ohne Kreuz (PRK)	Lieferart Nr. ohne Kreuz (PRK)	Produkt	Lagerart	Lagertyp
2	S 000 001 12 02	111222			Produkt 1	D43	WA21
3	S 000 001 12 03	112223			Produkt 2	D44	WA21
4	S 000 001 12 04	113224			Produkt 3	D43	WA21
5	S 000 001 12 05	114225			Produkt 4	D43	WA29
6	S 000 001 12 06	115226			Produkt 5	D43	WA21
7	S 000 001 12 07	116227			Produkt 6	D43	WA21
8	S 000 001 12 08	117228			Produkt 7	D45	WA21
9	S 000 001 12 09	118229			Produkt 8	D43	WA21
10	S 000 001 12 10	119230			Produkt 9	D43	WA21
11	S 000 001 12 11	120231			Produkt 10	D43	WA21
12	S 000 001 12 12	121232			Produkt 11	D43	WA21
13	S 000 001 12 13	122233			Produkt 12	D43	WA21
14	S 000 001 12 14	123234			Produkt 13	D43	WA21
15	S 000 001 12 15	124235			Produkt 14	D43	WA27
16	S 000 001 12 16	125236			Produkt 15	D43	WA21
17	S 000 001 12 17	126237			Produkt 16	D43	WA21
18	S 000 001 12 18	127238			Produkt 17	D45	WA21
19	S 000 001 12 19	128239			Produkt 18	D43	WA21
20	S 000 001 12 20	129240			Produkt 19	D43	WA21
21	S 000 001 12 21	130241			Produkt 20	D43	WA21
22			S 000 001 12 02	222123	Produkt 1	E03	12e
23			S 000 001 12 03	222124	Produkt 2	E03	12e
24			S 000 001 12 04	222125	Produkt 3	E03	12e
25			S 000 001 12 08	222126	Produkt 7	E12	42e
26			S 000 001 12 09	222127	Produkt 8	E03	12e
27			S 000 001 12 10	222128	Produkt 9	E03	12e
28			S 000 001 12 05	222129	Produkt 4	E12	12e
29			S 000 001 12 06	222130	Produkt 5	E03	12e
30			S 000 001 12 07	222131	Produkt 6	E03	12e
31			S 000 001 12 11	222132	Produkt 10	E03	12e
32			S 000 001 12 12	222133	Produkt 11	E03	12e
33			S 000 001 12 13	222134	Produkt 12	E03	12e
34			S 000 001 12 14	222135	Produkt 13	E12	42e
35			S 000 001 12 15	222136	Produkt 14	E03	12e
36			S 000 001 12 16	222137	Produkt 15	E03	12e
37			S 000 001 12 17	222138	Produkt 16	E03	33e
38			S 000 001 12 20	222139	Produkt 19	E03	12e
39			S 000 001 12 21	222140	Produkt 20	E03	12e
40			S 000 001 12 19	222141	Produkt 18	E03	12e
41			S 000 001 12 18	222142	Produkt 17	E18	12e

Zelle	Formel
H2	=WENN(I2="";"";SVERWEIS(I2;$B$2:$F$41;2;0))
I2	=WENNFEHLER(AGGREGAT(15;6;$B$2:$B$41/($A$2:$A$41="x");ZEILE(A1));"")
J2	=WENN(K2="";"";SVERWEIS(K2;$B$2:$F$41;2;0))
K2	=WENNFEHLER(AGGREGAT(15;6;$B$1:$B$41/($A$1:$A$41<>"x");ZEILE(A1)-ZÄHLENWENN($A$1:$A$41;"x"));"")
L2	=SVERWEIS(WENN($I2="";$K2;$I2);$B$1:$F$41;SPALTE(C$1);0)
M2	=SVERWEIS(WENN($I2="";$K2;$I2);$B$1:$F$41;SPALTE(D$1);0)
N2	=SVERWEIS(WENN($I2="";$K2;$I2);$B$1:$F$41;SPALTE(E$1);0)

**Rabe** · 29.06.2017, 15:49

Hi Jörg,

(29.06.2017, 15:17)Jockel schrieb: Hallo, hier nochmal, so wie ich das verstanden habe..:

ich habe es jetzt nicht genau angeschaut: ist das Ergebnis anders als bei mir?

Aber sicher sind die Formeln übersichtlicher bei Deiner Lösung. :19:

Login
Benutzername:
Passwort:	Passwort vergessen?
	Merken