Datum in Urlaubsliste übernehmen

[{Boris}]

Hi,

in Deiner Excelversion musst Du die Formel-Ergebniszellen sowie das Trennzeichen einzeln verketten

=L6&", "&M6&", "&N6&", "&O6&", " usw. usw.

Ist ne Fleißarbeit. Wenn Du das z.B. für 10 Zellen machst, es am Ende aber nur 5 Urlaubstage sind, dann bleiben am Ende in der Zelle 5 Trennzeichen stehen.
Seit xl2019 gibt es genau dafür die Funktion TEXTVERKETTEN - das macht das Ganze sehr leicht (siehe meine bereits gepostete Formel).
Aber für weitere Auswertungen ist eine Verkettung immer schlecht - das hat Dir Steve bereits geschrieben. Wenn Du nix weiter auswerten musst, dann ist es ok.

[Fafner]

Hallo Boris vielen vielen dank für die schnelle Hilfe.

Auswerten muss ich damit nichts weiter nur muss ich ja durchschnittlich 21 Slots anlegen, und mit 21,,, am Ende sieht echt bescheiden aus. Auch mit leerzeichen wird die Zelle unnötig groß. Aber so funktioniert es schonmal und mit meiner Excel Version gibt es keine andere Möglichkeit oder?

Jedenfalls vielen Dank noch einmal.

Grüße

[{Boris}]

Hi,

die überflüssigen Trennzeichen am Ende bekommst Du so weg:

=LINKS(L6&", "&M6&", "&N6&", "&O6&", "&P6&", "&Q6;AGGREGAT(14;6;ZEILE($1:$100)/ISTZAHL(--(TEIL(L6&", "&M6&", "&N6&", "&O6&", "&P6&", "&Q6;ZEILE($1:$100);1)));1))

Die Verkettung

L6&", "&M6&", "&N6&", "&O6&", "&P6&", "&Q6

musst Du natürlich auf Deine Anwendung anpassen bzw. erweitern.

[Fafner]

Guten Morgen,

=WENNFEHLER(TAG(INDEX($A$6:$A$36;AGGREGAT(15;6;ZEILE($1:$31)/($B$6:$B$36="U");SPALTEN($A:A))));"")

so habe ich es jetzt in meiner Tabelle

=A41&" "&B41&" "&C41&" "&D41&" "&E41&" "&F41&" "&G41&" "&H41&" "&I41&" "&J41&" "&K41&" "&L41&" "&M41&" "&N41&" "&O41&" "&P41&" "&Q41&" "&R41&" "&S41&" "&T41&" "&U41&" "&V41&" "&W41&" "&X41&" "&Y41&" "&Z41

so habe ich jetzt die zusammenfassung gemacht. Wie man sieht habe ich die Kommas entfernt und durch leerzeichen ersetzt.

Ich weiß jetzt nur leider nicht wo ich

=LINKS(L6&", "&M6&", "&N6&", "&O6&", "&P6&", "&Q6;AGGREGAT(14;6;ZEILE($1:$100)/ISTZAHL(--(TEIL(L6&", "&M6&", "&N6&", "&O6&", "&P6&", "&Q6;ZEILE($1:$100);1)));1))

einfügen müsste. Tut mir leid das ich schon wieder nachfragen muss, ich verstehe die Formal halt auch leider überhaupt nicht, mein Excelwissen hält sich noch stark in grenzen.

Grüße

[{Boris}]

Hi,

nur die Zellverkettung austauschen:

=LINKS(A41&" "&B41&" "&C41&" "&D41&" "&E41&" "&F41&" "&G41&" "&H41&" "&I41&" "&J41&" "&K41&" "&L41&" "&M41&" "&N41&" "&O41&" "&P41&" "&Q41&" "&R41&" "&S41&" "&T41&" "&U41&" "&V41&" "&W41&" "&X41&" "&Y41&" "&Z41;AGGREGAT(14;6;ZEILE($1:$100)/ISTZAHL(--(TEIL(A41&" "&B41&" "&C41&" "&D41&" "&E41&" "&F41&" "&G41&" "&H41&" "&I41&" "&J41&" "&K41&" "&L41&" "&M41&" "&N41&" "&O41&" "&P41&" "&Q41&" "&R41&" "&S41&" "&T41&" "&U41&" "&V41&" "&W41&" "&X41&" "&Y41&" "&Z41;ZEILE($1:$100);1)));1))

[Fafner]

Danke das funktioniert soweit,

jetzt habe ich nur leider das Problem wenn kein Urlaub genommen  wurde das in dem Feld steht.

#ZAHL!

kriege ich das noch irgendwie weg?

Edit: Vielleicht wäre es ja möglich falls kein Urlaub genommen wurde einfach ein "-" zu setzten.

[{Boris}]

Hi,

einfach mit WENNFEHLER umklammern:

=WENNFEHLER(LINKS(A41&" "&B41&" "&C41&" "&D41&" "&E41&" "&F41&" "&G41&" "&H41&" "&I41&" "&J41&" "&K41&" "&L41&" "&M41&" "&N41&" "&O41&" "&P41&" "&Q41&" "&R41&" "&S41&" "&T41&" "&U41&" "&V41&" "&W41&" "&X41&" "&Y41&" "&Z41;AGGREGAT(14;6;ZEILE($1:$100)/ISTZAHL(--(TEIL(A41&" "&B41&" "&C41&" "&D41&" "&E41&" "&F41&" "&G41&" "&H41&" "&I41&" "&J41&" "&K41&" "&L41&" "&M41&" "&N41&" "&O41&" "&P41&" "&Q41&" "&R41&" "&S41&" "&T41&" "&U41&" "&V41&" "&W41&" "&X41&" "&Y41&" "&Z41;ZEILE($1:$100);1)));1));"-")