Datum ermitteln

[MdeJong]

Hallo liebe Forummitglieder,

ich habe eine Tabelle in der ich nicht nur nach einem Datum gesucht werden soll, sondern mir zu einer vorgegeben Zahl z. 6, alle Datumsangaben ausgeworfen werden sollen.

Leider weiß ich nicht wie, ich hoffe ihr könnt mir helfen?

Ich habe die Tabelle mal beigefügt.

Gruße
Mike


  Datum_ermitteln.xlsx (Größe: 13,64 KB / Downloads: 10)

[steve1da]

Hola,


ist das das gleiche wie hier?
https://www.ms-office-forum.net/forum/sh...p?t=368267
Gruß,
steve1da

[maninweb]

Hallo,

Jep, sieht nach Crossposting aus - ich antworte hier trotzdem mal, nicht um Crossposting zu unterstützen,
sondern weil ich die Problematik interessant fand. Setzt dynamische Arrays voraus.

Code:

=FILTER(INDEX(Datumsangaben;WENN(REST(SEQUENZ(SPALTEN(Werte)*ZEILEN(Werte);1);ZEILEN(Werte))<>0;
 REST(SEQUENZ(SPALTEN(Werte)*ZEILEN(Werte);1);ZEILEN(Werte));ZEILEN(Werte));1);INDEX(Werte;WENN(
REST(SEQUENZ(SPALTEN(Werte)*ZEILEN(Werte);1);ZEILEN(Werte))<>0;REST(SEQUENZ(SPALTEN(Werte)*ZEILEN(Werte);1);ZEILEN(Werte));ZEILEN(Werte));
AUFRUNDEN(SEQUENZ(SPALTEN(Werte)*ZEILEN(Werte);1)/ZEILEN(Werte);0))=R$1;"-")

Gruß

[shift-del]

Moin

Ich habe eine kürzere Formel. Allerdings listet diese die Duplikate nicht mehrfach auf.
Kommt also darauf an was der Fragesteller will. Andererseits kann er mit den Lösungen nichts anfangen, da er kein aktuelles Excel benutzt.

Code:

=FILTER($A$1:$A$24;MMULT(--($B$1:$I$24=N$1);ZEILE($1:$8)^0))

[maninweb]

Hallo,

man könnte meine Formel noch mit EINDEUTIG kapseln, aber die Lösung von shift-del ist wesentlich eleganter :-)

Gruß

[MdeJong]

Hallo,

enstchuldige, ich dachte es wäre OK mein Problem noch einmal hier anzufragen?

Ich habe deinen Vorschlag mal ausprobiert.
Die Tabelle Filterbereich von die kann ich öffnen und es wird auch so angezeigt, wie ich es mir gedacht habe.
Doch wenn ich diese Tabelle jetzt in meine Mappe einfüge, oder meine Tabelle in deine Beispielmappe, funktioniert das ganze nicht mehr.
Es wird überall dann folgendes angezeigt:  "#Name?"

Was ist dort passiert?

  Filterbereich_Kopie.xlsx (Größe: 310,75 KB / Downloads: 2)

In der zusätzlichen sind die eigentlichen Werte, die durchsucht werden sollen.

Gruß
Mike

---

Hallo shift-del

bei diese Formel bekomme ich die Fehlermeldung

Diese Funktion ist ungültig

Ich benutze Office 360

Gruß
Mike

[shift-del]

Ich habe doch noch eine Variante bei der die Duplikate mehrfach aufgelistet werden.

Code:

=SORTIEREN(INDEX(Datumsangaben;KGRÖSSTE((Werte=N$1)*ZEILE(Werte);SEQUENZ(ZÄHLENWENNS(Werte;N$1)))))

EDIT: SPALTE() war überflüssig.

---

Hallo shift-del

bei diese Formel bekomme ich die Fehlermeldung

Diese Funktion ist ungültig

Ich benutze Office 360

In deiner Version fehlen dir 5 Tage im Dezember. Vielleicht liegt es daran.
Oder du bist im halbjährlichen Kanal. Da werden die neuen Funktionen nur 2x im Jahr aktualisiert (Jan/Jul).

[steve1da]

Hola,

=WENNFEHLER(INDEX($A$1:$A$24;AGGREGAT(15;6;ZEILE($A$1:$A$24)/($B$1:$I$24=N$1);ZEILE(A1)));"")

Gruß,
steve1da

[MdeJong]

Was muss ich bei ändern?

auch mit dieser Formel bekomme ich den gleiche  Fehler:

Code:

=SORTIEREN(INDEX(Datumsangaben;KGRÖSSTE((Werte=N$1)*(ZEILE(Werte)+SPALTE(Werte)%%);SEQUENZ(ZÄHLENWENNS(Werte;N$1)))))

[shift-del]

Du musst außerdem die Namen Werte und Datumsangaben durch Bezüge ersetzen oder entsprechende Namen anlegen.