Filtern über Dropdown liste

[Kevin Fragesteller]

Hallo,

ich möchte das Ergebnis in Tabelle2 anhand den Daten in Tabelle 1 erreichen. Darüber hinaus ist es denkbar das gewünschte Ergebnis auch in Tabelle 1 zu haben ?
Ich habe mit der Formel versucht: WENN(ZEILE(A1)>ANZAHL2(Tabelle1!D:D);"";INDEX(Tabelle1!D:D;KKLEINSTE(WENN(Tabelle1!D$1:D$3000<>"";ZEILE($1:$1000));ZEILE(A1))))

Lieber Gruß
Kevin

[shift-del]

Moin

Verwende eine Pivot mit Datenschnitt.

[Kevin Fragesteller]

Hallo, danke für den Vorschlag.
Ich verzichte auf Pivot Tabelle. Ich hoffe jemand kann das auch mit Aggregat oder so schaffen. :)

[shift-del]

Oder so.

Code:

=FILTER(Tabelle1!B3:D10;Tabelle1!D3:D10=Tabelle1!A2)

[Cadmus]

Hallo,

Daten als Tabelle formatieren und einfach filtern.

[Kevin Fragesteller]

Hallo, danke sehr. Nun funktioniert das nicht bei mir. Vllt liegt an der Version oder calc ?
Sonst Haben Sie die Formel in dem sheet getestet ? Bitte versuchen Sie auch.

LG
Kevin

[echo]

Hallo Kevin
ich mache das gerne per Hilfsspalte
Gruß Holger

[Fred11]

Hallo Kevin,

Formel in A2 (auf dem Tabellenblatt "Tabelle2"):
=WENN(ZEILE(A1)>ZÄHLENWENN(Tabelle1!D:D;Tabelle1!$A$2);"";INDEX(Tabelle1!B:B;KKLEINSTE(WENN(Tabelle1!D$1:D$1000=Tabelle1!$A$2;ZEILE($1:$1000));ZEILE(A1))))
(Matrixformel => Eingabe mit Strg+Shift+Enter)
Die anderen Spalten dann analog.

Oder mit AGGREGAT:
=WENNFEHLER(INDEX(Tabelle1!$B$1:$B$1000;AGGREGAT(15;6;ZEILE($1:$1000)/(Tabelle1!$D$1:$D$1000=Tabelle1!$A$2);ZEILE(A1)));"")

(Das ganze funktioniert natürlich auch auf dem Tabellenblatt "Tabelle1")

Erklärung der Aggregat-Formel https://www.youtube.com/watch?v=He3dblboncw

Gruß
Fred

[Kevin Fragesteller]

Hallo Echo, Hallo Fred,

vielen Dank für Ihre Vorschlaege beide haben Super funktioniert :).
@Fred Ihr ausführliches Kommentar hat mir sehr weitergebracht. Das Video bzw. Kanal ist auch hilfreich gewesen.

LG
Kevin