Einfach Liste für Brötchen mit Belag

[vettelchen]

Hallo liebes Forum,
ich wollte bei unseren Meetings immer Brötchen mitbringen. 
Jeder soll die Anzahl an Brötchen eintragen und es soll der auf 50 Cent aufgerundete Betrag rauskommen.
Irgendwie habe ich einen Wurm drin, da ich es nicht hinbekomme weder aufzurunden, noch, dass wenn einer NICHTS einträgt, er trotzdem die Kosten von 2,50 € hat.
Es soll so sein, dass man auch die Preise von Brötchen, Mett und Fleischwurst anpassen kann.
Knifflige Aufgabe für Profis. Wer kann da helfen?
Testtabelle im Anhang.

Danke. Gruß Seb

[BoskoBiati]

Hi,

Code:

=WENN([@Name]="";0;WENN(ANZAHL(Tabelle3[@[Anzahl Brötchen Jägermett]:[Anzahl Brötchen mit Fleischwurst]])=0;2,5;AUFRUNDEN((WENN([@[Anzahl Brötchen Jägermett]]="";0;[@[Anzahl Brötchen Jägermett]]*0,44+(F$2/10))+WENN([@[Anzahl Brötchen mit Fleischwurst]]="";0;([@[Anzahl Brötchen mit Fleischwurst]]*0,44+(F$3/10))))*2;0)/2))

[redeagle56]

Hallo,
das sollte auch funktionieren.

MfG Günter

  Brötchenliste_test_2.xlsx (Größe: 17,55 KB / Downloads: 7)

[BoskoBiati]

Hi,

in meiner Formel ist noch ein Fehler:

Code:

=WENN(A7="";0;WENN(ANZAHL(B7:C7)=0;2,5;AUFRUNDEN(((B7<>"")*(B7*(0,44+(F$2/10)))+(C7<>"")*(C7*(0,44+(F$3/10))))*2;0)/2))

=OBERGRENZE((A7<>"")*((B7+C7)*$F$1+B7*$F$2/10+C7*$F$3/10+(B7+C7=0)*2,5);0,5)

=WENN([@Name]="";0;WENN(ANZAHL(Tabelle3[@[Anzahl Brötchen Jägermett]:[Anzahl Brötchen mit Fleischwurst]])=0;2,5;AUFRUNDEN((([@[Anzahl Brötchen Jägermett]]<>"")*([@[Anzahl Brötchen Jägermett]]*(0,44+(F$2/10)))+([@[Anzahl Brötchen mit Fleischwurst]]<>"")*([@[Anzahl Brötchen mit Fleischwurst]]*(0,44+(F$3/10))))*2;0)/2))

[redeagle56]

Hallo,
das mit dem Mathematik in der Formel kannst du vergessen.
Schreib einfach so: =OBERGRENZE(((B7+C7)*$F$1)+(B7*$G$2)+(C7*$G$3);0,5)

MfG Günter

oder ohne Hilfszellen

  Brötchenliste_test_3.xlsx (Größe: 18,65 KB / Downloads: 1)

[BoskoBiati]

Hi Günter,

Nachteil Deiner Formel: Wenn einer nichts kauft hat er 0 zu zahlen, aber nach Vorbedingung hat jeder, der nichts kauft, 2,50 zu zahlen!

dass wenn einer NICHTS einträgt, er trotzdem die Kosten von 2,50 € hat.

[redeagle56]

Hallo,
warum soll jemand 2,50€ bezahlen, wenn er nichts kauft?
Der Sinn erschließt sich mir nicht.
Das geht aber auch.

MfG Günter

  Brötchenliste_test_4.xlsx (Größe: 18,74 KB / Downloads: 5)

[vettelchen]

Vielen lieben Dank! Ihr seid super! Ich probiere alles gleich mal aus... Merci!

---

Sorry, hatte mich falsch ausgedrückt. Bei mir kommt halt der Fehler durch die Formel, dass man 2,50 € zahlen müsste, aber man nichts einträgt, weil die Formel ja schon die 2,50 € selbstständig gerechnet hat.

---

Hallo Edgar, cool. Alle drei laufen glaube ich. Wenn einer aber nichts einträgt, soll auch "0" rauskommen. Wo nehme ich das raus?

[BoskoBiati]

Hi,

was denn jetzt?

Wenn einer aber nichts einträgt, soll auch "0" rauskommen
Bei mir kommt halt der Fehler durch die Formel, dass man 2,50 € zahlen müsste, aber man nichts einträgt, weil die Formel ja schon die 2,50 € selbstständig gerechnet hat.

Code:

=WENN(A7="";0;AUFRUNDEN(((B7<>"")*(B7*(0,44+(F$2/10)))+(C7<>"")*(C7*(0,44+(F$3/10))))*2;0)/2))
=OBERGRENZE((A7<>"")*((B7+C7)*$F$1+B7*$F$2/10+C7*$F$3/10);0,5)