Excel Funktion Aber welche

[derganze]

Hallo ich hoffe ich bin hier richtig 

ich möchte eine funktion haben  das wenn in der Spalte A ein x ist das er mit den text von Spalte B-G  nach L-Q copiert und die Spalte H nach R 
das ganze nach möglchkeit von oben nach unten ohne lücken inerhalb der Rechten Tabelle die spalte R wird automatisch zusammen gerechnet und in 5 O-R ausgegeben.
kann mir wer helfen hoffe ihr versteht was ich möchte.

[img]
Dateiupload bitte im Forum! So geht es: Klick mich!
]

[WillWissen]

Hi,

meine Lösung mit einer Hilfsspalte (einfach ausblenden):

Tabelle1

	A	B	C	D	E	F	G	H
1		Text	Zahl	HS			Text	Zahl
2		Text1	10				Text2	11
3	x	Text2	11	3			Text4	13
4		Text3	12				Text5	14
5	x	Text4	13	5			Text8	17
6	x	Text5	14	6
7		Text6	15
8		Text7	16
9	x	Text8	17	9
10		Text9	18

Formeln der Tabelle

Zelle Formel D2 =WENN(A2="x";ZEILE();"") G2 =WENNFEHLER(INDEX($B$1:$B$10;KKLEINSTE($D$2:$D$10;ZEILE(A1)));"") H2 =WENNFEHLER(SVERWEIS(G2;$B$2:$C$10;2;0);"")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[Jockel]

Hallo, hier noch eine lup(en)o1-reicher Vorschlag (angelehnt an eine Variante von lupo1, wo ich sowas zuerst sah... falls sich wieder jemand grämt... ... ich weiß also nicht, wer's erfunden hat)..:

Arbeitsblatt mit dem Namen 'Blatt1'
	A	B	C	D	E	F	G
1		Text	Zahl			Text	Zahl
2		Text1	10		3	Text2	11
3	x	Text2	11		5	Text4	13
4		Text3	12		6	Text5	14
5	x	Text4	13		9	Text8	17
6	x	Text5	14
7		Text6	15
8		Text7	16
9	x	Text8	17
10		Text9	18

Zelle	Formel
E2	=WENNFEHLER(VERGLEICH(1;INDEX(--(A$999:INDEX($A$1:$A$27;E1+1)="x"););)+E1;"")
F2	=WENN($E2="";"";INDEX(B$1:B$10;$E2))
G2	=WENN($E2="";"";INDEX(C$1:C$10;$E2))

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg

Aber es geht freilich auch ohne Hilfsspalte...

[Jockel]

Hallo, so sähe (m)eine AGGREGAT()-Varinate aus...:

Arbeitsblatt mit dem Namen 'Blatt1 (2)'
	A	B	C	D	E	F	G
1		Text	Zahl			Text	Zahl
2		Text1	10			Text2	11
3	x	Text2	11			Text4	13
4		Text3	12			Text5	14
5	x	Text4	13			Text8	17
6	x	Text5	14
7		Text6	15
8		Text7	16
9	x	Text8	17
10		Text9	18

Zelle	Formel
F2	=WENNFEHLER(INDEX(B$2:B$10;AGGREGAT(15;6;ZEILE($A$2:$A$10)-1/($A$2:$A$10="x");ZEILE($A1)));"")

Diese Tabelle wurde mit Tab2Html (v2.5.0) erstellt. ©Gerd alias Bamberg