Excel VBA: Spalte Verschieben und nicht vertauschen

[Kuwer]

Hallo Erich,

passt es so?

Sub SpaltenVerschiebenOhneZeile1()
Dim rngSpalteA As Range
Dim rngSpalteB As Range
Dim Zwischenspeicher As Variant

 On Error GoTo ErrorHandle

 Set rngSpalteA = Application.InputBox(prompt:="1. Spalte markieren:", Type:=8).EntireColumn
 If rngSpalteA.Columns.Count > 1 Then
   MsgBox "Die 1. Markierung enthält mehr als eine Spalte", vbCritical
   Exit Sub
 End If

 Set rngSpalteB = Application.InputBox(prompt:="1. Spalte ist " & _
   rngSpalteA.Address & vbLf & "2. Spalte markieren:", Type:=8).EntireColumn
 If rngSpalteB.Columns.Count > 1 Then
   MsgBox "Die 2. Markierung enthält mehr als eine Spalte", vbCritical
   Exit Sub
 End If
 
 Application.ScreenUpdating = False
 Zwischenspeicher = Rows(1).Value
 rngSpalteA.Cut
 rngSpalteB.Insert xlToRight
 Rows(1).Value = Zwischenspeicher
 Application.ScreenUpdating = True
 Exit Sub

ErrorHandle:
 MsgBox "Das Makro wurde abgebrochen!", vbExclamation

End Sub

Gruß Uwe

[sharky51]

Hallo Uwe,

wunderbar...so funktioniert es perfekt und hilft mir weiter.

Vielen Dank für Deine Bemühungen und Unterstützung...einfach klasse!