Formel für Zeiten in Punkte umwandeln

[Peter]

Hallo,

was du noch machen könntest wäre die Formel auf den genutzen Matrixbereich zu begrenzen, d.h. in G3 folgende Formel

=SVERWEIS(F3;A$2:C$12;3)

und in L3: =SVERWEIS(K3;S$3:U$13;3) bzw. Q3: =SVERWEIS(P3;S$3:U$13;3)

[Rabe]

Hi Peter,

=SVERWEIS(F3;A$2:C$12;3)

und in L3: =SVERWEIS(K3;S$3:U$13;3) bzw. Q3: =SVERWEIS(P3;S$3:U$13;3)

sollte nicht besser noch der 4. Parameter eingefügt werden?

=SVERWEIS(F3;A$2:C$12;3;0)

[Peter]

Hallo Ralf,

in diesem Fall macht der 4. Parameter keinen Sinn. Mit der 0 würdest du nach einer genauen Übereinstimmung suchen, wir wollen aber in einem Bereich von - bis suchen und würden dann, wenn es keine genaue Übereinstimmgung gibt, ein #NV als Ergebnis erhalten.

Die Matrix ist, das ist wichtig, aufsteigend angeordnet und deswegen funktioniert das in diesem Fall ohne den 4. Parameter.

[atilla]

Hallo,

hier noch eine Variante, die ich von Jörg(Jockel) gelernt habe:

Arbeitsblatt mit dem Namen 'Tabelle1'
	A	B	C	D	E	F	G
1	von	bis	Punkt			Abweichung
2	0	0,29	20			0,23	20
3	0,3	0,59	18			0,3	18
4	0,6	0,99	16			0,31	18
5	3		0			0,59	18
6						3	0

Zelle	Formel
G2	=VERWEIS(F2;$A$2:$C$5)

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[BoskoBiati]

Hallo,

so auf die Schnelle:

Code:

=20-KÜRZEN(ABS(A1);)*6-(A1>=1)*2-VERWEIS(REST(ABS(A1);1)*10;{0;3;6};{0;2;4})

oder auch so:

Code:

=VERWEIS(ABS(D1*10);{0;3;6;10;13;16;20;23;26;30};{20;18;16;12;10;8;6;4;2;0})

[BoskoBiati]

Hallo,

da ich bei 2,3 eine Unregelmäßigkeit im Ergebnis feststellen musste, hier mal eine Korrektur:

Arbeitsblatt mit dem Namen 'Tabelle1'
	D	E	F	G
1	0	20	20	20
2	0,29	20	20	20
3	0,3	18	18	18
4	0,59	18	18	18
5	0,6	16	16	16
6	0,99	16	16	16
7	1	12	12	12
8	1,29	12	12	12
9	1,3	10	10	10
10	1,59	10	10	10
11	1,6	8	8	8
12	1,99	8	8	8
13	2	6	6	6
14	2,29	6	6	6
15	2,3	4	4	4
16	2,59	4	4	4
17	2,6	2	2	2
18	2,99	2	2	2
19	3	0	0	0

Zelle	Formel
E1	=VERWEIS(ABS(D1*10);{0;3;6;10;13;16;20;23;26;30};{20;18;16;12;10;8;6;4;2;0})
F1	=20-KÜRZEN(ABS(D1);)*6-KÜRZEN((REST(ABS(D1)+1%%;1)-(REST(ABS(D1);1)>0,6)/10)/0,3;0)*2-(ABS(D1)>0,99)*2
G1	=20-KÜRZEN(ABS(D1);)*6-(ABS(D1)>=1)*2-VERWEIS(REST(ABS(D1)+1%%;1)*10;{0;3;6};{0;2;4})

Diese Tabelle wurde mit Tab2Html (v2.4.1) erstellt. ©Gerd alias Bamberg

[Peter]

Hallo,

ein schönes Beispiel für 'viele Wege führen nach Rom', wobei ich der separaten Matrix den Vorzug gebe.

Zum einen ist die Formel, vor allem wenn man sich das Ganze nach einer längeren Zeit anschaut, für Außenstehende verständlicher und zum anderen hat die Matrix bei einer Änderung der Grenzwerte den Vorteil dass ich die Formel nicht anfassen muss sondern lediglich die Werte in der Matrix ändere.

Aber das sind, genauso wie das Thema Hilfsspalten, persönliche Vorlieben oder auch Abneigungen.

[BoskoBiati]

Hallo Peter,

Du hast vollkommen recht, eine separate Matrix ist einfacher zu pflegen. Die Formel in E ist dann interessant, wenn die Berechnung nur an wenigen Stellen erfolgt. Die anderen beiden sind eher Spielerei und irgendwann nur noch für den, der sie erfunden hat nachvollziehbar.