Excel & Dias-Funktion

[sheffield]

Hallo
ich möchte mit einem Klick auf einer Zelle, dass Excel mir mehrere Bilder nacheinander anzeigt und zwar nach 15 Sekunden.
Die Bilder sind als Screenshot (jpg/png/bmp) und es ist wichtig, dass die Funktionalität von „Windwos Photo viewer“ genutzt wird.
Wie kann ich es erreichen?

Danke für Eure Hilfe

gruss t

[WillWissen]

Hi,

Wie kann ich es erreichen?

wenn überhaupt, dann nur mit VBA. Falls du Makros einsetzen darfst/kannst/willst, werden dir die VBA-Spezialisten sicherlich weiterhelfen können.

[Käpt'n Blaubär]

Hallo,

„Windwos Photo viewer“

Kenne ich nicht, brauche ich auch nicht und wenn das so überaus wichtig ist, dieses Programm einzusetzen,
dann sollte man vielleicht ein paar Euronen in die Hand nehmen und die Geschichte an einen Programmierer
vergeben. (hier sollte jetzt eigentlich ein Smilie stehen; HIV = Hab ich vergessen)

[Kuwer]

Hallo t,

hier ein Beispiel für einen Doppelklick in eine Zelle.
Der Code kommt in das schon vorhandene VBA-Modul des entsprechenden Arbeitsblattes:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
  Dim lngZ As Long
  Dim strBilder(1 To 5) As String 'Anzahl Bilder hier festlegen
  Dim strStart As String
  
  Cancel = True
  
  For lngZ = 1 To UBound(strBilder)
    strBilder(lngZ) = "C:\Excelbild\" & lngZ & ".png"
  Next lngZ
  
  For lngZ = 1 To UBound(strBilder)
    strStart = "rundll32 """ & Environ("ProgramFiles") & "\Windows Photo Viewer\PhotoViewer.dll"",ImageView_Fullscreen " & strBilder(lngZ)
    Shell strStart, vbMaximizedFocus  'Windows-Fotoanzeige öffnen
    Application.Wait Now + TimeValue("0:00:15") '15 Sekunden warten
    SendKeys "%db"  'Windows-Fotoanzeige schließen
  Next lngZ
End Sub

Gruß Uwe

[sheffield]

Hallo Uwe

Danke Dir für die große Hilfe. sorry, dass ich mich jetzt melde (wegen der Krankheit)

ich habe folgende Fragen

-kann ich dein VBA ohne „Private“ verwenden?

-Kann ich anstatt irgendeiner Zelle eine Absolute Bezüge definieren sagen, wir mal $A406?

Grüsse
t

[Käpt'n Blaubär]

Hallo,

-kann ich dein VBA ohne „Private“ verwenden?

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

nein, Kannst Du nicht, Du kannst es auch nicht in ein Allgemeines Modul stecken.
Es wirkt nur in dem Tabellenblatt, hinter dem es liegt.

-Kann ich anstatt irgendeiner Zelle eine Absolute Bezüge definieren sagen, wir mal $A406?

das kannst Du selbst probieren. Es schadet nichts, wenn man damit ein bischen rumexperimentiert.
Kaputtmachen kann man da nichts.

[Kuwer]

Hallo t,

Public Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
 Dim lngZ As Long
 Dim strBilder(1 To 5) As String 'Anzahl Bilder hier festlegen
 Dim strStart As String
 
 Select Case Target.Address
   Case "$A$406", "$C$5" 'diese beiden Zellen sollen reagieren > entsprechend anpassen!
   
     Cancel = True
     
     For lngZ = 1 To UBound(strBilder)
       strBilder(lngZ) = "C:\Excelbild\" & lngZ & ".png"
     Next lngZ
     
     For lngZ = 1 To UBound(strBilder)
       strStart = "rundll32 """ & Environ("ProgramFiles") & "\Windows Photo Viewer\PhotoViewer.dll"",ImageView_Fullscreen " & strBilder(lngZ)
       Shell strStart, vbMaximizedFocus  'Windows-Fotoanzeige öffnen
       Application.Wait Now + TimeValue("0:00:15") '15 Sekunden warten
       SendKeys "%db"  'Windows-Fotoanzeige schließen
     Next lngZ
 End Select
End Sub

Gruß Uwe

[sheffield]

Hallo uwe

besten dank für die Hilfe

br
t