Doppelte Werte aus zwei Spalten anzeigen

[JulyVienna]

Hallo,

ich habe eine Frage - ich komme einfach nicht weiter.

Ich habe Spalte A mit Werten und B mit Werten.
Nun möchte ich alle Werte welche in Spalte A UND B vorkommen in Spalte C anzeigen.

Ebenso benötige ich in Spalte D jene Werte die NUR in Spalte B vorkommen..

Ein ehemaliger Arbeitskollege hat mir jene Formel erstellt, jedoch funktioniert Sie irgendwie nicht mehr...
=WENNFEHLER(WENN(SVERWEIS(B3;$A:$B;2;0);"";B3);B3)

Es sind maximal 400 Werte jeweils in einer Spalte...

Vielleicht habt ihr eine Idee wo hier der Fehler liegt oder wie ich das Problem sonst lösen kann?

Danke im Voraus und lg July

[neopa]

Hallo July,

Deine Angaben sind noch nicht ganz vollständig/eindeutig.

Nachfolgend gehe ich davon aus, dass es sich um alphanumerische Werte handelt und diese in den Spalte A und B jeweils nur einmal vorkommen bzw. diese dann auch als alphanumerische Werte und doppelt bzw. gelistet werden.
Anderenfalls bedarf es entsprechender Anpassung im Formelkonstrukt, was natürlich auch möglich ist.

In C1:

Code:

=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;ZEILE(A$1:A$400)/(ZÄHLENWENN(A$1:A$400;B$1:B$400)>0);ZEILE(A1)));"")

In D1:

Code:

=WENNFEHLER(INDEX(B:B;AGGREGAT(15;6;ZEILE(A$1:A$400)/(ZÄHLENWENN(A$1:A$400;B$1:B$400)=0);ZEILE(A1)))&"";"")

und Formeln weit genug nach unten kopieren.

[Glausius]

Hallo Werner,

ohne deine Formel getestet zu haben - setzt du voraus, dass July eine Excelversion verwendet, die AGGREGAT bereits kennt. Leider hat July sich nicht zu ihrer Version geäußert.

[steve1da]

Hola,

hat sie doch, zumindest steht 2016 im Profil.

Gruß,
steve1da

[WillWissen]

Hi Günter,

schau mal hier:

[
Bild bitte so als Datei hochladen: Klick mich!
]

[JulyVienna]

Hallo,

Danke für eure antworten
Ja version 2016, die formel sollte aber auch mit 2013 kompatibel sein :/

Es sind rein numerische werte (kundennummern 8stellig)
Ob ein wert in einer spalte doppelt ist ist nicht wichtig

Werte welche in spalte A und B vorkommen sollen in C angezeigt werden (egal ihrer anzahl in einer spalte)
Vielleicht könnte es auch wichtig sein - spalte A hat 400 Daten, B ca. Due hälfte.

Lg

[neopa]

Hallo July,

ja, Excel ist auf jeden Fall aufwärts kompatibel und die Funktion AGGREGAT() gibt es schon seit der Version 2010.


Wenn nur numerische Werte auszuwerten sind, bedarf es in den Formeln auch keines INDEX() und Du hast zusätzlich den Vorteil, dass die Ergebnislisten sortiert (hier aufwärts) ausgegeben werden.

Ich hab in unterstehende Formeln nun noch eingebaut, dass doppelte Werte innerhalb einer Spalte nicht doppelt im Ergebnis auftauchen. Außerdem bin ich davon ausgegangen, dass Du in der ersten Zeile Überschriften zu stehen hast,

Somit dann in C2:

Code:

=WENNFEHLER(AGGREGAT(15;6;A$2:A$400/(ZÄHLENWENN(B$2:B$400;A$2:A$400)>0)/(ZÄHLENWENN(C$1:C1;A$2:A$400)=0);1);"")

und in D2:

Code:

=WENNFEHLER(AGGREGAT(15;6;B$2:B$400/(ZÄHLENWENN(A$2:A$400;B$2:B$400)=0)/(B$2:B$400<>"")/(ZÄHLENWENN(D$1:D1;B$2:B$400)=0);1);"")

und Formeln nach unten kopieren.

[JulyVienna]

Danke Werner!

Funktioniert einwandfrei :)

Lg Julia