Dynamisches Zählenwenn möglich ???
#1
Hallo ich mal wieder mit was komischem....

meine Frage kann man die Zählenwenn Funktion dynamisch gestalten ?

Ich habe in Feld E3 ein Dropdown mit Projekten und in Zelle C6 sollen dazu passend Tage gezählt werden das mache ich mit 

'=WENN(B6="";"";ZÄHLENWENNS(DB_Projekt1[Besuchsdatum];"="&B6;DB_Projekt1[USER];"="&$N$3))'

Jetzt soll aber je nach Dropdown Auswahl der Kriterienbereich geändert werden.

Ich hab es mit '=WENN(B6="";"";ZÄHLENWENNS("DB_"&""&$E$3&""&"[Besuchsdatum]";"="&B6;"DB_"&""&$E$3&""&"[USER]";"="&$N$3))' versucht aber das klappt nicht.


Ist das irgendwie möglich oder geht so was generell nicht ?

DANKE

PS: Beispieldatei bastle ich noch da die Original voll ist mit Privaten Daten....
Top
#2
Moin

Ich würde ja auf Pivot tippen.
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.

[-] Folgende(r) 1 Nutzer sagt Danke an shift-del für diesen Beitrag:
  • Psycor
Top
#3
Hi

Um Bezüge aus Zellangaben zu erstellen benötigst du die Funktion Indirekt.
https://www.online-excel.de/excel/singsel.php?f=24

Gruß Elex
[-] Folgende(r) 1 Nutzer sagt Danke an Elex für diesen Beitrag:
  • Psycor
Top
#4
so hier mal die Beispieldatei


Angehängte Dateien
.xlsx   Excel_Dyn._Abfrage.xlsx (Größe: 23,43 KB / Downloads: 11)
Top
#5
Hallo, eine Möglichkeit per Formel..:

PHP-Code:
=ZÄHLENWENNS(WAHL(VERGLEICH($E$1;Projekte[Projekte];0);DB_Projekt1[Besuchsdatum];DB_Projekt2[Besuchsdatum]);B4;WAHL(VERGLEICH($E$1;Projekte[Projekte];0);DB_Projekt1[USER];DB_Projekt2[USER]);$H$1


Hier muss aber angepasst werden. Nicht optimal...
Gruß Jörg
stolzes Mitglied im ----Excel-Verein
Freund einer excellenten Power Query-Abfrage
[-] Folgende(r) 1 Nutzer sagt Danke an Jockel für diesen Beitrag:
  • Psycor
Top
#6
damit bekomme ich es auch nicht wirklich hin ...

bin ich zu unerfahren zu ...


dachte es gibt so was einfaches wie den String zusammen zu setzen  Undecided

danke trotzdem


evtl. fällt jemandem ja was ein :05:
Top
#7
(30.05.2019, 15:01)Psycor schrieb: dachte es gibt so was einfaches wie den String zusammen zu setzen  Undecided
Bei der Datenlage gibt es keine wirklich einfache Lösung.
An der Stringzusammensetzung mit INDIREKT() wirst du vermutlich noch mehr verzweifeln als an der Lösung mit WAHL().
Und die Lösung mit PQ und Pivot bedeutet auch einen Lernaufwand.

Für dich wäre es am einfachsten die beiden Projekt-Tabellen in einer Tabelle zusammenzufassen mit einer zusätzlichen Spalte "Projekt".
Wir sehen uns!
... Detlef

Meine Beiträge können Ironie oder Sarkasmus enthalten.

[-] Folgende(r) 1 Nutzer sagt Danke an shift-del für diesen Beitrag:
  • Psycor
Top
#8
Hi

evtl. hilft dir das Bsp. weiter.

deine Formel von C4. Hier kannst du jetzt in E1 das Projekt ändern.

Code:
=WENN(B4="";"";ZÄHLENWENNS(INDIREKT("DB_"&$E$1&"[Besuchsdatum]");B4;INDIREKT("DB_"&$E$1&"[USER]");$H$1))

Für [Besuchsdatum] und [USER] kannst du auch eine Zelle zum wechseln verwenden.

Code:
=WENN(B4="";"";ZÄHLENWENNS(INDIREKT("DB_"&$E$1& Zelle(?)  );B4;INDIREKT("DB_"&$E$1&"[USER]");$H$1))
Gruß Elex
[-] Folgende(r) 1 Nutzer sagt Danke an Elex für diesen Beitrag:
  • Psycor
Top
#9
Danke sehr werde es später testen wenn ich es dann noch kann  :15:
Top
#10
Hallo Psycor,

es kann schon so realisiert werden, wie Du es momentan anstrebst.
Doch würde ich bei Deiner bisher vorgestellten Datenstruktur dazu raten, Deine Projektliste wie folgt zu ermitteln.

In Tabelle2!A2 folgende Formel:
Code:
=WENNFEHLER(INDEX($1:$1;AGGREGAT(15;6;SPALTE(F1:ZZ1)/(F$1:ZZ$1<>"");ZEILE(A1)));"")

diese nach unten ziehend kopieren. Damit hast Du die gleiche Bezeichnung Deiner Projekte, wie Du sie in Tabelle2 Zeile benannt hast. Du musst jetzt natürlich noch gewährleisten, dass Du Deine intelligenten Tabellen auch exakt so bezeichnet hast. (Es gäbe auch eine andere Formellösung, wo diese Bezeichnung keine Rolle spielt, aber ich hatte nun mal mit dieser hier angefangen und erst jetzt festgestellt, dass die Möglichkeit gegeben sein könnte, dass Du Deine Projektdatenbezeichnung im Namensmanager nicht exakt so bezeichnen könntest wie Du dies in Zeile 1 zu stehen hast)

Nun definiere im Namensmanager  eine benannte Formel die ich nachfolgend z.B. als Proj_Ausw bezeichnet habe.

Code:
Proj_Ausw =INDEX(Projekte[Projekte];1):INDEX(Projekte[Projekte];ZÄHLENWENN(Projekte[Projekte];"?*"))

Nun ändere die "Quelle" der Datengültigkeit in Tabelle1!E1 zu:
Code:
=Proj_Ausw


Und jetzt folgende Formel in Tabelle1!C4:


Code:
=WENN(B4="";"";ZÄHLENWENNS(INDIREKT(E$1&"[Besuchsdatum]");"="&B4;INDIREKT(E$1&"[USER]");"="&$H$1))


und diese nach unten kopieren.
Gruß Werner
.. , - ...
[-] Folgende(r) 1 Nutzer sagt Danke an neopa für diesen Beitrag:
  • Psycor
Top


Gehe zu:


Benutzer, die gerade dieses Thema anschauen: 1 Gast/Gäste