Datum - Differenz in WENN-Funktion

[MrLinux]

Hallo und guten Morgen,

ich habe ein Problem mit der Ermittlung einer Datumsdifferenz, die ich trotz intensiver Bemühung von G**GLE nicht lösen konnte.

Formelvariante 1:
=WENN(H3="-";"-";WENN(UND(F3<"25";DATEDIF(H3;'FM Statistik'!$B$3;"m")<=3);"ok";WENN(UND(F3>"24";DATEDIF(H3;'FM Statistik'!$B$3;"m")<=6);"ok";"prüfen")))

Formelvariante 2:
=WENN(H3="-";"-";WENN(UND(F3<"25";H3>=EDATUM('FM Statistik'!$B$3;-3));"ok";WENN(UND(F3>"24";H3>=EDATUM('FM Statistik'!$B$3;-6));"ok";"prüfen")))

Im Feld 'FM Statistik'!$B$3 steht ein Datum im Format tt.mm.yyyy und ist in jedem Fall größer als das abgefragte Datum aus der Zelle H3.

Erreichen möchte ich nun, dass folgendes geprüft wird:
- F3<25 und Datumsdifferenz <=3 Monate = "ok"
- F3>24 und Datumsdifferenz <=6 Monate = "ok"
- ansonsten "prüfen"

Ich bekomme zwar keine Fehlermeldung aber auch nicht das gewünschte Ergebnis
Hilfestellung wäre echt prima!

Viele Grüße

Ergänzung:
Nachdem mir EXCEL gerade abgestürzt ist - habe ich die Spalte nebst Formel (nach Variante1) erneut eingegeben und - voila - es funktioniert nun; zumindest grundsätzlich.
Die Kür ware jetzt, wenn ich die Prüfung der 3 bzw. 6 Monate tatsächlich ausgehend von den "krummen" Daten bzw. Zeitfenstern became (z.B. 25.03.16 - 24.06.16).

Viele Grüße

[steve1da]

Hola,

bevor das jemand nachbaut, warum fragst du auf TEXTE ab? "25" ist keine Zahl!

Gruß,
steve1da

[MrLinux]

bevor das jemand nachbaut, warum fragst du auf TEXTE ab? "25" ist keine Zahl!

Ups, entschuldige, das hatte ich in der Formel anders ohne "" - danke für den Hinweis!

[BoskoBiati]

Hallo,

außerdem sollte das eigentlich genügen:

Code:

=WENN(H3="-";"-";WENN(DATEDIF(H3;'FM Statistik'!$B$3;"m")<=3+(F3>24)*3;"ok";"prüfen"))

[steve1da]

Hola,

ist das denn jetzt gelöst?

Wenn nicht, dann solltest du uns erklären, was ein "nicht gewünschtes Ergebnis" für dich ist.


Gruß,
steve1da

[MrLinux]

Hallo,

außerdem sollte das eigentlich genügen:

Code:

=WENN(H3="-";"-";WENN(DATEDIF(H3;'FM Statistik'!$B$3;"m")<=3+(F3>24)*3;"ok";"prüfen"))

Wow, danke BoskoBiati, das ist natürlich wesentlich eleganter (bin halt eher greenhorn).
Wobei ich den 2. Part mit der Addition und der gleichzeitigen Bedingung erst mit der Formelauswertung nachvollziehen konnte. Damit lassen sich künftig bestimmt noch andere Wenn-Funktionen vereinfachen.

Nochmals vielen Dank,
MrLinux

[BoskoBiati]

Hallo,

so ist es besser:

Code:

=WENN(H3="-";"-";WENN('FM Statistik'!$B$3+1-DATUM(JAHR(H3);MONAT(H3)+3+(F3>24)*3;TAG(H3))<=0;"ok";"prüfen"))