Doppelte Einträge finden und Wert ausgeben

[air]

Hallo zusammen,

ich komme einfach nicht dahinter wie und ob mein Problem zu lösen ist.

ich will meine Tabelle ständig erweitern (mit Name und Zahl) und sofort bei der Eingabe Doppelte Werte finden und dazu noch den Wert des früher getätigten Eintrags anzeigen lassen

Hans        6
Max         4
Heidi        9
Uwe         1
Wenn ich jetzt erneut
Max eingebe, soll mir der Wert 4 angezeigt werden, bevor ich einen neuen Wert hinter den neuen Max schreibe. Dieser Wert soll am Besten über der Tabelle stehen. Den Doppelten Max lösche ich dann wieder, so dass keine doppelten übrigbleiben.
Am Besten wäre es, wenn mir in Zelle 1A Max und in 1B 4 anzeigen würde


vielen Dank
Gruß Jürgen

[WillWissen]

Hi Jürgen,

mein Vorschlag:

Tabelle4

	A	B	C
1	Name	Wert	Kontrollfeld
2	Hans	6	Stopp: Hans 6 in Zeile 2 vorhanden!
3	Max	4
4	Lieschen	8
5	Eva	2
6	Hans

Formeln der Tabelle

Zelle Formel C2 ="Stopp: "&VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280)&" "&INDEX(B:B;VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0))&" in Zeile "& VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0)&" vorhanden!"

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[air]

Hallo Günter,


fast Perfekt, bei mir kommt die Meldung aber nur wenn ich den 2. doppelten Wert in Zeile 280 habe. kommt er in Zeile 279 krieg ich : DIV/0

Gruß Jürgen

[Jockel]

Hallo Günter, ist das so auch gewollt..?

Arbeitsblatt mit dem Namen 'Tabelle4'
	A	B	C
1	Name	Wert	Kontrollfeld
2	Hans	6	Stopp: Eva 2 in Zeile 5 vorhanden!
3	Max	4
4	Lieschen	8
5	Eva	2
6

Zelle	Formel
C2	="Stopp: "&VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280)&" "&INDEX(B:B;VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0))&" in Zeile "& VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0)&" vorhanden!"

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[air]

Hallo Jörg,

der Ansatz von Günter war schon richtig und das Ergebnis auch so gewollt, nur kommt bei die doppelt Meldung nur in Zeile 280 und sonst nirgendwo. sollta aber auch in Zeile 4,15 oder sonstwo kommen

Gruß Jürgen

[Jockel]

Hallo, ich weiß nicht ob das so soll..?

Code:

=WENN(ZÄHLENWENN(A:A;VERWEIS(WIEDERHOLEN("z";255);A:A))>1;VERWEIS(WIEDERHOLEN("z";255);A:A)&" steht schon in Zeile "&VERGLEICH(VERWEIS(WIEDERHOLEN("z";255);A:A);A:A;0)&" mit dem Wert "&INDEX(B:B;VERGLEICH(VERWEIS(WIEDERHOLEN("z";255);A:A);A:A;0));"keine doppelten Einträge")

Arbeitsblatt mit dem Namen 'Tabelle4'
	A	B	C
1	Name	Wert	Kontrollfeld
2	Hans	6	Stopp: Eva 2 in Zeile 5 vorhanden!
3	Max	4	keine doppelten Einträge
4	Lieschen	8
5	Eva	2
6

Zelle	Formel
C2	="Stopp: "&VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280)&" "&INDEX(B:B;VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0))&" in Zeile "& VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0)&" vorhanden!"
C3	=WENN(ZÄHLENWENN(A:A;VERWEIS(WIEDERHOLEN("z";255);A:A))>1;VERWEIS(WIEDERHOLEN("z";255);A:A)&" steht schon in Zeile "&VERGLEICH(VERWEIS(WIEDERHOLEN("z";255);A:A);A:A;0)&" mit dem Wert "&INDEX(B:B;VERGLEICH(VERWEIS(WIEDERHOLEN("z";255);A:A);A:A;0));"keine doppelten Einträge")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

Arbeitsblatt mit dem Namen 'Tabelle4'
	A	B	C
1	Name	Wert	Kontrollfeld
2	Hans	6	Stopp: Max 4 in Zeile 3 vorhanden!
3	Max	4	Max steht schon in Zeile 3 mit dem Wert 4
4	Lieschen	8
5	Eva	2
6	Max

Zelle	Formel
C2	="Stopp: "&VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280)&" "&INDEX(B:B;VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0))&" in Zeile "& VERGLEICH(VERWEIS(2;1/($A$2:$A$280<>"");$A$2:$A$280);A:A;0)&" vorhanden!"
C3	=WENN(ZÄHLENWENN(A:A;VERWEIS(WIEDERHOLEN("z";255);A:A))>1;VERWEIS(WIEDERHOLEN("z";255);A:A)&" steht schon in Zeile "&VERGLEICH(VERWEIS(WIEDERHOLEN("z";255);A:A);A:A;0)&" mit dem Wert "&INDEX(B:B;VERGLEICH(VERWEIS(WIEDERHOLEN("z";255);A:A);A:A;0));"keine doppelten Einträge")

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[lupo1]

{
=MIN(WENN(ZÄHLENWENN(A1:A999;A1:A999)>1;ZEILE(A1:A999)))&"-"
&MAX(WENN(ZÄHLENWENN(A1:A999;A1:A999)>1;ZEILE(A1:A999)))
}

zeigt 0-0 an, wenn es keine Doppler gibt, sonst den ersten und den letzten Dopplereintrag (Zeilenangabe). Mit Nr. 5

Die Angabe der 4 ist irrelevant, da einer der beiden Maxe eh weg muss.