Exceltabelle-Ausgabe aus Microsoft NAV --> Formatierung für Formeln

[Musi]

Hallo zusammen,

auf Arbeit lasse ich mir in Microsoft Navision (SAP-Pendant) eine Exceltabelle erzeugen. Diese Tabelle enthält in Spalte A Ziffern (Format Standard) und Spalte B Datumswerte (Format Datum).
(Siehe Tabelle 1 im Anhang).

In Tabelle 2 (nicht aus Navision, ganz normal erzeugt) steht in Spalte A eine Formel:
=WENN(C3="";"Kein Kontakt bisher";WENN(UND(B3=0;DATWERT(C3)>42004);"Telefonat";WENN(UND(DATWERT(C3)>42004;NICHT(ISTLEER(C3));B3>0);"Besuch";"kein Kontakt 2015")))

In Spalte B und C in Tabelle 2 werden die beiden Spalten aus Tabelle 1 eingefügt.

Das Problem ist, die Formel funktioniert nur dann wenn:
- die leere Spalte C in Tabelle 2 als Text formatiert ist
- ich die Daten aus Tabelle 1 vor dem einfügen in Tabelle 2 im Notepad "zwischenparke".

An sich habe ich überhaupt kein Problem damit, allerdings wird mit dieser Tabelle in Zukunft eine Kollegin arbeiten, und ich habe die Aufgabe bekommen ihr den Schritt über Notepad zu ersparen - sie soll also die Daten direkt aus Tabelle 1 in 2 kopieren können.

Könnt ihr mir da helfen?
Vielen Dank :)

[shift-del]

Hallo

Wenn ich die Daten mit CTRL-C/CTRL-V kopiere dann funktioniert deine Formel - wenn ich die Funktion DATWERT() weglasse.
Man könnte die Formel auch noch weiter kürzen.

Code:

=WENN(C3="";"Kein Kontakt bisher";WENN(C3>--"31.12.2014";WENN(B3=0;"Telefonat";"Besuch");"Kein Kontakt 2015"))

[WillWissen]

Hi,

ich hab' dir mal die beiden Tabellen der Einfachheit halber zusammengepackt. Schau mal, ob es das ist, was du benötigst.


  Musi-Testtabelle_zusammengefasst.xlsx (Größe: 18,31 KB / Downloads: 2)

[Musi]

Vielen lieben Dank euch beiden für die schnelle Hilfe.

@shift-del: Leider hat es nicht ganz funktioniert, ich habe zwar keine "#wert" Fehlermeldung mehr bekommen, allerdings kam immer das gleiche Ergebnis unabhängig von den Werten.

@WillWissen: Deine Formel klappt sehr gut. Vielen Dank :)

[shift-del]

allerdings kam immer das gleiche Ergebnis unabhängig von den Werten.

Das kann ich nicht nachvollziehen. Beide Formeln liefern die selben Ergebnisse.

	A	B	C	D
3	Telefonat	0	17.03.2015	Telefonat
4	Besuch	1	14.01.2015	Besuch
5	Besuch	2	25.08.2015	Besuch
6	Besuch	1	29.01.2015	Besuch
7	Besuch	1	29.07.2015	Besuch
8	kein Kontakt 2015	0	25.01.2012	Kein Kontakt 2015
9	kein Kontakt 2015	0	28.05.2014	Kein Kontakt 2015
10	kein Kontakt 2015	0	06.12.2011	Kein Kontakt 2015
11	kein Kontakt 2015	0	06.06.2013	Kein Kontakt 2015
12	kein Kontakt 2015	0	21.11.2011	Kein Kontakt 2015
13	Kein Kontakt bisher			Kein Kontakt bisher

Zelle	Formel
A3	=WENN(C3="";"Kein Kontakt bisher";WENN(UND(B3=0;C3>42004);"Telefonat";WENN(UND(C3>42004;B3>0);"Besuch";"kein Kontakt 2015")))
D3	=WENN(C3="";"Kein Kontakt bisher";WENN(C3>--"31.12.2014";WENN(B3=0;"Telefonat";"Besuch");"Kein Kontakt 2015"))

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Musi]

Ich muss mich in aller Form entschuldigen, ich habe es gerade nocheinmal probiert und es funktioniert super.

Kannst du mir der Interesse halber erklären, welche Funktion die beiden "-" in der Funktion übernehmen? (...WENN(C3>--"31.12.2014"...)
Abgesehen davon, das es ohne nicht geht.


Vielen Dank :)

[WillWissen]

Hi Musi,

mit dem Doppelminus wandelst du in diesem Beispiel ein Datum in Textform in ein echtes Datum um. Du könntest anstelle der beiden Minus auch mit *1 operieren oder +0 operieren.

Tabelle1

	A	B
1	15-08-15	42231
2	15-08-15	42231
3	15-08-15	42231

Formeln der Tabelle

Zelle Formel B1 =--(A1) B2 =A2*1 B3 =A3+0

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

[Musi]

Hi Musi,

mit dem Doppelminus wandelst du in diesem Beispiel ein Datum in Textform in ein echtes Datum um. Du könntest anstelle der beiden Minus auch mit *1 operieren oder +0 operieren.

Wieder was gelernt. Vielen Dank :)