Excel Formel

[Asceroon]

Hallo zusammen,

ich habe folgendes Problem:

In einer Tabelle habe ich eine Zahl die zu einer bestimmten Kontonummer gehört. In einer anderen Tabelle gibt es diese Zahl auch. Allerdings setzt sich diese ggf. aus mehreren Konten zusammen. Die Konten aus Tabelle 2 habe ich in Tabelle 1 eingegeben und folgende Funktion in Tabelle 1 eingegeben:

=WENN(SUMME(WENN(ODER(H39<0;H39>0);SVERWEIS(D39;Tabelle2!$A$1:$C$237;3;FALSCH));WENN(ODER(H39<0;H39>0);SVERWEIS(C39;Tabelle2!$A$1:$C$237;3;FALSCH));WENN(ODER(H39<0;H39>0);SVERWEIS(E39;Tabelle2!$A$1:$C$237;3;FALSCH)))<0;SUMME(WENN(ODER(H39<0;H39>0);SVERWEIS(D39;Tabelle2!$A$1:$C$237;3;FALSCH));WENN(ODER(H39<0;H39>0);SVERWEIS(C39;Tabelle2!$A$1:$C$237;3;FALSCH));WENN(ODER(H39<0;H39>0);SVERWEIS(E39;Tabelle2!$A$1:$C$237;3;FALSCH)))*-1;SUMME(WENN(ODER(H39<0;H39>0);SVERWEIS(D39;Tabelle2!$A$1:$C$237;3;FALSCH));WENN(ODER(H39<0;H39>0);SVERWEIS(C39;Tabelle2!$A$1:$C$237;3;FALSCH));WENN(ODER(H39<0;H39>0);SVERWEIS(E39;Tabelle2!$A$1:$C$237;3;FALSCH))))

Problem ist allerdings, wenn in nur in einer Zelle eine Kontonummer steht und in den anderen beiden keine, dann bekomm ich als Ergebnis #NV. Wenn alle drei Zellen mit Kontonummern versehen sind funktioniert die Formel. Habt ihr eine Idee wie ich das auch hinbekomme wenn nur eine bzw. zwei Kontonummern ausgefüllt sind?

Vielen Dank für eure Mühe.

Viele Grüße

Asceroon

[steve1da]

Hola,

da hier niemand weiß, welche Daten genau wo stehen:

=wennfehler(Deine_Formel;andere_Formel=

Gruß,
steve1da

[RPP63]

Moin!
Ändere >0 in <42
Und im Ernst:
Glaubst Du ernsthaft, dass sich da jemand ohne Datei hineindenkt?

Gruß Ralf

[BoskoBiati]

Hi,

das: 

Code:

WENN(ODER(H39<0;H39>0) 

ist doch das Gleiche wie das:

Code:

WENN(H39<>0;

Code:

=WENN(H39<>0;ABS(SUMME(WENNFEHLER(SVERWEIS(D39;Tabelle2!$A$1:$C$237;3;0);0);WENNFEHLER(SVERWEIS(C39;Tabelle2!$A$1:$C$237;3;0);0);WENNFEHLER(SVERWEIS(E39;Tabelle2!$A$1:$C$237;3;0);0)));0)

[Josef B]

Hallo

Hier noch eine andere Variante.

Code:

=(H39<>0)*ABS(SUMMENPRODUKT((Tabelle2!A1:A237=C39:E39)*Tabelle2!C1:C237))

Gruss Sepp