Eigene Funktion aktualisiert alle Blätter

[Crazy Tom]

Hallo zusammen

ich benutze folgende Funktion um jeweils in den Spalten A und B 1sen aus den letzten 20 Einträgen zu zählen

Code:

Public Function fctZaehlen(intSpalte As Integer) As Long
Dim lngLetzte As Long
Dim lngErste As Long
Application.Volatile
With ActiveSheet
   lngLetzte = .UsedRange.Rows.Count
   If lngLetzte < 20 Then
       lngErste = 1
   Else
       lngErste = lngLetzte - 19
   End If
   fctZaehlen = Application.WorksheetFunction.CountIf(.Range(.Cells(lngErste, intSpalte), _
                                                   .Cells(lngLetzte, intSpalte)), 1)
End With
End Function

jeweils in den Zellen F1 und G1 lasse ich mir das Ergebnis per Formel

=fctZaehlen(1)

bzw.

=fctZaehlen(2)

anzeigen

diese Formeln habe ich nun in Tabelle1 und in Tabelle2 stehen
wenn ich nun in Tabelle1 eine weitere 1 unten anschreibe
wird das Ergebnis richtig in den Zellen angezeigt
wechsel ich nun in Tabelle2 steht in den Formelzellen das gleiche Ergebnis wie in den Zellen aus Tabelle1
und umgekehrt
wie kriege ich das nun hin, dass das jeweilig richtige Ergebnis im richtigen Tabellenblatt steht?


MfG Tom

hier noch die Datei

[RPP63]

Moin Tom!
Dass Du auch mal ne Frage hast …  :19:
Der Knackpunkt ist ActiveSheet in der UDF.
Übergib den Tabellennamen als Text der UDF:

Public Function fctZaehlen(TName As String, intSpalte As Integer) As Long
Dim lngLetzte As Long
Dim lngErste As Long
Application.Volatile
With Worksheets(TName)
    lngLetzte = .UsedRange.Rows.Count
    If lngLetzte < 20 Then
        lngErste = 1
    Else
        lngErste = lngLetzte - 19
    End If
    fctZaehlen = Application.WorksheetFunction.CountIf(.Range(.Cells(lngErste, intSpalte), _
                                                    .Cells(lngLetzte, intSpalte)), 1)
End With
End Function

Aufruf im Tabellenblatt dann so:

	F	G
1	11	8

Formeln der Tabelle

Zelle Formel F1 =fctzaehlen("Tabelle1";1) G1 =fctzaehlen("Tabelle1";2)

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Ralf

[RPP63]

Noch ein Zusatz:
Die Unzuverlässigkeit von .UsedRange sollte Dir doch bekannt sein?

Code:

lngLetzte = .Cells(.Rows.Count, intSpalte).End(xlUp).Row

Gruß Ralf

[Crazy Tom]

Hallo Ralf

danke

die Übergabe der Tabelle hatte ich auch schon versucht
hatte aber nicht gedacht den Namen in Gänsfüßchen zu packen

hatte es so versucht

=fctZaehlen(Tabelle1!;1)

und das mochte die Funktion gar nicht :@

so komme ich nun weiter

MfG Tom

[Crazy Tom]

Hallo Ralf

das mit der UsedRange ist mir bewusst

allerdings brauche ich die letzte Zeile aus den Spalten A und B
denn aus den beiden Spalten zusammen sollen die letzten 20 Einträge betrachtet werden

MfG Tom

[RPP63]

Ach so, dies hatte ich mir fast gedacht!
Dann würde ich zur Sicherheit folgenden Code verwenden:
lngLetzte = WorksheetFunction.Max _
   (.Cells(.Rows.Count, 1).End(xlUp).Row, _
    .Cells(.Rows.Count, 2).End(xlUp).Row)

Gruß Ralf

[Crazy Tom]

Hallo Ralf

danke das macht es perfekt

MfG Tom