Formel benötigt, wenn Artikelnr. mehrere Werte aufweist

[BenQLnX]

Hallo zusammen,

nachdem ich ein paar Minuten im Forum hier nichts gefunden hatte, stelle ich die Frage nun einfach mal rein.


In meiner Tabelle habe ich mehrere Artikel, bei welchen ich überprüfen will, ob eine Artikelnummer unterschiedliche Preise aufweist; hier ein kleiner Ausschnitt dazu:

Art.Nr.   Name                 Preis
464699  Rucksack (S)      78,00
464699  Rucksack (XL)     84,00
464700  Lampe              25,00
464701  Eimer                 7,00
464702  Schlafsack (RR) 99,00
464702  Schlafsack (RL) 109,00

Die Artikelnummern tauchen in der Tabelle sowohl einzeln als auch mehrfach auf.

Welche Formel kann ich anwenden, damit mir Excel in einer neuen Spalte ausgibt, dass zu der angegeben Artikelnummern verschiedene Preise existieren?

LG, Ben

[RPP63]

Moin!
Nun, unterschiedliche Artikel mit gleicher Art-Nr. zu versehen, empfinde ich als gelinde gesagt unglücklich!
Aber gut, eine Formellösung gibt es dennoch:
Tabelle4

	A	B	C	D
1	Art.Nr.	Name	Preis
2	464699	Rucksack (S)	78,00 €	X
3	464699	Rucksack (XL)	84,00 €	X
4	464700	Lampe	25,00 €
5	464701	Eimer	7,00 €
6	464702	Schlafsack (RR)	99,00 €	X
7	464702	Schlafsack (RL)	109,00 €	X

Formeln der Tabelle

Zelle Formel D2 {=WENN(MAX(WENN(A$2:A$7=A2;C$2:C$7))=MIN(WENN(A$2:A$7=A2;C$2:C$7));"";"X")}

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Formel wie beschrieben abschließen und nach unten ziehen.

Gruß Ralf

[RPP63]

In Spalte E gibt es eine Matrixfreie Lösung, die aber erst ab Excel 2016 funktioniert:
(ein weiterer Vorteil: man kann ganze Spalten angeben)

Tabelle4

	A	B	C	D	E
1	Art.Nr.	Name	Preis
2	464699	Rucksack (S)	78,00 €	X	Y
3	464699	Rucksack (XL)	84,00 €	X	Y
4	464700	Lampe	25,00 €
5	464701	Eimer	7,00 €
6	464702	Schlafsack (RR)	99,00 €	X	Y
7	464702	Schlafsack (RL)	109,00 €	X	Y

Formeln der Tabelle

Zelle Formel D2 {=WENN(MAX(WENN(A$2:A$7=A2;C$2:C$7))=MIN(WENN(A$2:A$7=A2;C$2:C$7));"";"X")} E2 =WENN(MAXWENNS(C:C;A:A;A2)=MINWENNS(C:C;A:A;A2);"";"Y")

Enthält Matrixformel: Umrandende { } nicht miteingeben, sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

Gruß Ralf

[Jonas0806]

Hallo,

hätte da auch noch einen matrixfreien Vorschlag in älteren Versionen

Code:

=SUMMEWENN($A$2:$A$7;A2;$C$2:$C$7)/ZÄHLENWENN($A$2:$A$7;A2)=C2

Habe das jetzt allerdings nicht großartig durchgetestet.

[BoskoBiati]

Hi,

reicht da nicht das:

	A	B	C	D	E
1	Art.Nr.	Name	Preis
2	464699	Rucksack (S)	78,00 €	X	FALSCH
3	464699	Rucksack (XL)	84,00 €	X	FALSCH
4	464700	Lampe	25,00 €		WAHR
5	464701	Eimer	7,00 €		WAHR
6	464702	Schlafsack (RR)	99,00 €	X	FALSCH
7	464702	Schlafsack (RL)	109,00 €	X	FALSCH

Zelle	Formel
E2	=MITTELWERTWENN($A$2:$A$7;A2;$C$2:$C$7)=C2

[RPP63]

:19:
Für das Beispiel reicht, wenn keine Datensatzdubletten vorkommen, natürlich auch:
=ZÄHLENWENN(A:A;A2)>1

Gruß Ralf

[BenQLnX]

Hallo Ralf,

vielen Dank für die rasche Hilfe, klappt wunderbar mit der ersten Formel.

LG Ben