Druck als PDF Datei

[RPP63]

Nö. 
[…]
Von der Logik her musst Du Dich von der größtmöglichen Auswahl zu den kleinen durcharbeiten.

Sorry, aber das ist doch Killefit, André!
Spätestens ab fünf Sheets wird es grotesk!
Man sammelt die Sheets mittels Schleife über den TypeName des Controls in einem Array,
kopiert dieses Sheet-Array in eine neue Mappe,
exportiert diese (ActiveWorkbook) als PDF
und schließt die temporäre Mappe, ohne sie zu speichern.

Mal ein Code aus einem meiner Muster, den ich nicht anpassen werde:

Code:

Private Sub RPP()
Dim ctrl As Control
Dim i&, j&, arr() As String
For Each ctrl In Me.Controls
   If TypeName(ctrl) = "CheckBox" Then
      If ctrl Then
         ReDim Preserve arr(j)
         arr(j) = Worksheets(Int(Right(ctrl.Name, 1))).Name
         j = j + 1
      End If
   End If
Next
Worksheets(arr).Copy
ActiveWorkbook.ExportAsFixedFormat _
   xlTypePDF, Environ("UserProfile") & "\Desktop\MeineAuswahl", OpenAfterPublish:=True
ActiveWorkbook.Close False
End Sub

Die Mappe lade ich mal hoch.

Gruß Ralf

[Mike123]

Mega, Danke !

Hab den Code zum Drucken noch erweitert. Meine Zieldatei hat nur 22 verschiedene Checkboxen, hoffentlich vergesse ich da keine Verweise :) 

Private Sub CommandButton1_Click()

If CheckBox1 = True And CheckBox2 = True And CheckBox3 = True Then
    Sheets(Array("Tabelle1", "Tabelle2", "Tabelle3")).Select


ElseIf CheckBox1 = True And CheckBox2 = True Then
    Sheets(Array("Tabelle1", "Tabelle2")).Select

ElseIf CheckBox2 = True And CheckBox3 = True Then
    Sheets(Array("Tabelle2", "Tabelle3")).Select

ElseIf CheckBox1 = True And CheckBox3 = True Then
    Sheets(Array("Tabelle1", "Tabelle3")).Select

ElseIf CheckBox1 = True Then
    Sheets("Tabelle1").Select

ElseIf CheckBox2 = True Then
    Sheets("Tabelle2").Select

ElseIf CheckBox3 = True Then
    Sheets("Tabelle3").Select
End If


ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
        True


End Sub

[RPP63]

Eigenzitat:

Spätestens ab fünf Sheets wird es grotesk!

[Mike123]

Klasse deine Beispieldatei und Danke dafür ! Ich denke damit werde ich mir die Sache zurecht biegen können.

Danke an ALLE Unterstützer !

[schauan]

Hi Ralf,

ich schrieb

Kann man sicher noch abkürzen, ist aber erst mal zum Verständnis.

im Beispiel ging es erst mal um 3 Blätter.
Du kannst die Klarnamen in Abhängigkeit des Zustandes der Checkboxen einem Array sammeln und damit dann die Blätter direkt in der Mappe selektieren und ausgeben ohne diese gesondert in eine temporäre zu legen ....

[Kuwer]

Hallo Mike,

vielleicht reicht das ja schon für die 22 CheckBoxen:

Code:

Private Sub CommandButton1_Click()
  Dim i As Long, j As Long
  Dim oWs As Worksheet
  Set oWs = ActiveSheet
  For i = 1 To 22
    If Me.Controls("CheckBox" & i) Then
      Worksheets(i).Select j = 0
      j = 1
    End If
  Next i
  If j = 1 Then
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Quality:=xlQualityStandard, _
      IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True
    oWs.Select
  End If
End Sub

Gruß Uwe

[schauan]

Hi Uwe,

wie kommt man denn auf so was ...

Worksheets(i).Select j = 0
j = 1

Kannte ich noch gar nicht. Hab gleich mal bei MS nachgeschaut, ist ja sogar beschrieben.
Das reicht dann auch:

Worksheets(i).Select False

[Kuwer]

Hi André

Das reicht dann auch:

Worksheets(i).Select False

Nö! Nicht, wenn das aktive Blatt nicht zu den angehakten Blättern gehört.

Gruß Uwe

[schauan]

Hi Uwe,
Stimmt. Man müsste beim ersten Treffer nur selektieren und ab dem zweiten hinzufügen.