Excel to PDF überschreibt Dokumente

[Patrick S]

Hallo Zusammen,

ich habe einen kleinen VBA Code, der ein Excel Sheet in PDF exportiert. Die Benamung des PDF Dokuments ist festgelegt und wird generiert.
Möchte ein User allerdings einen gleichen Namen speichern und ändert im Windows Explorer den Dateinamen beispielsweise von Freigabe_12345 auf Freigabe_12345_1 und drückt dann speichern, so speichert mein Code das trotzdem unter dem alten Namen und überschreibt das alte...

Vielleicht kann mir einer helfen oder meinen "Fehler" finden. 

Code:

Sub PDFActiveSheet()
'www.contextures.com
'for Excel 2010 and later
Dim wsA As Worksheet
Dim wbA As Workbook
Dim strPath As String
Dim strFile As String
Dim strPathFile As String
Dim myFile As Variant
On Error GoTo errHandler
Dim SIS As String

SIS = ThisWorkbook.Worksheets("ToPdf").Cells(14, 6).Value

Set wbA = ActiveWorkbook
Set wsA = ActiveSheet
On Error GoTo errHandler

strPath = "\\srv08n10\tchl\08-prod\08-Reparaturabwicklung\30-Reparaturübersichten\Strahlquellen-Freigabe-PDFs\"


'create default name for savng file
strFile = "Freigabe_" & SIS & ".pdf"
strPathFile = strPath & strFile

' select folder for file
myFile = Application.GetSaveAsFilename _
  (InitialFileName:=strPathFile, _
      FileFilter:="PDF Files (*.pdf), *.pdf", _
      Title:="Select Folder and FileName to save")

'export to PDF if a folder was selected
If myFile <> "False" Then
  wsA.ExportAsFixedFormat _
      Type:=xlTypePDF, _
      Filename:=strPathFile, _
      Quality:=xlQualityStandard, _
      IncludeDocProperties:=True, _
      IgnorePrintAreas:=False, _
      From:=1, To:=1, _
      OpenAfterPublish:=False
  'confirmation message with file info
  MsgBox "Wurde gespeichert unter: " _
    & vbCrLf _
    & myFile
End If

exitHandler:
  Exit Sub
errHandler:
  MsgBox "PDF wurde nicht erstellt"
  Resume exitHandler
End Sub

Vielen Dank 
Gruß Patrick

[Gast 123]

Hallo Patrick

ich bin mir nicht 100% sicher wie man es aendern muss, sehe aber einen Fehler, und zwar hier:   strPathFile = strPath & strFile

Dahinter kommt mit myFile der Dialog Aufruf, aber du aenderst den oberen Teil  "strPathFiie" NICHT BEIM Speichern! Probier Filenname= bitte mal mit myFile!
 wsA.ExportAsFixedFormat Type:=xlTypePDF, _
      Filename:=strPathFile, 

mfg  Gast 123

[Patrick S]

Hallo Gast123

deine Lösung hat das Problem tatsächlich gelöst.
Habe ich komplett übersehen. 

Vielen Dank!

Gruß Patrick