Einzelne Monatstage zwischen Zeiträumen nach vorherigen Kriterien berechnen!

[RoBs1505]

Schönen guten Tag,

ich hänge da an einem sehr komplexen Problem. Muss aber auch im Vorfeld sagen, dass ich nicht der größte Excelkenner bin.

Folgender Sachverhalt:
Ich habe eine Tabelle mit Zeitraumangaben und einzelne Werte die als Gruppe agieren.
Gruppe 1 = A,B,C
Gruppe 2 = D,E,F
Gruppe 3 = G,H,I

Der Aufbau der Tabelle ist wie folgt:
Bsp.:
Zeitraum
15.07.2024 - 16.08.2024
Tage gebraucht
33
Nutzer
Gruppe 1 - A

Das zieht sich über mehrere Zellen und Spalten mit allen Nutzern. Nutzer A taucht im Jahr öfters auf. Nun sollen die Nutzer der Gruppen herausgesucht und für den jeweiligen Monat ausgerechnet werden wie lange Sie gebraucht haben und dieses einzeln in einer separaten Tabelle ausgegeben werden. 
D.h. Tage für Juli und August separieren. 

Hoffe hab das halbwegs verständlich rübergebracht, was ich benötige :D

Ansonsten hab ich auch ne Bsp. Datei hochgeladen

[Ego]

Hallo R...,

wenn in den Monatsüberschriften die Ersten der Monate eingetragen sind geht

ab Version 21:

Code:

=LET(LT;WENN(Daten!$B$3:$B$8+1<C$7;Daten!$B$3:$B$8+1;C$7);
ET;WENN(Daten!$A$3:$A$8>B$7;Daten!$A$3:$A$8;B$7);
IG;ISTZAHL(VERGLEICH(Daten!$D$3:$D$8;INDEX($A$2:$C$4;;VERGLEICH($A8;$A$1:$C$1;0));0));
D;(LT-ET)*IG;
S;SUMME(D*(D>0));
S)

für deine Version:

Code:

=SUMME((WENN(Daten!$B$3:$B$8+1<C$7;Daten!$B$3:$B$8+1;C$7)-WENN(Daten!$A$3:$A$8>B$7;Daten!$A$3:$A$8;B$7))*ISTZAHL(VERGLEICH(Daten!$D$3:$D$8;INDEX($A$2:$C$4;;VERGLEICH($A15;$A$1:$C$1;0));0))*
((WENN(Daten!$B$3:$B$8+1<C$7;Daten!$B$3:$B$8+1;C$7)-WENN(Daten!$A$3:$A$8>B$7;Daten!$A$3:$A$8;B$7))>0))

=

[RoBs1505]

Danke Sehr,

hat mir geholfen. Habs jetzt geschafft.